一、esp8266 讀取 DHT11 數據並通過微信小程序發送數據

前言

我們之前有做過這個項目，后來傳到了雲端 Dweet.io ，以圖表的方式復現出來了。傳送門：利用 esp8266 搭建簡單物聯網項目
今天我們把數據與微信小程序連接起來，之前我在做阿里雲的時候，搗騰過公眾號，其實都差不多道理。

原理（發布訂閱模式）

讀取 DHT11 數據
新建主題，然后esp8266往這個主題發送消息
小程序通過http API接口獲取數據
發布訂閱模式：

訂閱（訂閱）：訂閱給定的一個主題/頻道的信息。
發布（發布）將信息發送到指定的主題/頻道。
只有訂閱該主題的設備才可以收到發往該主題的消息。

讀取 DHT11 數據

接線
| esp8266 | DHT11 |
| ---- | ---- |
| 3V | VCC |
| GND | GND |
| D4 | Data |
- 這里用的D4口，上篇博客的 D1口被我的 OLED 屏占用了
測試功能
- 安裝庫： SimpleDHT

#include <SimpleDHT.h>
int pinDHT11 = D4;
SimpleDHT11 dht11(pinDHT11);

//鄭某人的測試代碼
void setup() {
  Serial.begin(115200);
}

void loop() {
  // start working...
  Serial.println("=================================");
  Serial.println("Sample DHT11...");
  
  // read without samples.
  byte temperature = 0;
  byte humidity = 0;
  int err = SimpleDHTErrSuccess;
  if ((err = dht11.read(&temperature, &humidity, NULL)) != SimpleDHTErrSuccess) {
    Serial.print("Read DHT11 failed, err="); Serial.println(err);delay(1000);
    return;
  }
  
  Serial.print("Sample OK: ");
  Serial.print((int)temperature); Serial.print(" *C, ");
  Serial.print((int)humidity); Serial.println(" H");
  
  // DHT11 sampling rate is 1HZ.
  delay(1500);
}

正常結果

數據發送至雲端(感謝Arduino社區bemfa大佬提供的源代碼和方法)

/*
關於UID：在巴法雲注冊登陸，即可看到自己UID，推送微信消息，需要手機綁定微信，bemfa.com在控制台進行綁定即可。
QQ交流群：824273231
巴法雲官網：bemfa.com
時間：2020/04/25
官方文檔見官網：http://www.cloud.bemfa.com/docs/#/
*/
//DHT11數據上傳+LED遠程控制 //不限於DHT11,可以接其他傳感器，也可以接多個傳感器，這里只是例程
//DHT11數據上傳主題temp   //根據自己在控制台命的名字可自己隨意修改
//LED燈控制主題light002   //根據自己命的名字可自己隨意修改
/*
程序講解：ESP8266 有兩個角色，一個是temp(傳感器數據)主題消息的發布者，esp8266往這個主題推送消息，手機app訂閱temp主題，就可以收到傳感器數據了。
esp8266聯網后，訂閱light002，手機往這個主題推送消息，esp8266就能收到手機的控制的指令了。
*/
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <SimpleDHT.h>


//巴法雲服務器地址默認即可
#define TCP_SERVER_ADDR "bemfa.com"
//服務器端口//TCP創客雲端口8344//TCP設備雲端口8340
#define TCP_SERVER_PORT "8344"

///****************需要修改的地方*****************///

//WIFI名稱，區分大小寫，不要寫錯
#define DEFAULT_STASSID  "Geohot"
//WIFI密碼
#define DEFAULT_STAPSW "zheng123+"
//用戶私鑰，可在控制台獲取,修改為自己的UID
String UID = "4222ebc83f26eac038c8e48bfc208031";
//主題名字，可在控制台新建
String TOPIC = "temp"; //用於傳輸溫濕度的主題
//DHT11引腳值
int pinDHT11 = D4;  //連接dht11的引腳
//單片機LED引腳值
const int LED_Pin = D2;  //假設連接led的引腳
//主題名字，可在控制台新建
String TOPIC2  = "light002";  //用於led控制的主題

///*********************************************///
//led 控制函數
void turnOnLed();
void turnOffLed();
//led狀態狀態
String my_led_status = "off";



//設置上傳速率2s（1s<=upDataTime<=60s）
//下面的2代表上傳間隔是2秒
#define upDataTime 2*1000


// for DHT11, 
//      VCC: 5V or 3V
//      GND: GND
//      DATA: 2

SimpleDHT11 dht11(pinDHT11);





