一行一行讀取txt里的內容
@echo off
for /f %%i in (C:\Users\86132\Desktop\name.txt) do (
echo %%i>>name2.txt
echo %%i
)
pause
文件夾下的文件遍歷腳本
echo off
cd ..\..\..\Dist\media\gui
FOR /F "delims==" %%i IN ('dir /b') do (
if exist "..\..\..\Tools\texturepack\%%i" (echo %%i ok ) else (echo %%i err)
)
pause
遍歷文件夾，包括子文件夾里的文件名
echo off & color 0A
::指定起始文件夾
set DIR="C:\Users\86132\Desktop\html"
echo DIR=%DIR%
:: 參數 /R 表示需要遍歷子文件夾,去掉表示不遍歷子文件夾
:: %%f 是一個變量,類似於迭代器,但是這個變量只能由一個字母組成,前面帶上%%
:: 括號中是通配符,可以指定后綴名,*.*表示所有文件
for /R %DIR% %%f in (*.php) do (
echo %%f
)
pause
文件監控腳本（包括子目錄），檢測到新添加進來的文件后，調用readfile_line.bat，然后刪除新添加的文件，這個腳本還能用做用作window系統防御落地木馬
@echo off & title 監控文件夾 By 依夢琴瑤
color 0a & mode 35,3
::設置要監控的文件夾
set MtrDir=E:\phpStudy\WWW
::設置要調用的bat腳本
set Bat=readfile_line.bat
echo 正在初始化記錄文件 ...
(for /f "delims=" %%a in ('dir /a-d/s/b "%MtrDir%\*"') do (
echo "%%~a"
))>"%tmp%\oFiles.Lst"
:Loop
set "Change="
cls & echo 正在監控文件夾中 ...
for /f "delims=" %%a in ('dir /a-d/s/b "%MtrDir%"') do (
findstr /i "^\"%%~a\"$" "%tmp%\oFiles.Lst" >nul || (
del /f /q "%%~a"
set Change=1
)
)
if defined Change (
echo 發現新增文件，啟動其它腳本。
start "" "%Bat%"
)
goto Loop
設置代理上網
@echo off
echo 開始設置IE代理上網
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "
http=183.129.207.82:11169;https=183.129.207.82:11169" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /t REG_SZ /d "<-loopback>" /f
echo 代理設置完成按任意鍵關閉
pause>nul
取消代理
@echo off
echo 開始清除IE代理設置
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /f
echo IE代理清楚完成按任意鍵關閉
pause>nul
刪除某個文件夾某種后綴的所有文件
@echo off
del /a /f /s /q C:\Users\86132\Desktop\bingdu\*.sarut