n 介紹
在編寫pl/sql程序是，可以定義變量和常量；在pl/sql程序中包括有：
①標量類型（scalar）
②復合類型（composite）
③參照類型（reference）
④lob（large object）
標量（scalar）一常用類型
在編寫pl/sql塊時，如果要使用變量，需在定義部分定義變量。
n pl/sql中定義變量和常量的語法如下：
identifier [constant] datatype [not null][:=|default expr]
identifier：名稱
constant：指定常量，需要指定它的初始值，且其值是不能改變的
datatype：數據類型
not null：指定變量值不能為null
:= ： 給變量或是常量指定初始值
default：用於指定初始值
expr：指定初始值的pl/sql表達式，可以是文本值、其它變量、函數等
n 標量定義的案例
①定義一個變長字符串
v_ename varchar2(10)
②定義一個小數 范圍-9999.99~9999.99
v_sal number（6，2）；
③定義一個小數並給一個初始值為5.4：=是pl/sql的賦值號
v_sal2number（6,2）:=5.4
④定義一個日期類型的數據
v_hiredate date；
⑤定義一個布爾變量，不能為空，初始值為false
v_valid boolean：=false；
n 標量（scalar）一使用標量
在定義好變量后，就可以使用這些變量。這里需要說明的是pl/sql塊為變量賦值不同於其它編程語言，需要在等號前加冒號（:=）
案例：以輸入工號，顯示雇員姓名、工資、個人所得稅（稅率為0.03）為例，說明變量的使用，看看如何編寫。
create or replace procedure pro1(v_in_empno in number) is
v_tax_rate number(3,2):=0.03;
v_sal number;
v_ename varchar2(32);
v_tax number;
begin
select ename,sal into v_ename,v_sal from emp where empno=v_in_empno;
v_tax:=v_sal*v_tax_rate;
dbms_output.put_line(v_ename||'工資是 '||v_sal||' 個人所得稅是 '||v_tax);
end;
n 標量（scalar）一使用%type類型
對於上面的pl/sql塊有一個問題：
就是如果員工的姓名超過了5個字符的話，就會有錯誤，為了降低pl/sql程序的維護工作量，可以使用%type屬性定義變量，這樣它會按照數據庫列來確定你定義的變量的類型和長度。
為了讓我們在pl/sql編程中，讓變量的類型和大小與表的列的大小和類型一致可以使用%type。
我們看看這個怎么使用：
標識符名 表名.列名%type；
create or replace procedure pro1(v_in_empno in number) is
v_tax_rate number(3,2):=0.03;
v_sal emp.sal%type; --為了讓V_sal的類型更加靈活，使用%type自適應
v_ename emp.ename%type;
v_tax number;
begin
select ename,sal into v_ename,v_sal from emp where empno=v_in_empno;
v_tax:=v_sal*v_tax_rate;
dbms_output.put_line(v_ename||'工資是 '||v_sal||' 個人所得稅是 '||v_tax);
end;
n 復合變量（composite）
用於存放多個值的變量。常用的包括這：
①pl/sql記錄 ②pl/sql表
n 復合類型一pl/sql記錄
類似與高級語言中的結構體，需要注意的是，當引用pl/sql記錄成員時，必須要加記錄變量作為前綴（記錄變量.記錄成員)如下：
|
請編寫一個過程，該過程可以接收一個用戶編號，並顯示該用戶的名字、薪水、工資崗位（注意：要求用pl/sql記錄實現）
create or replace procedure pro1(v_in_empno in number) is
type lsz_emp_record is record(
v_ename emp.ename%type,
v_sal emp.sal%type,
v_job emp.job%type);
v_emp_record lsz_emp_record;
begin
select ename,sal,job into v_emp_record from emp where empno=v_in_empno;
dbms_output.put_line('名字：'||v_emp_record.v_ename||' 工資:'||v_emp_record.v_sal);
end;
n 復合類型一pl/sql表（了解即可）
類似與高級語言中的數組，但是需要注意的是在高級語言中數組的下標不能為負數，而pl/sql是可以為負數的，並且表元素的下標沒有限制，實例如下：
declare
type sp_table_type is table of emp.ename%type
index by binary_integer;
sp_table sp_table_type; --定義一個變量：sp_table:類型
begin
select ename into sp_table(-1) from emp where empno=7788;
dbms_output.put_line(‘員工名：’||sp_table(-1));
end;
說明： sp_table_type 是pl/sql表類型
emp.ename%type 指定了表的元素的類型和長度
sp_table 為pl/sql表變量
sp_table(0) 則表示下標為0的元素
n 參照變量一介紹
參照變量是指用於存放數值指針的變量，通過使用參照變量，可以使得應用程序共享相同對象，從而降低占用的空間。在編寫pl/sql程序是，可以使用游標變量（ref cursor）和對象類型變量（ref obj_type）兩種參照變量類型。
n 參照變量-ref cursor使用
|
|||||||
|
|||||||
|
|||||||
|
|||||||
通過游標，我們可以取得返回結果集（這個結果集，往往是select語句的結果）的任何一行數據，從而提高共享的效率
使用游標：當定義游標時不需要指定相應的select語句，但是當使用游標時（open）需要指定select語句，這樣一個游標就與一個select語句結合了。實例如下：
①請使用pl/sql編寫一個過程，可以輸入部門號，並顯示該部門所有員工姓名和他的工資。
create or replace procedure pro1(v_in_deptno number) is
--先定義一個游標變量類型
type lsz_emp_cursor is ref cursor;
--定義一個游標變量
v_emp_cursor lsz_emp_cursor;
--定義兩個變量
v_ename emp.ename%type;
v_sal emp.sal%type;
begin
--執行語句
open v_emp_cursor for select ename,sal from emp where deptno=v_in_deptno;
--取出游標指向的每行數據，用循環語句
loop
fetch v_emp_cursor into v_ename,v_sal;--這句話會引起v_emp_cursor向下走一格
--判斷當前游標是否到達最后
exit when v_emp_cursor%notfound;
--輸出
dbms_output.put_line('用戶名：'||v_ename||' 薪水：'||v_sal);
end loop;
--關閉游標（完成后一定要記住關閉游標）
close v_emp_cursor;
end;
②在①的基礎上，如果某個員工的工資低於200元，就增加100元。
create or replace procedure pro1(v_in_deptno number) is
--先定義一個游標變量類型
type lsz_emp_cursor is ref cursor;
--定義一個游標變量
v_emp_cursor lsz_emp_cursor;
--定義兩個變量
v_ename emp.ename%type;
v_sal emp.sal%type;
v_empno emp.empno%type;
begin
--執行語句
open v_emp_cursor for select ename,sal,empno from emp where deptno=v_in_deptno;
--取出游標指向的每行數據，用循環語句
loop
fetch v_emp_cursor into v_ename,v_sal,v_empno;--這句話會引起v_emp_cursor向下走一格
--判斷當前游標是否到達最后
exit when v_emp_cursor%notfound;
--輸出
--dbms_output.put_line('用戶名：'||v_ename||' 薪水：'||v_sal);
if v_sal<1500 then
update emp set sal=sal+100 where empno=v_empno;
end if;
end loop;
--關閉游標（完成后一定要記住關閉游標）
close v_emp_cursor;
end;