//最大字節數
#define MAX_PACKETSIZE 512





//tcp客戶端相關初始化，默認即可
WiFiClient TCPclient;
String TcpClient_Buff = "";
unsigned int TcpClient_BuffIndex = 0;
unsigned long TcpClient_preTick = 0;
unsigned long preHeartTick = 0;//心跳
unsigned long preTCPStartTick = 0;//連接
bool preTCPConnected = false;



//相關函數初始化
//連接WIFI
void doWiFiTick();
void startSTA();

//TCP初始化連接
void doTCPClientTick();
void startTCPClient();
void sendtoTCPServer(String p);





/*
  *發送數據到TCP服務器
 */
void sendtoTCPServer(String p){
  
  if (!TCPclient.connected()) 
  {
    Serial.println("Client is not readly");
    return;
  }
  TCPclient.print(p);
  Serial.println("[Send to TCPServer]:String");
  Serial.println(p);
}


/*
  *初始化和服務器建立連接
*/
void startTCPClient(){
  if(TCPclient.connect(TCP_SERVER_ADDR, atoi(TCP_SERVER_PORT))){
    Serial.print("\nConnected to server:");
    Serial.printf("%s:%d\r\n",TCP_SERVER_ADDR,atoi(TCP_SERVER_PORT));
    String tcpTemp="";
    tcpTemp = "cmd=1&uid="+UID+"&topic="+TOPIC2+"\r\n";

    sendtoTCPServer(tcpTemp);
    preTCPConnected = true;
    preHeartTick = millis();
    TCPclient.setNoDelay(true);
  }
  else{
    Serial.print("Failed connected to server:");
    Serial.println(TCP_SERVER_ADDR);
    TCPclient.stop();
    preTCPConnected = false;
  }
  preTCPStartTick = millis();
}



/*
  *檢查數據，發送數據
*/
void doTCPClientTick(){
 //檢查是否斷開，斷開后重連
   if(WiFi.status() != WL_CONNECTED) return;

  if (!TCPclient.connected()) {//斷開重連

  if(preTCPConnected == true){

    preTCPConnected = false;
    preTCPStartTick = millis();
    Serial.println();
    Serial.println("TCP Client disconnected.");
    TCPclient.stop();
  }
  else if(millis() - preTCPStartTick > 1*1000)//重新連接
    startTCPClient();
  }
  else
  {
    if (TCPclient.available()) {//收數據
      char c =TCPclient.read();
      TcpClient_Buff +=c;
      TcpClient_BuffIndex++;
      TcpClient_preTick = millis();
      
      if(TcpClient_BuffIndex>=MAX_PACKETSIZE - 1){
        TcpClient_BuffIndex = MAX_PACKETSIZE-2;
        TcpClient_preTick = TcpClient_preTick - 200;
      }
      preHeartTick = millis();
    }
    if(millis() - preHeartTick >= upDataTime){//上傳數據
      preHeartTick = millis();

      /*****************獲取DHT11 溫濕度*****************/
      // read without samples.
      byte temperature = 0;
      byte humidity = 0;
      int err = SimpleDHTErrSuccess;
      if ((err = dht11.read(&temperature, &humidity, NULL)) != SimpleDHTErrSuccess) {
        Serial.print("Read DHT11 failed, err="); Serial.println(err);delay(1000);
        return;
      }
      
      /*********************數據上傳*******************/
      /*
        數據用#號包裹，以便app分割出來數據，&msg=#23#80#on#\r\n，即#溫度#濕度#按鈕狀態#，app端會根據#號分割字符串進行取值，以便顯示
        如果上傳的數據不止溫濕度，可在#號后面繼續添加&msg=#23#80#data1#data2#data3#data4#\r\n,app字符串分割的時候，要根據上傳的數據進行分割
      */
      String upstr = "";
      upstr = "cmd=2&uid="+UID+"&topic="+TOPIC+"&msg=#"+temperature+"#"+humidity+"#"+my_led_status+"#\r\n";
      sendtoTCPServer(upstr);
      upstr = "";
    }
  }
  if((TcpClient_Buff.length() >= 1) && (millis() - TcpClient_preTick>=200))
  {//data ready
    TCPclient.flush();
    Serial.println("Buff");
    Serial.println(TcpClient_Buff);
    //////字符串匹配，檢測發了的字符串TcpClient_Buff里面是否包含&msg=on，如果有，則打開開關
    if((TcpClient_Buff.indexOf("&msg=on") > 0)) {
      turnOnLed();
    //////字符串匹配，檢測發了的字符串TcpClient_Buff里面是否包含&msg=off，如果有，則關閉開關
    }else if((TcpClient_Buff.indexOf("&msg=off") > 0)) {
      turnOffLed();
    }
   TcpClient_Buff="";//清空字符串，以便下次接收
   TcpClient_BuffIndex = 0;
  }
}


