windows ping 帶時間戳

使用方法

新建文本文件,改后綴為 .bat 編輯該文件，將下面代碼拷貝進去，ctrl+s保存一下，雙擊文件運行
效果圖

運行效果：

一秒鍾ping一次目標網絡，
創建ping_host.log文件保存記錄，會覆蓋，意思你用這個腳本運行兩次ping同一個host，第二次的文件會覆蓋第一次的

中止方式：

第一種ctrl+c，會問你是否中止 鍵入 y回車
第二種，直接關閉窗口

結果：

可以看到當前目錄產生了一個.log文件，其實就是一個txt文本文件，只是后綴不一樣，可以用記事本打開看文件

這是我剛才ping的記錄 帶時間戳的

簡化版代碼

@echo off
set /p host=host:
set logfile=ping_%host%.log
echo Target Host=%host% > %logfile%

:loop
for /f "tokens=* skip=2" %%A in ('ping %host% -n 1') do (
	echo %date:~0,-3% %time:~0,-3% %%A>>%logfile%
	echo %date:~0,-3% %time:~0,-3% %%A
	timeout /t 1 /nobreak>nul
	goto loop
)
pause>nul

注解版代碼

略啰嗦 不懂具體指令可以百度

::      這是注釋 文件名 test.bat
@echo off
::      關閉回顯

set /p host=myhost:
::      這是備注/p效果是 需要用戶輸入host，即你要ping的地址
::      設置字符串變量     =后：前為提示

set logfile=ping_%host%.log
::      設置文件名 要重用set設置的變量host 需要兩邊包裹%

echo Target Host=%host% > %logfile%
::       echo 輸出的字符串 >到 輸入的對象
::      >file.txt 輸出字符串到文件；沒有> 默認輸出到屏幕； >nul 輸出到空的對象，指令操作的提示語句不會顯示


::      增強for循環
::      tokens 選擇一行中的分割好的部分 *剩余全部 
::      skip 跳過開頭幾行
::      %date:~0,-3% 日期字符串從第一個到倒數第三個
::      >>a.txt 追加到a.txt里
::      >a.txt 無創建a.txt，有清空a.txt
::      echo str 輸出字符串
::      echo str >>filename 輸出字符串到文件
::      timeout /t waittime /nobreak>nul 等待時間waittime 期間無法停止 >nul 意思不要打印到命令窗口 不顯示
::      ":loop" "goto loop" 循環
::      pause>nul 按任意鍵繼續，不顯示提示

:loop
for /f "tokens=* skip=2" %%A in ('ping %host% -n 1') do (
	echo %date:~0,-3% %time:~0,-3% %%A>>%logfile%
	echo %date:~0,-3% %time:~0,-3% %%A
	timeout /t 1 /nobreak>nul
	goto loop
)
pause>nul