ESP8266-01S GET POST 天貓精靈 APP控制 燒錄教程 基於巴法雲平台

需要工具：Arduino IDE 配置好esp8266環境

　　　　ESP8266開發板（此處用的esp8266-01s  帶5v繼電器如下圖）

 

　　　　串口工具TTL隨便什么芯片（但作者剛好帶了一個PL2303HXA的芯片（網上有驅動下載安裝后，一插拔又讓聯系供貨商），結果找不到其他ch340芯片了）

流程： 下載好開發環境和 代碼包,地址：https://cloud.bemfa.com/docs/#/?id=_22-%e6%8e%a7%e5%88%b6%e5%8d%95%e7%89%87%e6%9c%ba

然后連接設備 燒錄。 完成

巴法雲官網里面有接入文檔：https://bemfa.com/

手頭上暫時有幾個esp8266的板子

 ESP8266-01/S的外觀區別

 

其他的也可以更具實際需求修改代碼

 

　　　　

//********************需要修改的部分*******************//

#define DEFAULT_STASSID  "QQqun:51798659"     //WIFI名稱，區分大小寫，不要寫錯
#define DEFAULT_STAPSW   "51798659"  //WIFI密碼
String UID = "QQ群：51798659----------";  //用戶私鑰，可在控制台獲取,修改為自己的UID
String TOPIC =   "light002";         //主題名字，可在控制台新建
const int LED_Pin = 0;              //單片機LED引腳值 ESP8266-01S用這個腳

//**************************************************//

 

 

 串口芯片驅動裝好后就會有串口COMX

 

 

串口連接8266

GND->GND

VCC->3.3v

TX<->RX

GPIO0->GND

RST->GND燒錄前按下上電

 

 

 

然后就是串口選好和開發板選好

 

 

准備燒錄

 

還沒傳輸數據前 要按住rst上電放開手即可。gpio0一定要接入gnd 

 

 

隨后用的以前有個小E開發板來接的

 

 

 

 

最終代碼（需要更具自己的修改）：

/*
 * 天貓精靈控制
 * 2020-05-12
 * QQ交流群：824273231              
 * 官網https://bemfa.com 
 */
#include <WiFiClient.h>
#include <ESP8266WiFi.h>


//巴法雲服務器地址默認即可
#define TCP_SERVER_ADDR "bemfa.com"
//服務器端口，tcp創客雲端口8344
#define TCP_SERVER_PORT "8344"

//********************需要修改的部分*******************//

#define DEFAULT_STASSID  "QQqun:51798659"     //WIFI名稱，區分大小寫，不要寫錯
#define DEFAULT_STAPSW   "51798659"  //WIFI密碼
String UID = "QQ群：51798659----------";  //用戶私鑰，可在控制台獲取,修改為自己的UID
String TOPIC =   "light002";         //主題名字，可在控制台新建
const int LED_Pin = 0;              //單片機LED引腳值 ESP8266-01S用這個腳

//**************************************************//



//最大字節數
#define MAX_PACKETSIZE 512
//設置心跳值30s
#define KEEPALIVEATIME 30*1000



//tcp客戶端相關初始化，默認即可
WiFiClient TCPclient;
String TcpClient_Buff = "";
unsigned int TcpClient_BuffIndex = 0;
unsigned long TcpClient_preTick = 0;
unsigned long preHeartTick = 0;//心跳
unsigned long preTCPStartTick = 0;//連接
bool preTCPConnected = false;



//相關函數初始化
//連接WIFI
void doWiFiTick();
void startSTA();

//TCP初始化連接
void doTCPClientTick();
void startTCPClient();
void sendtoTCPServer(String p);

//led 控制函數
void turnOnLed();
void turnOffLed();



/*
  *發送數據到TCP服務器
 */
void sendtoTCPServer(String p){
  
  if (!TCPclient.connected()) 
  {
    Serial.println("Client is not readly");
    return;
  }
  TCPclient.print(p);
  Serial.println("[Send to TCPServer]:String");
  Serial.println(p);
}


