2019 SDN上機第7次作業

1.補充並運行basic代碼

任務是實現基礎的交換機轉發數據包功能

補充后代碼如下：

/* -*- P4_16 -*- */
#include <core.p4>
#include <v1model.p4>

const bit<16> TYPE_IPV4 = 0x800;

/*************************************************************************
*********************** H E A D E R S  ***********************************
*************************************************************************/

typedef bit<9>  egressSpec_t;
typedef bit<48> macAddr_t;
typedef bit<32> ip4Addr_t;

header ethernet_t {
    macAddr_t dstAddr;
    macAddr_t srcAddr;
    bit<16>   etherType;
}

header ipv4_t {
    bit<4>    version;
    bit<4>    ihl;
    bit<8>    diffserv;
    bit<16>   totalLen;
    bit<16>   identification;
    bit<3>    flags;
    bit<13>   fragOffset;
    bit<8>    ttl;
    bit<8>    protocol;
    bit<16>   hdrChecksum;
    ip4Addr_t srcAddr;
    ip4Addr_t dstAddr;
}

struct metadata {
    /* empty */
}

struct headers {
    ethernet_t   ethernet;
    ipv4_t       ipv4;
}

/*************************************************************************
*********************** P A R S E R  ***********************************
*************************************************************************/

parser MyParser(packet_in packet,
                out headers hdr,
                inout metadata meta,
                inout standard_metadata_t standard_metadata) {

    state start {
	transition parse_ethernet;	/*解析以太包頭*/
    }	
    state parse_ethernet
    {	
	packet.extract(hdr.ethernet);   /*根據定義的數據結構提取以太包頭*/
        transition select(hdr.ethernet.etherType) {  /*根據協議類型選擇下一個狀態*/
            0x0800: parse_ipv4;   /*設置為0x0800，parse_ipv4狀態*/
	    default: accept;      /*默認設置為接受*/
        }
    }
    state parse_ipv4
    {        
	packet.extract(hdr.ipv4); /*提取ip包的頭部*/
        transition accept;
    }
}


/*************************************************************************
************   C H E C K S U M    V E R I F I C A T I O N   *************
*************************************************************************/

control MyVerifyChecksum(inout headers hdr, inout metadata meta) {   
    apply {  }
}


/*************************************************************************
**************  I N G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyIngress(inout headers hdr,
                  inout metadata meta,
                  inout standard_metadata_t standard_metadata) {
    action drop() {
        mark_to_drop();
    }
    
    action ipv4_forward(macAddr_t dstAddr, egressSpec_t port) {
        hdr.ethernet.srcAddr = hdr.ethernet.dstAddr;   /*原數據包的源地址改為目的地址*/
    	hdr.ethernet.dstAddr = dstAddr;
	standard_metadata.egress_spec = port; /*從參數中獲取要輸出的端口*/
	hdr.ipv4.ttl = hdr.ipv4.ttl - 1;
    }
    
    table ipv4_lpm {
        key = {
            hdr.ipv4.dstAddr: lpm;
        }
        actions = {
            ipv4_forward;
            drop;
            NoAction;
        }
        size = 1024;
        default_action = NoAction();
    }
    
    apply {
        if (hdr.ipv4.isValid())
        {
          ipv4_lpm.apply(); /*這里要求搞定入口協議邏輯編寫，即數據包處理邏輯，條件是ipv4頭部有效時ipv4_lpm可以使用*/
        }
    }
}

/*************************************************************************
****************  E G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyEgress(inout headers hdr,
                 inout metadata meta,
                 inout standard_metadata_t standard_metadata) {
    apply {  }
}

/*************************************************************************
*************   C H E C K S U M    C O M P U T A T I O N   **************
*************************************************************************/

control MyComputeChecksum(inout headers hdr, inout metadata meta) {
     apply {
	update_checksum(
	    hdr.ipv4.isValid(),
            { hdr.ipv4.version,
	      hdr.ipv4.ihl,
              hdr.ipv4.diffserv,
              hdr.ipv4.totalLen,
              hdr.ipv4.identification,
              hdr.ipv4.flags,
              hdr.ipv4.fragOffset,
              hdr.ipv4.ttl,
              hdr.ipv4.protocol,
              hdr.ipv4.srcAddr,
              hdr.ipv4.dstAddr },
            hdr.ipv4.hdrChecksum,
            HashAlgorithm.csum16);
    }
}