//打開燈泡
void turnOnLed(){
  Serial.println("Turn ON");
  digitalWrite(LED_Pin,LOW);
  my_led_status = "on";
}
//關閉燈泡
void turnOffLed(){
  Serial.println("Turn OFF");
  digitalWrite(LED_Pin,HIGH);
  my_led_status = "off";
}


void startSTA(){
  WiFi.disconnect();
  WiFi.mode(WIFI_STA);
  WiFi.begin(DEFAULT_STASSID, DEFAULT_STAPSW);
}



/**************************************************************************
                                 WIFI
***************************************************************************/
/*
  WiFiTick
  檢查是否需要初始化WiFi
  檢查WiFi是否連接上，若連接成功啟動TCP Client
  控制指示燈
*/
void doWiFiTick(){
  static bool startSTAFlag = false;
  static bool taskStarted = false;
  static uint32_t lastWiFiCheckTick = 0;

  if (!startSTAFlag) {
    startSTAFlag = true;
    startSTA();
    Serial.printf("Heap size:%d\r\n", ESP.getFreeHeap());
  }

  //未連接1s重連
  if ( WiFi.status() != WL_CONNECTED ) {
    if (millis() - lastWiFiCheckTick > 1000) {
      lastWiFiCheckTick = millis();
    }
  }
  //連接成功建立
  else {
    if (taskStarted == false) {
      taskStarted = true;
      Serial.print("\r\nGet IP Address: ");
      Serial.println(WiFi.localIP());
      startTCPClient();
    }
  }
}



// 初始化，相當於main 函數
void setup() {
  Serial.begin(115200);

  //初始化引腳為輸出
	pinMode(LED_Pin,OUTPUT);
}

//循環
void loop() {
  doWiFiTick();
  doTCPClientTick();
}

真的強，我還需要再修煉修煉ovo

運行結果

其中#號進行封裝，28溫度，61濕度，OFF表示LED燈的開啟狀態

微信小程序開發
前往微信小程序平台

設置 - 拿到APPID ： wx71055a3e823092d9
開發 - 開發設置 - 添加 requests 合法域名：https://api.bemfa.com
下載 demo 示例程序並解壓
下載微信開發者工具，導入剛才的文件
導入后，會顯示出數據，然后上傳就行了
回到微信小程序平台，管理 - 版本管理 - 開發版本 - 提交審核，預計1-2天通過

那么這個項目就結束了，在此還是感謝Arduino社區bemfa大神

二、心知天氣[參考taichi-maker]

注冊

傳送門：心知天氣

申請 API 服務

控制台 - 申請免費版
產品管理 - 獲取 API 密鑰 並復制

獲取並解析心知天氣數據

Ⅰ.獲取實時溫度和天氣

#include <ArduinoJson.h>
#include <ESP8266WiFi.h>

const char* ssid     = "Geohot";       // 連接WiFi名
                                           
const char* password = "zheng123+";          // 連接WiFi密碼
                                            
 
const char* host = "api.seniverse.com";     // 將要連接的服務器地址  
const int httpPort = 80;                    // 將要連接的服務器端口      

// 心知天氣HTTP請求所需信息
String reqUserKey = "SnMQITaPAa0oGsIrQ";   // 私鑰，填上自己的
String reqLocation = "Hangzhou";            // 城市
String reqUnit = "c";                      // 攝氏/華氏

void setup(){
  Serial.begin(9600);          
  Serial.println("");
  
  // 連接WiFi
  connectWiFi();
}
 
void loop(){
  // 建立心知天氣API當前天氣請求資源地址
  String reqRes = "/v3/weather/now.json?key=" + reqUserKey +
                  + "&location=" + reqLocation + 
                  "&language=en&unit=" +reqUnit;

  // 向心知天氣服務器服務器請求信息並對信息進行解析
  httpRequest(reqRes);
  delay(3000);
}
 
