Oracle字符串函數處理

1、字符串是否包含數字

 select regexp_substr('SFDSDF','[0-9]+') from dual;空不包含數字，不為空包含數字

2、字符串是否包含字母

select 1 from dual where regexp_like('12123A123','.([a-z]+|[A-Z])')

3、字符串是否包含漢字

select 1 from dual where ASCIISTR('你好hello') like '%\%'

4、字符串截取

select substr('524419k0791243374H',9,9) from dual

 5、組織機構代碼校驗

CREATE OR REPLACE FUNCTION CHECKORGCODE(organizationCode VARCHAR2)
/*
功能：驗證組織機構代碼，成功返回1，失敗返回0
organizationCode：要驗證的組織機構代碼
*/
RETURN NUMBER AS
codeSum NUMBER(10) := 0;
code VARCHAR(100);
code_9 varchar(1);
C9 NUMBER(2);
/*字符與字符的值，每個字符后兩位為該字符的字符數值*/
Ci CHAR(250) := '000101202303404505606707808909A10B11C12D13E14F15G16H17I18J19K20L21M22N23O24P25Q26R27S28T29U30V31W32X33Y34Z35';
/*前8位字符的加權因子*/
type v_ar is varray(10) of number;
Wi v_ar := v_ar(3, 7, 9, 10, 5, 8, 4, 2);
BEGIN
/*判斷是否為null*/
IF (organizationCode is NULL) THEN
BEGIN
RETURN 0;
END;
END IF;

code := RTRIM(LTRIM(REPLACE(organizationCode, '-', ''))); /*把-,前后空格去掉*/

/*驗證長度是否正確*/
/*驗證機構代碼是由數字和大寫字母組成*/
IF (LENGTH(code) != 9 or NOT REGEXP_LIKE(code, '^[A-Z0-9]+$')) THEN
BEGIN
RETURN 0;
END;
END IF;

/*前8位字符的字符數值分別乘於該位的加權因子，然后求和*/
for i in 1 .. Wi.count loop
codeSum := codeSum +
to_Number(substr(Ci, INSTR(Ci, substr(code, i, 1)) + 1, 2)) *
Wi(i);
end loop;

/* 計算校驗碼C9*/
C9 := 11 - (codeSum MOD 11);
code_9 := substr(code, 9, 1);

/*驗證校驗碼C9*/
/*當C9的值為10時，校驗碼應是拉丁字母X */
/*當C9的值為11時校驗碼應是0*/
/*驗證第9位是否等於計算出的校驗結果*/
IF ((C9 = 10 and code_9 = 'X') or (C9 = 11 and code_9 = '0') or
(code_9 = to_char(C9))) THEN
BEGIN
return 1;
END;
END IF;

RETURN 0;
EXCEPTION
WHEN OTHERS THEN
raise;
END;

6、身份證校驗

CREATE OR REPLACE FUNCTION fn_checkidcard (p_idcard IN VARCHAR2) RETURN INT
IS
/*校驗身份證*/
v_regstr VARCHAR2 (2000);
v_sum NUMBER;
v_mod NUMBER;
v_checkcode CHAR (11) := '10X98765432';
v_checkbit CHAR (1);
v_areacode VARCHAR2 (2000) := '11,12,13,14,15,21,22,23,31,32,33,34,35,36,37,41,42,43,44,45,46,50,51,52,53,54,61,62,63,64,65,71,81,82,91,';
BEGIN
CASE LENGTHB (p_idcard)
WHEN 15
THEN -- 15位
IF INSTRB (v_areacode, SUBSTR (p_idcard, 1, 2) || ',') = 0 THEN
RETURN 0;
END IF;

IF MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 2)) + 1900, 400) = 0
OR
(
MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 2)) + 1900, 100) <> 0
AND
MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 2)) + 1900, 4) = 0
)
THEN -- 閏年
v_regstr :=
'^[1-9][0-9]{5}[0-9]{2}((01|03|05|07|08|10|12)(0[1-9]|[1-2][0-9]|3[0-1])|(04|06|09|11)(0[1-9]|[1-2][0-9]|30)|02(0[1-9]|[1-2][0-9]))[0-9]{3}$';
ELSE
v_regstr :=
'^[1-9][0-9]{5}[0-9]{2}((01|03|05|07|08|10|12)(0[1-9]|[1-2][0-9]|3[0-1])|(04|06|09|11)(0[1-9]|[1-2][0-9]|30)|02(0[1-9]|1[0-9]|2[0-8]))[0-9]{3}$';
END IF;

IF REGEXP_LIKE (p_idcard, v_regstr) THEN
RETURN 1;
ELSE
RETURN 0;
END IF;
WHEN 18
THEN -- 18位
IF INSTRB (v_areacode, SUBSTRB (p_idcard, 1, 2) || ',') = 0 THEN
RETURN 0;
END IF;

IF MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 4)), 400) = 0
OR
(
MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 4)), 100) <> 0
AND
MOD (TO_NUMBER (SUBSTRB (p_idcard, 7, 4)), 4) = 0
)
THEN -- 閏年
v_regstr :=
'^[1-9][0-9]{5}(19|20)[0-9]{2}((01|03|05|07|08|10|12)(0[1-9]|[1-2][0-9]|3[0-1])|(04|06|09|11)(0[1-9]|[1-2][0-9]|30)|02(0[1-9]|[1-2][0-9]))[0-9]{3}[0-9Xx]$';
ELSE
v_regstr :=
'^[1-9][0-9]{5}(19|20)[0-9]{2}((01|03|05|07|08|10|12)(0[1-9]|[1-2][0-9]|3[0-1])|(04|06|09|11)(0[1-9]|[1-2][0-9]|30)|02(0[1-9]|1[0-9]|2[0-8]))[0-9]{3}[0-9Xx]$';
END IF;

IF REGEXP_LIKE (p_idcard, v_regstr) THEN
v_sum :=
( TO_NUMBER (SUBSTRB (p_idcard, 1, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 11, 1))
)
* 7
+ ( TO_NUMBER (SUBSTRB (p_idcard, 2, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 12, 1))
)
* 9
+ ( TO_NUMBER (SUBSTRB (p_idcard, 3, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 13, 1))
)
* 10
+ ( TO_NUMBER (SUBSTRB (p_idcard, 4, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 14, 1))
)
* 5
+ ( TO_NUMBER (SUBSTRB (p_idcard, 5, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 15, 1))
)
* 8
+ ( TO_NUMBER (SUBSTRB (p_idcard, 6, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 16, 1))
)
* 4
+ ( TO_NUMBER (SUBSTRB (p_idcard, 7, 1))
+ TO_NUMBER (SUBSTRB (p_idcard, 17, 1))
)
* 2
+ TO_NUMBER (SUBSTRB (p_idcard, 8, 1)) * 1
+ TO_NUMBER (SUBSTRB (p_idcard, 9, 1)) * 6
+ TO_NUMBER (SUBSTRB (p_idcard, 10, 1)) * 3;
v_mod := MOD (v_sum, 11);
v_checkbit := SUBSTRB (v_checkcode, v_mod + 1, 1);

IF v_checkbit = upper(substrb(p_idcard,18,1)) THEN
RETURN 1;
ELSE
RETURN 0;
END IF;
ELSE
RETURN 0;
END IF;
ELSE
RETURN 0; -- 身份證號碼位數不對
END CASE;
EXCEPTION
WHEN OTHERS
THEN
RETURN 0;
END fn_checkidcard;

校驗統一社會信用代碼只需要從第九位字符截取9位放入組織機構校驗函數校驗即可。