/*************************************************************************
***********************  D E P A R S E R  *******************************
*************************************************************************/

control MyDeparser(packet_out packet, in headers hdr) { /*數據包重組*/
    apply {
       packet.emit(hdr.ethernet);
       packet.emit(hdr.ipv4);
    }
}

/*************************************************************************
***********************  S W I T C H  *******************************
*************************************************************************/

V1Switch(
MyParser(),
MyVerifyChecksum(),
MyIngress(),
MyEgress(),
MyComputeChecksum(),
MyDeparser()
) main;

接着打開終端，進入basic文件夾，輸入make run編譯運行

在mininet界面進行ping通測試，先是將數據包從h1發送到h2
再就是進行全部主機之間的連通測試
如果都連通，證明代碼補充成功

流程圖

2.補充並運行支持基本隧道協議的basic_tunnel代碼

任務是定義新的頭部類型並修改交換機部分的代碼，從而將消息封裝進IP數據包並讓目標端口使用新的頭部類型

補充后代碼如下：

/* -*- P4_16 -*- */
#include <core.p4>
#include <v1model.p4>

// NOTE: new type added here
const bit<16> TYPE_MYTUNNEL = 0x1212;
const bit<16> TYPE_IPV4 = 0x800;

/*************************************************************************
*********************** H E A D E R S  ***********************************
*************************************************************************/

typedef bit<9>  egressSpec_t;
typedef bit<48> macAddr_t;
typedef bit<32> ip4Addr_t;

header ethernet_t {
    macAddr_t dstAddr;
    macAddr_t srcAddr;
    bit<16>   etherType;
}

// NOTE: added new header type
header myTunnel_t {
    bit<16> proto_id;
    bit<16> dst_id;
}

header ipv4_t {
    bit<4>    version;
    bit<4>    ihl;
    bit<8>    diffserv;
    bit<16>   totalLen;
    bit<16>   identification;
    bit<3>    flags;
    bit<13>   fragOffset;
    bit<8>    ttl;
    bit<8>    protocol;
    bit<16>   hdrChecksum;
    ip4Addr_t srcAddr;
    ip4Addr_t dstAddr;
}

struct metadata {
    /* empty */
}

// NOTE: Added new header type to headers struct
struct headers {
    ethernet_t   ethernet;
    myTunnel_t   myTunnel;
    ipv4_t       ipv4;
}

/*************************************************************************
*********************** P A R S E R  ***********************************
*************************************************************************/
parser MyParser(packet_in packet,
                out headers hdr,
                inout metadata meta,
                inout standard_metadata_t standard_metadata) {

    state start {
        transition parse_ethernet;
    }

    state parse_ethernet {
        packet.extract(hdr.ethernet);
        transition select(hdr.ethernet.etherType) {
            TYPE_IPV4 : parse_ipv4;
	    TYPE_MYTUNNEL: parse_myTunnel;  /*設置mytunnel頭類型對應的以太類型為ipv4*/
            default : accept;
        }
    }

     state parse_myTunnel /*要求更新解析器，解析mytunnel頭部，那么添加mytunnel頭類型。其中類型字段為16位的proto_id*/
    {
        packet.extract(hdr.myTunnel);
        transition select(hdr.myTunnel.proto_id) 
	{
            TYPE_IPV4: parse_ipv4;
            default: accept;
        }
    }

    state parse_ipv4 {
        packet.extract(hdr.ipv4);
        transition accept;
    }


}

/*************************************************************************
************   C H E C K S U M    V E R I F I C A T I O N   *************
*************************************************************************/

control MyVerifyChecksum(inout headers hdr, inout metadata meta) {   
    apply {  }
}