// 向心知天氣服務器服務器請求信息並對信息進行解析
void httpRequest(String reqRes){
  WiFiClient client;

  // 建立http請求信息
  String httpRequest = String("GET ") + reqRes + " HTTP/1.1\r\n" + 
                              "Host: " + host + "\r\n" + 
                              "Connection: close\r\n\r\n";
  Serial.println(""); 
  Serial.print("Connecting to "); Serial.print(host);

  // 嘗試連接服務器
  if (client.connect(host, 80)){
    Serial.println(" Success!");
 
    // 向服務器發送http請求信息
    client.print(httpRequest);
    Serial.println("Sending request: ");
    Serial.println(httpRequest);  
 
    // 獲取並顯示服務器響應狀態行 
    String status_response = client.readStringUntil('\n');
    Serial.print("status_response: ");
    Serial.println(status_response);
 
    // 使用find跳過HTTP響應頭
    if (client.find("\r\n\r\n")) {
      Serial.println("Found Header End. Start Parsing.");
    }
    
    // 利用ArduinoJson庫解析心知天氣響應信息
    parseInfo(client); 
  } else {
    Serial.println(" connection failed!");
  }   
  //斷開客戶端與服務器連接工作
  client.stop(); 
}

// 連接WiFi
void connectWiFi(){
  WiFi.begin(ssid, password);                  // 啟動網絡連接
  Serial.print("Connecting to ");              // 串口監視器輸出網絡連接信息
  Serial.print(ssid); Serial.println(" ...");  // 告知用戶NodeMCU正在嘗試WiFi連接
  
  int i = 0;                                   // 這一段程序語句用於檢查WiFi是否連接成功
  while (WiFi.status() != WL_CONNECTED) {      // WiFi.status()函數的返回值是由NodeMCU的WiFi連接狀態所決定的。 
    delay(1000);                               // 如果WiFi連接成功則返回值為WL_CONNECTED                       
    Serial.print(i++); Serial.print(' ');      // 此處通過While循環讓NodeMCU每隔一秒鍾檢查一次WiFi.status()函數返回值
  }                                            // 同時NodeMCU將通過串口監視器輸出連接時長讀秒。
                                               // 這個讀秒是通過變量i每隔一秒自加1來實現的。                                              
  Serial.println("");                          // WiFi連接成功后
  Serial.println("Connection established!");   // NodeMCU將通過串口監視器輸出"連接成功"信息。
  Serial.print("IP address:    ");             // 同時還將輸出NodeMCU的IP地址。這一功能是通過調用
  Serial.println(WiFi.localIP());              // WiFi.localIP()函數來實現的。該函數的返回值即NodeMCU的IP地址。  
}

// 利用ArduinoJson庫解析心知天氣響應信息
void parseInfo(WiFiClient client){
  const size_t capacity = JSON_ARRAY_SIZE(1) + JSON_OBJECT_SIZE(1) + 2*JSON_OBJECT_SIZE(3) + JSON_OBJECT_SIZE(6) + 230;
  DynamicJsonDocument doc(capacity);
  
  deserializeJson(doc, client);
  
  JsonObject results_0 = doc["results"][0];
  
  JsonObject results_0_now = results_0["now"];
  const char* results_0_now_text = results_0_now["text"]; // "Sunny"
  const char* results_0_now_code = results_0_now["code"]; // "0"
  const char* results_0_now_temperature = results_0_now["temperature"]; // "32"
  
  const char* results_0_last_update = results_0["last_update"]; // "2020-09-27T16:20:00+08:00" 

  // 通過串口監視器顯示以上信息
  String results_0_now_text_str = results_0_now["text"].as<String>(); 
  int results_0_now_code_int = results_0_now["code"].as<int>(); 
  int results_0_now_temperature_int = results_0_now["temperature"].as<int>(); 
  
  String results_0_last_update_str = results_0["last_update"].as<String>();   

  Serial.println(F("======Weahter Now======="));
  Serial.print(F("Weather Now: "));
  Serial.print(results_0_now_text_str);
  Serial.print(F(" "));
  Serial.println(results_0_now_code_int);
  Serial.print(F("Temperature: "));
  Serial.println(results_0_now_temperature_int);
  Serial.print(F("Last Update: "));
  Serial.println(results_0_last_update_str);
  Serial.println(F("========================"));
}

9600 比特率串口

Ⅱ.獲取天氣預報信息（溫度，天氣，降水概率，風力，風向，濕度）


#include <ArduinoJson.h>
#include <ESP8266WiFi.h>
 
const char* ssid     = "Geohot";       // 連接WiFi名
                                            
const char* password = "zheng123+";          // 連接WiFi密碼
                                           
 
const char* host = "api.seniverse.com";   // 將要連接的服務器地址  
const int httpPort = 80;              // 將要連接的服務器端口      
 
