windows下mysql數據庫自動備份功能

windows下mysql數據庫自動備份功能

一，利用腳本備份

實現的特性
①，可指定多個數據庫
②，按照 年/月/日 的方式組織備份
③，可選的使用 WinRAR 壓縮備份
④，使用計划任務實現定時備份

原理

利用windows批處理腳本（.bat文件）執行mysql 數據庫備份命令 mysqldump ，若指定了winrar 安裝路徑，則會使用winrar 壓縮備份數據。雙擊 .bat 文件可執行 

①，備份數據庫數據

標黃顏色的地方，是需要讀者自行修改成你自己的配置信息的，保存以下文件內容為 backup.bat 文件

 
@echo off & setlocal ENABLEEXTENSIONS 

:: ---------- 配置項 ---------- 

:: 備份放置的路徑，加 \ 
set BACKUP_PATH=D:\Backup\ 

:: 要備份的數據庫名稱，多個用空格分隔 
set DATABASES=database1 database2 database3 

:: MySQL 用戶名 
set USERNAME=root 

:: MySQL 密碼 
set PASSWORD=123456 

:: MySQL Bin 目錄，加 \ 
:: 如果可以直接使用 mysqldump（安裝時添加 MySQL Bin 目錄到了環境變量），此處留空即可 
set MYSQL=D:\SERVER\MySQL\bin\ 

:: WinRAR 自帶命令行工具的可執行文件路徑，長文件名注意用 Dos 長文件名書寫方式 
set WINRAR=C:\Progra~1\WinRAR\Rar.exe 

:: ---------- 以下請勿修改 ---------- 

set YEAR=%date:~0,4% 
set MONTH=%date:~5,2% 
set DAY=%date:~8,2% 
:: 如果在 dos 下輸入 time 返回的不是 24 小時制（沒有 0 填充），請自行修改此處 
set HOUR=%time:~0,2% 
set MINUTE=%time:~3,2% 
set SECOND=%time:~6,2% 

set DIR=%BACKUP_PATH%%YEAR%\%MONTH%\%DAY%\ 
set ADDON=%YEAR%%MONTH%%DAY%%HOUR%%MINUTE%%SECOND% 

:: create dir 
if not exist %DIR% ( 
mkdir %DIR% 2>nul 
) 
if not exist %DIR% ( 
echo Backup path: %DIR% not exists, create dir failed. 
goto exit 
) 
cd /d %DIR% 

:: backup 
echo Start dump databases... 
for %%D in (%DATABASES%) do ( 
echo Dumping database %%D ... 
%MYSQL%mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D.%ADDON%.sql 2>nul 
:: winrar 
if exist %WINRAR% ( 
%WINRAR% a -k -r -s -m1 -ep1 %%D.%ADDON%.rar %%D.%ADDON%.sql 2>nul 
del /F /S /Q %%D.%ADDON%.sql 2>nul 
) 
) 
echo Done 

:exit 

②，自動備份

創建windows定時任務自動備份（其實就是創建定時任務執行上面創建的備份數據庫腳本，注意腳本保存位置），保存以下文件內容為 backup_plan.bat 文件

 
@echo off 

:: ------- 配置項 ------- 

:: 要執行的文件名 
set FILE=.\backup.bat

:: 計划頻率類型 
set FREQUENCY=DAILY 

:: 頻率，與上面的計划頻率類型對應 
set MODIFIER=1 

:: 該計划執行的時間（24 小時制） 
set DATETIME=00:30:00 

:: 計划的名字 
set NAME="Backup Mysql Job" 

:: 計划執行用戶，不建議修改 
set USER="System" 

:: ------- 以下請勿修改 ------- 

schtasks /Create /RU %USER% /SC %FREQUENCY% /MO %MODIFIER% /ST %DATETIME% /TN %NAME% /TR %FILE% 
pause 

參數說明，其中的
:: 計划頻率類型，可選項：
:: MINUTE 分鍾
:: DAILY 天
:: HOURLY 小時
:: WEEKLY 周
:: MONTHLY 月

:: 頻率，與上面的計划頻率類型對應
:: MINUTE: 1 到 1439 分鍾
:: HOURLY: 1 - 23 小時
:: DAILY: 1 到 365 天
:: WEEKLY: 1 到 52 周
:: MONTHLY: 1 到 12，或 FIRST, SECOND, THIRD, FOURTH, LAST, LASTDAY

二，利用客戶端工具備份

上面說這么多，就是懶，希望電腦幫我們自動備份。如果用mysql客戶端工具，右鍵備份就搞定啦，（只不過客戶端工具創建定時計划需要收費）

選擇想要備份數據庫或者表，右鍵選擇 “轉儲SQL文件”。

 

參考博客內容 

 https://www.jb51.net/article/30195.htm

 https://www.cnblogs.com/mmzs/p/10063176.html

 

 

@萍2櫻釋ღ( ´･ᴗ･` )