/*************************************************************************
**************  I N G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyIngress(inout headers hdr,
                  inout metadata meta,
                  inout standard_metadata_t standard_metadata) {
    action drop() {
        mark_to_drop();
    }
    
    action ipv4_forward(macAddr_t dstAddr, egressSpec_t port) {
        standard_metadata.egress_spec = port;
        hdr.ethernet.srcAddr = hdr.ethernet.dstAddr;
        hdr.ethernet.dstAddr = dstAddr;
        hdr.ipv4.ttl = hdr.ipv4.ttl - 1;
    }
    
    table ipv4_lpm {
        key = {
            hdr.ipv4.dstAddr: lpm;
        }
        actions = {
            ipv4_forward;
            drop;
            NoAction;
        }
        size = 1024;
        default_action = drop();
    }

    action myTunnel_forward(egressSpec_t port) {  /*要求定義一個新動作，將出口端口設置為控制平面提供的端口號*/
        standard_metadata.egress_spec = port;
    }
 
    table myTunnel_exact {    /*要求定義一個新表，將它的dstid匹配mytunnel字段，如果myTunnel_forward存在匹配項，就調用drop操作*/
        key = {
            hdr.myTunnel.dst_id: exact;
        }
        actions = {
            myTunnel_forward;
            drop;
        }
        size = 1024;
        default_action = drop();
    }

    apply {
        if (hdr.ipv4.isValid()&&!hdr.myTunnel.isValid()) {  /*處理未經過通道的ipv4包*/
            ipv4_lpm.apply();
        }
	if (hdr.myTunnel.isValid()) { /* 處理經過通道的ipv4包*/
            myTunnel_exact.apply();
        }
    }
}

/*************************************************************************
****************  E G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyEgress(inout headers hdr,
                 inout metadata meta,
                 inout standard_metadata_t standard_metadata) {
    apply {  }
}

/*************************************************************************
*************   C H E C K S U M    C O M P U T A T I O N   **************
*************************************************************************/

control MyComputeChecksum(inout headers  hdr, inout metadata meta) {
     apply {
	update_checksum(
	    hdr.ipv4.isValid(),
            { hdr.ipv4.version,
	      hdr.ipv4.ihl,
              hdr.ipv4.diffserv,
              hdr.ipv4.totalLen,
              hdr.ipv4.identification,
              hdr.ipv4.flags,
              hdr.ipv4.fragOffset,
              hdr.ipv4.ttl,
              hdr.ipv4.protocol,
              hdr.ipv4.srcAddr,
              hdr.ipv4.dstAddr },
            hdr.ipv4.hdrChecksum,
            HashAlgorithm.csum16);
    }
}

/*************************************************************************
***********************  D E P A R S E R  *******************************
*************************************************************************/

control MyDeparser(packet_out packet, in headers hdr) {
    apply {
        packet.emit(hdr.ethernet);
        packet.emit(hdr.myTunnel); /*把通道頭部加進去*/
        packet.emit(hdr.ipv4);
    }
}

/*************************************************************************
***********************  S W I T C H  *******************************
*************************************************************************/

V1Switch(
MyParser(),
MyVerifyChecksum(),
MyIngress(),
MyEgress(),
MyComputeChecksum(),
MyDeparser()
) main;

接着打開終端，進入basic_tunnel文件夾，輸入make run編譯運行

在mininet命令提示符界面輸入xterm h1 h2來模擬兩個終端

先在主機2的xterm界面輸入

./receive.py

啟動服務器

接着在主機1的xterm界面輸入

./send.py 10.0.2.2 "P4 is cool"

發送信息

檢查主機2的xterm界面，可以看到已經接收到了信息，內容包括以太頭部，IP頭部，TCP頭部以及發送的信息

接着在主機1的xterm界面更改dst_id，再次發送信息

./send.py 10.0.2.2 "P4 is cool" --dst_id 2

檢查主機2的xterm界面，可以看到已經接收到了信息，內容包括以太頭部，IP頭部，TCP頭部以及發送的信息

接着在主機1的xterm界面修改IP地址，再一次發送信息

./send.py 10.0.3.3 "P4 is cool" --dst_id 2

檢查主機2的xterm界面，可以看到已經接收到了信息，IP地址變更為了主機3的地址，這是因為交換機不再使用IP頭部數據來定位，而是用數據包中的隧道頭部數據來定位

3.對P4的認識和體會

初次接觸P4，了解到它作為一種數據面的編程語言 ，克服了OpenFlow協議的局限性， 定義我們想要的數據面。進而再通過南向協議添加流表項，可以更方便地定位數據包發送的目標地址，但我目前僅能通過官方教程和老師指點學到些許皮毛，僅僅能完善官方提供好框架的basic代碼來實現交換機的數據包轉發情景，我自己仍然有着極大的不足，我需要更加努力學習，虛心向老師請教，盡力學好P4這一方便又高深的編程語言