// 心知天氣HTTP請求所需信息
String reqUserKey = "SnMQITaPAa0oGsIrQ";   // 私鑰
String reqLocation = "Hangzhou";            // 城市
String reqUnit = "c";                      // 攝氏/華氏
 
void setup(){
  Serial.begin(9600);          
  Serial.println("");
  
  // 連接WiFi
  connectWiFi();
}
 
void loop(){
  // 建立心知天氣API當前天氣請求資源地址
  String reqRes = "/v3/weather/daily.json?key=" + reqUserKey +
                  + "&location=" + reqLocation + "&language=en&unit=" +
                  reqUnit + "&start=0&days=3";
 
  // 向心知天氣服務器服務器請求信息並對信息進行解析
  httpRequest(reqRes);
  
  delay(3000);
}
 
// 向心知天氣服務器服務器請求信息並對信息進行解析
void httpRequest(String reqRes){
  WiFiClient client;
 
  // 建立http請求信息
  String httpRequest = String("GET ") + reqRes + " HTTP/1.1\r\n" + 
                              "Host: " + host + "\r\n" + 
                              "Connection: close\r\n\r\n";
  Serial.println(""); 
  Serial.print("Connecting to "); Serial.print(host);
 
  // 嘗試連接服務器
  if (client.connect(host, 80)){
    Serial.println(" Success!");
 
    // 向服務器發送http請求信息
    client.print(httpRequest);
    Serial.println("Sending request: ");
    Serial.println(httpRequest);  
 
    // 獲取並顯示服務器響應狀態行 
    String status_response = client.readStringUntil('\n');
    Serial.print("status_response: ");
    Serial.println(status_response);
 
    // 使用find跳過HTTP響應頭
    if (client.find("\r\n\r\n")) {
      Serial.println("Found Header End. Start Parsing.");
    }
    
    // 利用ArduinoJson庫解析心知天氣響應信息
    parseInfo(client); 
  }
  else {
    Serial.println(" connection failed!");
  }   
  //斷開客戶端與服務器連接工作
  client.stop(); 
}
 
// 連接WiFi
void connectWiFi(){
  WiFi.begin(ssid, password);                  // 啟動網絡連接
  Serial.print("Connecting to ");              // 串口監視器輸出網絡連接信息
  Serial.print(ssid); Serial.println(" ...");  // 告知用戶NodeMCU正在嘗試WiFi連接
  
  int i = 0;                                   // 這一段程序語句用於檢查WiFi是否連接成功
  while (WiFi.status() != WL_CONNECTED) {      // WiFi.status()函數的返回值是由NodeMCU的WiFi連接狀態所決定的。 
    delay(1000);                               // 如果WiFi連接成功則返回值為WL_CONNECTED                       
    Serial.print(i++); Serial.print(' ');      // 此處通過While循環讓NodeMCU每隔一秒鍾檢查一次WiFi.status()函數返回值
  }                                            // 同時NodeMCU將通過串口監視器輸出連接時長讀秒。
                                               // 這個讀秒是通過變量i每隔一秒自加1來實現的。                                              
  Serial.println("");                          // WiFi連接成功后
  Serial.println("Connection established!");   // NodeMCU將通過串口監視器輸出"連接成功"信息。
  Serial.print("IP address:    ");             // 同時還將輸出NodeMCU的IP地址。這一功能是通過調用
  Serial.println(WiFi.localIP());              // WiFi.localIP()函數來實現的。該函數的返回值即NodeMCU的IP地址。  
}
 
