效果圖
前言
記得上高二的時候,閑來無事,上b站搜電腦病毒的視頻看(不要問我為什么會搜這個),看到一個很有意思的"病毒",其實也不算病毒,它會控制桌面圖標形成一個人形,並跳舞,跳完之后電腦就藍屏了.之后下定決心也要整一個,埋頭研究了兩個星期吧,寫了一個貪吃蛇,此貪吃蛇非彼貪吃蛇,它當然是控制的桌面圖標來玩啦,還寫了個網絡版的,通過手機去控制.
貪吃蛇效果
本文章只介紹如何移動圖標,不介紹貪吃蛇實現(源碼太多),可以評價私信要源碼
實現思路
說到這,真的很后悔以前沒第一個學c語言,反而學了vb,現在被其他語言搞得沒有精力去學了,並沒有說vb不好,它也很強大,只是它封裝了很多,讓很多人接觸底層得知識更少了,比如窗體,歸根到底,所有窗體都是用CreateWindow 函數來創建,但是學了vb,誰會傻到在用CreateWindow來創建窗口呢?
好了,說原理吧.
首先要了解什么是句柄,通俗得講它就是一個整數,具體它標識窗口、位圖、畫筆等對象,並且是不變得整數,就像身份證一樣,當人出生后,必定會有一個18位的身份證號,並且是不變得,通過它,可以知道某人得姓名,地址,年齡等信息,句柄也是如此.
上面所說的CreateWindow,當它成功創建一個窗口后,它的返回值就是一個句柄,你拿到這個句柄后,你就可以對它做你想做的事了,比如用SetWindowText 給它設置一個標題.
明白了句柄,現在就要拿到桌面的句柄,對它進行控制,用spy++可以分析一下它
這里有一點不一樣,在windows7中,它的父窗口類名是Program Manage,但是在windows10中,它的類名是WorkerW,並且有多個WorkerW.下圖是windows 7中
但是這不影響我們.從中可以看到,桌面就是一個ListView,我們只要拿到它的句柄,就可以對他進行控制.
獲取桌面句柄
需要用到api:
FindWindow:根據窗口的類名和窗口名稱匹配指定的窗口,並且返回這個窗口的句柄
FindWindowEx:根據所在的父窗口中查找類名和窗口名稱匹配的窗口,並且返回這個窗口的句柄
查找桌面句柄如下.
注:在win7下可就不這么寫了,
Private Function getDesktopHwnd() As Long
Dim hwndWorkerW As Long, hwndShelldll As Long, hwndDesktop As Long
Do While (hwndDesktop = 0)
hwndWorkerW = FindWindowEx(0, hwndWorkerW, "WorkerW", vbNullString)
If (hwndWorkerW <> 0) Then
hwndShelldll = FindWindowEx(hwndWorkerW, 0, "SHELLDLL_DefView", vbNullString)
hwndDesktop = FindWindowEx(hwndShelldll, 0, "SysListView32", vbNullString)
End If
Loop
getDesktopHwnd = hwndDesktop
End Function
移動圖標
知道了桌面的句柄,然后就是移動圖標了
既然桌面就是一個ListView,那么只需要給ListView發送一個LVM_SETITEMPOSITION消息來設置item的位置.
如果你對windows機制不太了解的話,可能不明白為何要這樣做,簡單說一下,windows是根據消息來驅動程序運行的,例如，單擊鼠標、改變窗口尺寸、按下鍵盤上的一個鍵都會使Windows發送一個消息給應用程序,應用程序會在一個叫窗口過程函數的地方處理消息,windows定義了大量的消息,列入:WM_CLOSE,對這個窗口發送WM_CLOSE,如果應用程序不做特殊處理的話,窗口就會關閉,
如果對ListView操作的話,就需要發送以LVM開頭的消息,WM開頭的是窗口消息,還有對列表框的消息LB_xxx
發送消息可以用SendMessage函數或PostMessage,區別在於使用PostMessage是立即返回,SendMessage需要等待應用程序處理完之后返回,在這里我們也不需要等待程序返回,所以用PostMessage.
看一下PostMeeage的定義
參數hwnd:消息接收的窗口句柄
參數msg:具體消息
參數wparam和lparam:其他特定於消息的信息。
在看一下LVM_SETITEMPOSITION消息的定義
也就是說,使用PostMeeage投遞LVM_SETITEMPOSITION消息的時候,參數wparam是某個圖標的索引,lparam是位置.
但是如何用一個整數標識一個坐標呢,在c中可以用MAKELPARAM來獲取,vb中可沒有這樣的方法,那就自己寫一個
Public Function MAKELPARAM(ByVal l As Integer, ByVal h As Integer) As Long
Dim ll As String
Dim lh As String
Dim r As String
ll = Format(Hex(l), "@@@@")
lh = Format(Hex(h), "@@@@")
Dim result As Long
result = CLng("&h" & Replace(lh & ll, " ", "0"))
MAKELPARAM = result
End Function
全部代碼
Private Const LVM_FIRST As Long = &H1000
Private Declare Function GetDesktopWindow Lib "user32.dll" () As Long
Private Const LVM_SETITEMPOSITION32 As Long = (LVM_FIRST + 49)
Private Declare Function PostMessage Lib "user32.dll" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function EnumWindows Lib "user32.dll" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long
Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32.dll" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Const LVM_SETITEMPOSITION As Long = (LVM_FIRST + 15)
Private Type POINTAPI
x As Long
y As Long
End Type
Dim curPoint As POINTAPI
Dim listViewhwnd As Long
Public Function MAKELPARAM(ByVal l As Integer, ByVal h As Integer) As Long
Dim ll As String
Dim lh As String
Dim r As String
ll = Format(Hex(l), "@@@@")
lh = Format(Hex(h), "@@@@")
Dim result As Long
result = CLng("&h" & Replace(lh & ll, " ", "0"))
MAKELPARAM = result
End Function
Private Function getDesktopHwnd() As Long
Dim hwndWorkerW As Long, hwndShelldll As Long, hwndDesktop As Long
Do While (hwndDesktop = 0)
hwndWorkerW = FindWindowEx(0, hwndWorkerW, "WorkerW", vbNullString)
If (hwndWorkerW <> 0) Then
hwndShelldll = FindWindowEx(hwndWorkerW, 0, "SHELLDLL_DefView", vbNullString)
hwndDesktop = FindWindowEx(hwndShelldll, 0, "SysListView32", vbNullString)
End If
Loop
getDesktopHwnd = hwndDesktop
End Function
Private Sub Form_Load()
listViewhwnd = getDesktopHwnd()
End Sub
Private Sub Timer1_Timer()
curPoint.x = curPoint.x + 10
PostMessage listViewhwnd, LVM_SETITEMPOSITION, 10, MAKELPARAM(curPoint.x, 110)
End Sub
注:右擊桌面--->查看---->自動排列圖標 、將圖標和網格對齊 需要取消勾選