/*
  *初始化和服務器建立連接
*/
void startTCPClient(){
  if(TCPclient.connect(TCP_SERVER_ADDR, atoi(TCP_SERVER_PORT))){
    Serial.print("\nConnected to server:");
    Serial.printf("%s:%d\r\n",TCP_SERVER_ADDR,atoi(TCP_SERVER_PORT));
    
    String tcpTemp="";  //初始化字符串
    tcpTemp = "cmd=1&uid="+UID+"&topic="+TOPIC+"\r\n"; //構建訂閱指令
    sendtoTCPServer(tcpTemp); //發送訂閱指令
    tcpTemp="";//清空
    
    preTCPConnected = true;
    preHeartTick = millis();
    TCPclient.setNoDelay(true);
  }
  else{
    Serial.print("Failed connected to server:");
    Serial.println(TCP_SERVER_ADDR);
    TCPclient.stop();
    preTCPConnected = false;
  }
  preTCPStartTick = millis();
}


/*
  *檢查數據，發送心跳
*/
void doTCPClientTick(){
 //檢查是否斷開，斷開后重連
   if(WiFi.status() != WL_CONNECTED) return;

  if (!TCPclient.connected()) {//斷開重連

  if(preTCPConnected == true){

    preTCPConnected = false;
    preTCPStartTick = millis();
    Serial.println();
    Serial.println("TCP Client disconnected.");
    TCPclient.stop();
  }
  else if(millis() - preTCPStartTick > 1*1000)//重新連接
    startTCPClient();
  }
  else
  {
    if (TCPclient.available()) {//收數據
      char c =TCPclient.read();
      TcpClient_Buff +=c;
      TcpClient_BuffIndex++;
      TcpClient_preTick = millis();
      
      if(TcpClient_BuffIndex>=MAX_PACKETSIZE - 1){
        TcpClient_BuffIndex = MAX_PACKETSIZE-2;
        TcpClient_preTick = TcpClient_preTick - 200;
      }
      preHeartTick = millis();
    }
    if(millis() - preHeartTick >= KEEPALIVEATIME){//保持心跳
      preHeartTick = millis();
      Serial.println("--Keep alive:");
      sendtoTCPServer("cmd=0&msg=keep\r\n");
    }
  }
  if((TcpClient_Buff.length() >= 1) && (millis() - TcpClient_preTick>=200))
  {//data ready
    TCPclient.flush();
    Serial.println("Buff");
    Serial.println(TcpClient_Buff);
    if((TcpClient_Buff.indexOf("&msg=on") > 0)) {
      turnOnLed();
    }else if((TcpClient_Buff.indexOf("&msg=off") > 0)) {
      turnOffLed();
    }
   TcpClient_Buff="";
   TcpClient_BuffIndex = 0;
  }
}

void startSTA(){
  WiFi.disconnect();
  WiFi.mode(WIFI_STA);
  WiFi.begin(DEFAULT_STASSID, DEFAULT_STAPSW);
}



/**************************************************************************
                                 WIFI
***************************************************************************/
/*
  WiFiTick
  檢查是否需要初始化WiFi
  檢查WiFi是否連接上，若連接成功啟動TCP Client
  控制指示燈
*/
void doWiFiTick(){
  static bool startSTAFlag = false;
  static bool taskStarted = false;
  static uint32_t lastWiFiCheckTick = 0;

  if (!startSTAFlag) {
    startSTAFlag = true;
    startSTA();
    Serial.printf("Heap size:%d\r\n", ESP.getFreeHeap());
  }

  //未連接1s重連
  if ( WiFi.status() != WL_CONNECTED ) {
    if (millis() - lastWiFiCheckTick > 1000) {
      lastWiFiCheckTick = millis();
    }
  }
  //連接成功建立
  else {
    if (taskStarted == false) {
      taskStarted = true;
      Serial.print("\r\nGet IP Address: ");
      Serial.println(WiFi.localIP());
      startTCPClient();
    }
  }
}
//打開燈泡
void turnOnLed(){
  Serial.println("Turn ON");
  digitalWrite(LED_Pin,LOW);
}
//關閉燈泡
void turnOffLed(){
  Serial.println("Turn OFF");
    digitalWrite(LED_Pin,HIGH);
}


// 初始化，相當於main 函數
void setup() {
  Serial.begin(115200);
  pinMode(LED_Pin,OUTPUT);
  digitalWrite(LED_Pin,HIGH);
  Serial.println("Beginning...");
}

//循環
void loop() {
  doWiFiTick();
  doTCPClientTick();
}