// 利用ArduinoJson庫解析心知天氣響應信息
void parseInfo(WiFiClient client){
  const size_t capacity = JSON_ARRAY_SIZE(1) + JSON_ARRAY_SIZE(3) + JSON_OBJECT_SIZE(1) + JSON_OBJECT_SIZE(3) + JSON_OBJECT_SIZE(6) + 3*JSON_OBJECT_SIZE(14) + 860;
  
  DynamicJsonDocument doc(capacity);
  
  deserializeJson(doc, client);
  
  JsonObject results_0 = doc["results"][0];
  
  JsonArray results_0_daily = results_0["daily"];
  
  JsonObject results_0_daily_0 = results_0_daily[0];
  const char* results_0_daily_0_date = results_0_daily_0["date"]; 
  const char* results_0_daily_0_text_day = results_0_daily_0["text_day"]; 
  const char* results_0_daily_0_code_day = results_0_daily_0["code_day"];
  const char* results_0_daily_0_text_night = results_0_daily_0["text_night"]; 
  const char* results_0_daily_0_code_night = results_0_daily_0["code_night"]; 
  const char* results_0_daily_0_high = results_0_daily_0["high"];
  const char* results_0_daily_0_low = results_0_daily_0["low"]; 
  const char* results_0_daily_0_rainfall = results_0_daily_0["rainfall"];
  const char* results_0_daily_0_precip = results_0_daily_0["precip"]; 
  const char* results_0_daily_0_wind_direction = results_0_daily_0["wind_direction"]; 
  const char* results_0_daily_0_wind_direction_degree = results_0_daily_0["wind_direction_degree"];
  const char* results_0_daily_0_wind_speed = results_0_daily_0["wind_speed"];
  const char* results_0_daily_0_wind_scale = results_0_daily_0["wind_scale"];
  const char* results_0_daily_0_humidity = results_0_daily_0["humidity"];
  
  JsonObject results_0_daily_1 = results_0_daily[1];
  const char* results_0_daily_1_date = results_0_daily_1["date"];
  const char* results_0_daily_1_text_day = results_0_daily_1["text_day"];
  const char* results_0_daily_1_code_day = results_0_daily_1["code_day"];
  const char* results_0_daily_1_text_night = results_0_daily_1["text_night"]; 
  const char* results_0_daily_1_code_night = results_0_daily_1["code_night"]; 
  const char* results_0_daily_1_high = results_0_daily_1["high"];
  const char* results_0_daily_1_low = results_0_daily_1["low"]; 
  const char* results_0_daily_1_rainfall = results_0_daily_1["rainfall"]; 
  const char* results_0_daily_1_precip = results_0_daily_1["precip"]; 
  const char* results_0_daily_1_wind_direction = results_0_daily_1["wind_direction"];
  const char* results_0_daily_1_wind_direction_degree = results_0_daily_1["wind_direction_degree"]; 
  const char* results_0_daily_1_wind_speed = results_0_daily_1["wind_speed"];
  const char* results_0_daily_1_wind_scale = results_0_daily_1["wind_scale"];
  const char* results_0_daily_1_humidity = results_0_daily_1["humidity"]; 
  
  JsonObject results_0_daily_2 = results_0_daily[2];
  const char* results_0_daily_2_date = results_0_daily_2["date"];
  const char* results_0_daily_2_text_day = results_0_daily_2["text_day"];
  const char* results_0_daily_2_code_day = results_0_daily_2["code_day"];
  const char* results_0_daily_2_text_night = results_0_daily_2["text_night"];
  const char* results_0_daily_2_code_night = results_0_daily_2["code_night"];
  const char* results_0_daily_2_high = results_0_daily_2["high"]; 
  const char* results_0_daily_2_low = results_0_daily_2["low"]; 
  const char* results_0_daily_2_rainfall = results_0_daily_2["rainfall"];
  const char* results_0_daily_2_precip = results_0_daily_2["precip"]; 
  const char* results_0_daily_2_wind_direction = results_0_daily_2["wind_direction"]; 
  const char* results_0_daily_2_wind_direction_degree = results_0_daily_2["wind_direction_degree"]; 
  const char* results_0_daily_2_wind_speed = results_0_daily_2["wind_speed"];
  const char* results_0_daily_2_wind_scale = results_0_daily_2["wind_scale"]; 
  const char* results_0_daily_2_humidity = results_0_daily_2["humidity"]; 
  
  const char* results_0_last_update = results_0["last_update"]; 
  
  // 從以上信息中摘選幾個通過串口監視器顯示
  String results_0_daily_0_date_str = results_0_daily_0["date"].as<String>();
  String  results_0_daily_0_text_day_str = results_0_daily_0["text_day"].as<String>(); 
  int results_0_daily_0_code_day_int = results_0_daily_0["code_day"].as<int>(); 
  String results_0_daily_0_text_night_str = results_0_daily_0["text_night"].as<String>(); 
  int results_0_daily_0_code_night_int = results_0_daily_0["code_night"].as<int>(); 
  int results_0_daily_0_high_int = results_0_daily_0["high"].as<int>();
  int results_0_daily_0_low_int = results_0_daily_0["low"].as<int>();
  String results_0_last_update_str = results_0["last_update"].as<String>();
 
  Serial.println(F("======Today Weahter ======="));
  Serial.print(F("DATE: "));
  Serial.println(results_0_daily_0_date_str);
  Serial.print(F("Day Weather: "));
  Serial.print(results_0_daily_0_text_day_str);
  Serial.print(F(" "));
  Serial.println(results_0_daily_0_code_day_int);
  Serial.print(F("Night Weather: "));
  Serial.print(results_0_daily_0_text_night_str);
  Serial.print(F(" "));
  Serial.println(results_0_daily_0_code_night_int);
  Serial.print(F("High: "));
  Serial.println(results_0_daily_0_high_int);
  Serial.print(F("LOW: "));
  Serial.println(results_0_daily_0_low_int);
  Serial.print(F("Last Update: "));
  Serial.println(results_0_last_update_str);
  Serial.println(F("=============================="));
}

