Esp8266連接阿里雲MQTT服務器（arduino編譯器）

前提條件：

arduino開發環境已搭建

阿里雲MQTT服務器已搭建

（搭建方法請參考博客內其他文章）

先放行服務器1883端口，MQTT服務器端口為：1883

輸入你的服務器ip:18083，打開MQTT控制面板

點擊工具Websocket,如圖所示點擊連接，提示連接成功

頁面下拉找到訂閱，輸入主題： /test/onoff/，點擊訂閱，如圖所示

下拉找到消息，主題同樣輸入： /test/onoff/

上燒錄的代碼，打開arduino軟件，復制如下代碼：

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
int deng = 14;  //IO14(D5)
const char* ssid = "路由器WiFi賬號";
const char* password = "路由器WiFi密碼";
const char* mqtt_server = "IP地址"; // 使用HIVEMQ 的信息中轉服務
const char* TOPIC = "/test/onoff/";                     // 訂閱信息主題
const char* client_id = "ID";                   // 標識當前設備的客戶端編號，隨便填

WiFiClient espClient;                                                         // 定義wifiClient實例
PubSubClient client(espClient);                                         // 定義PubSubClient的實例
long lastMsg = 0;                                                               // 記錄上一次發送信息的時長

void setup() {
  pinMode(deng, OUTPUT);                               // 定義板載LED燈為輸出方式
  Serial.begin(115200); 
  setup_wifi();                                                                    //執行Wifi初始化，下文有具體描述
  client.setServer(mqtt_server, 1883);                              //設定MQTT服務器與使用的端口，1883是默認的MQTT端口
  client.setCallback(callback);                                          //設定回調方式，當ESP8266收到訂閱消息時會調用此方法
}

void setup_wifi() {

  delay(10);
  // 板子通電后要啟動，稍微等待一下讓板子點亮
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);   // 打印主題信息
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]); // 打印主題內容
  }
  Serial.println();

  if ((char)payload[0] == '1') {
    digitalWrite(deng, HIGH);   // 亮燈
  } else {
    digitalWrite(deng, LOW);   // 熄燈
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(client_id)) {
      Serial.println("connected");
      // 連接成功時訂閱主題
      client.subscribe(TOPIC);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    client.publish("/test/onoff/", "{device:client_id,'status':'on'}");
  }
}

PubSubClient庫的安裝方法：
點擊工具打開庫管理面板，在搜索欄輸入：PubSubClient
點擊安裝，如圖所示


注意修改代碼中的WiFi賬號與密碼及ip地址，設備的客戶端編號ID
插上Esp8266開發板點擊向右的箭頭開始編譯燒錄，等待編譯成功 100%
燒錄成功后點擊arduino軟件右上角串口監視器查看連接狀態
MQTT控制面板消息中消息輸入1，點擊右側發送則會出現如下圖所示，Esp8266連接MQTT服務器成功



開發板接線圖：左側D5，右側GND

MQTT服務器發送消息 1，則燈點亮，發送 0 則熄滅

參考博客：MQTT之 PubSubClient 庫 https://www.jianshu.com/p/7f54b92d7a7b