使用bat一鍵安裝mysql

1、下載mysql的壓縮包版，下載地址如下：

　　https://cdn.mysql.com//Downloads/MySQL-8.0/mysql-8.0.22-winx64.zip

2、解壓后目錄如下：

　　

 3、把下面的內容，另存為一個bat文件，把這個bat文件放到剛才那個目錄里，然后以右鍵管理員的方式運行

@setlocal enabledelayedexpansion
@echo off
color f0
rem 編程技術 www.vcvb.cn 出品，轉載請保留此信息。
title MYSQL一鍵安裝

set basedir=%~dp0
set bin=%~dp0\bin
cd /d %~dp0
if exist !bin!\mysqld.exe (
rem 寫入配置
>my.ini echo [mysqld]
>>my.ini echo port=3306
>>my.ini echo basedir=!basedir!
>>my.ini echo datadir=!basedir!\Data
>>my.ini echo log-error=!basedir!\Logs.log
>>my.ini echo max_connections=200
>>my.ini echo max_connect_errors=10
>>my.ini echo character-set-server=utf8mb4
>>my.ini echo default-storage-engine=INNODB
>>my.ini echo default_authentication_plugin=mysql_native_password
>>my.ini echo local_infile=ON
>>my.ini echo.
>>my.ini echo [mysql]
>>my.ini echo default-character-set=utf8mb4
>>my.ini echo local_infile=ON
>>my.ini echo.
>>my.ini echo [client]
>>my.ini echo port=3306
>>my.ini echo default-character-set=utf8mb4

rem 添加環境變量
echo 開始檢查環境變量...
echo.
for /f "tokens=2*" %%i ^
in ('reg query "HKLM\SYSTEM\ControlSet001\Control\Session Manager\Environment" /v Path^|findstr /i "path"') ^
do (set "p=%%j")
for /f "tokens=*" %%a in ('echo !p! ^| find /i "!bin!"') do (set flag=1)
if not defined flag (
echo 開始添加環境變量
setx Path "!p!;!bin!" /M | find "成功" && echo 環境變量添加成功
set p=!Path!
) else (echo 環境變量已存在，無需設置。)
echo.

rem 初始化 --console
cd !bin!

>!basedir!\Logs.log echo --------初始化數據庫開始--------

echo 開始初始化數據庫

mysqld --initialize-insecure

>>!basedir!\Logs.log echo --------初始化數據庫結束--------

rem 安裝服務
echo 開始安裝服務
mysqld --install MySQL | find "successfully" && echo 服務安裝成功
echo.
rem 啟動服務
echo 開始啟動MYSQL服務
net start MySQL
echo. 

mysql -u root -e "ALTER USER 'root'@'localhost' IDENTIFIED WITH mysql_native_password BY '1qaz'";

echo 安裝完成
) else (
echo 請將本工具放在解壓后的MYSQL根目錄下再打開
)
pause >nul

3、安裝完成，密碼已設定為：1qaz

備注：如果安裝出現缺少dll情況，請安裝vc++ runtime后重試  下載地址：(39條消息) VC_redist.x64.zip-其它文檔類資源-CSDN下載

 bat文件下載地址：下載

備注：如果想重新安裝的時候，記得把data目錄下的數據先刪除掉。