如圖
Ⅲ.獲取實時生活指數（穿衣，紫外線強度，洗車，旅游，感冒，運動）

#include <ArduinoJson.h>
#include <ESP8266WiFi.h>
 
const char* ssid     = "Geohot";       // 連接WiFi名（此處使用taichi-maker為示例）
                                            // 請將您需要連接的WiFi名填入引號中
const char* password = "zheng123+";          // 連接WiFi密碼（此處使用12345678為示例）
                                            // 請將您需要連接的WiFi密碼填入引號中
 
const char* host = "api.seniverse.com";     // 將要連接的服務器地址  
const int httpPort = 80;                    // 將要連接的服務器端口      
 
// 心知天氣HTTP請求所需信息
String reqUserKey = "SnMQITaPAa0oGsIrQ";   // 私鑰
String reqLocation = "Hangzhou";            // 城市
String reqUnit = "c";                      // 攝氏/華氏
 
void setup(){
  Serial.begin(9600);          
  Serial.println("");
  
  // 連接WiFi
  connectWiFi();
}
 
void loop(){
  // 建立心知天氣API當前天氣請求資源地址
  String reqRes = "/v3/life/suggestion.json?key=" + reqUserKey +
                  + "&location=" + reqLocation + 
                  "&language=en";
                  
  // 向心知天氣服務器服務器請求信息並對信息進行解析                               
  httpRequest(reqRes);
  delay(3000);
}
 
// 向心知天氣服務器服務器請求信息並對信息進行解析
void httpRequest(String reqRes){
  WiFiClient client;
 
  // 建立http請求信息
  String httpRequest = String("GET ") + reqRes + " HTTP/1.1\r\n" + 
                              "Host: " + host + "\r\n" + 
                              "Connection: close\r\n\r\n";
  Serial.println(""); 
  Serial.print("Connecting to "); Serial.print(host);
 
  // 嘗試連接服務器
  if (client.connect(host, 80)){
    Serial.println(" Success!");
 
    // 向服務器發送http請求信息
    client.print(httpRequest);
    Serial.println("Sending request: ");
    Serial.println(httpRequest);  
 
    // 獲取並顯示服務器響應狀態行 
    String status_response = client.readStringUntil('\n');
    Serial.print("status_response: ");
    Serial.println(status_response);
 
    // 使用find跳過HTTP響應頭
    if (client.find("\r\n\r\n")) {
      Serial.println("Found Header End. Start Parsing.");
    }
    
    // 利用ArduinoJson庫解析心知天氣響應信息
    parseInfo(client); 
  }
  else {
    Serial.println(" connection failed!");
  }   
  //斷開客戶端與服務器連接工作
  client.stop(); 
}
 
// 連接WiFi
void connectWiFi(){
  WiFi.begin(ssid, password);                  // 啟動網絡連接
  Serial.print("Connecting to ");              // 串口監視器輸出網絡連接信息
  Serial.print(ssid); Serial.println(" ...");  // 告知用戶NodeMCU正在嘗試WiFi連接
  
  int i = 0;                                   // 這一段程序語句用於檢查WiFi是否連接成功
  while (WiFi.status() != WL_CONNECTED) {      // WiFi.status()函數的返回值是由NodeMCU的WiFi連接狀態所決定的。 
    delay(1000);                               // 如果WiFi連接成功則返回值為WL_CONNECTED                       
    Serial.print(i++); Serial.print(' ');      // 此處通過While循環讓NodeMCU每隔一秒鍾檢查一次WiFi.status()函數返回值
  }                                            // 同時NodeMCU將通過串口監視器輸出連接時長讀秒。
                                               // 這個讀秒是通過變量i每隔一秒自加1來實現的。                                              
  Serial.println("");                          // WiFi連接成功后
  Serial.println("Connection established!");   // NodeMCU將通過串口監視器輸出"連接成功"信息。
  Serial.print("IP address:    ");             // 同時還將輸出NodeMCU的IP地址。這一功能是通過調用
  Serial.println(WiFi.localIP());              // WiFi.localIP()函數來實現的。該函數的返回值即NodeMCU的IP地址。  
}
 
// 利用ArduinoJson庫解析心知天氣響應信息
void parseInfo(WiFiClient client){
  const size_t capacity = JSON_ARRAY_SIZE(1) + JSON_OBJECT_SIZE(1) + 6*JSON_OBJECT_SIZE(2) + JSON_OBJECT_SIZE(3) + 2*JSON_OBJECT_SIZE(6) + 400;
  DynamicJsonDocument doc(capacity);
  
  deserializeJson(doc, client);
  
  JsonObject results_0 = doc["results"][0];
  
  JsonObject results_0_suggestion = results_0["suggestion"];
  
  const char* results_0_suggestion_car_washing_brief = results_0_suggestion["car_washing"]["brief"];
  const char* results_0_suggestion_car_washing_details = results_0_suggestion["car_washing"]["details"];
  
  const char* results_0_suggestion_dressing_brief = results_0_suggestion["dressing"]["brief"];
  const char* results_0_suggestion_dressing_details = results_0_suggestion["dressing"]["details"]; 
  
  const char* results_0_suggestion_flu_brief = results_0_suggestion["flu"]["brief"]; 
  const char* results_0_suggestion_flu_details = results_0_suggestion["flu"]["details"]; 
  
  const char* results_0_suggestion_sport_brief = results_0_suggestion["sport"]["brief"]; 
  const char* results_0_suggestion_sport_details = results_0_suggestion["sport"]["details"];
  
  const char* results_0_suggestion_travel_brief = results_0_suggestion["travel"]["brief"];
  const char* results_0_suggestion_travel_details = results_0_suggestion["travel"]["details"]; 
  
  const char* results_0_suggestion_uv_brief = results_0_suggestion["uv"]["brief"]; 
  const char* results_0_suggestion_uv_details = results_0_suggestion["uv"]["details"]; 
  
  const char* results_0_last_update = results_0["last_update"];
 
  // 通過串口監視器顯示以上信息
  String results_0_suggestion_car_washing_brief_str = results_0_suggestion["car_washing"]["brief"];
    
  String results_0_suggestion_dressing_brief_str = results_0_suggestion["dressing"]["brief"];
   
  String results_0_suggestion_flu_brief_str = results_0_suggestion["flu"]["brief"]; 
  
  String results_0_suggestion_sport_brief_str = results_0_suggestion["sport"]["brief"]; 
  
  String results_0_suggestion_travel_brief_str = results_0_suggestion["travel"]["brief"]; 
  
  String results_0_suggestion_uv_brief_str = results_0_suggestion["uv"]["brief"]; 
   
  const char* results_0_last_update_str = results_0["last_update"]; 
  
  Serial.println(F("======Life Info======="));
  Serial.print(F("Car Washing: "));
  Serial.println(results_0_suggestion_car_washing_brief_str);
  Serial.print(F("Dressing: "));
  Serial.println(results_0_suggestion_dressing_brief_str);
  Serial.print(F("Flu: "));
  Serial.println(results_0_suggestion_flu_brief_str);
  Serial.print(F("Sport: "));
  Serial.println(results_0_suggestion_sport_brief_str);
  Serial.print(F("Travel: "));
  Serial.println(results_0_suggestion_travel_brief_str);  
  Serial.print(F("UV: "));
  Serial.println(results_0_suggestion_uv_brief_str);    
  Serial.print(F("Last Update: "));
  Serial.println(results_0_last_update_str);
  Serial.println(F("======================"));
}

如圖

三、結尾

我現在暫時停留在能用會看源代碼階段，C語言也會一些，但上手項目比較少
后面···上課表 = = 可能博客會選擇周更，或者三天一更，盡量保持質量，把學到的都能分享出來

免責聲明！

本站轉載的文章為個人學習借鑒使用，本站對版權不負任何法律責任。如果侵犯了您的隱私權益，請聯系本站郵箱yoyou2525@163.com刪除。

猜您在找 干貨分享 | 3個開發IoT項目的開源物聯網平台項目的上線流程是怎樣的？不同springboot項目的互相調用關於git及項目的歸檔 SpringBoot項目的異常基於SpringBoot項目的https 談談項目的執行二、Maven項目的構建項目的總結與反思項目的用例圖設計