windows服務器修改遠程登錄的端口+防火牆配置

 

話不多說，一個bat文件，快速修改注冊表端口。你只需要做的是另外防火牆添加例外端口后重啟即可。經測試2008-2012-2016-2019正常使用！

 

@echo off
rem 查找端口號
for /f "skip=4 tokens=3 delims= " %%i in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber') do (set value16=%%i)
set value=%value16:~2%
rem echo %value%
setlocal EnableDelayedExpansion
set "str=0123456789ABCDEF"
for /l %%a in (0 1 15) do (
 set -%%a=!str:~%%a,1!
 set -!str:~%%a,1!=%%a
)
for /l %%a in (0 1 100) do (
if not "!value:~%%a,1!"=="" (
call set sun=%%-!value:~%%a,1!%% !sun!
))
rem echo !sun!
set /a nnn=1,num=0
for %%a in (!sun!) do (
rem set num0=!num!
set /a num=%%a*nnn+num
rem echo num = %%a*!nnn! + !num0! = !num!
set /a nnn*=16
)
rem echo 當前遠程桌面端口號為十六進制: %value16% 即 %value%
echo 修改后重啟系統生效，記得把新端口加入防火牆.
rem setlocal DisableDelayedExpansion
rem 以下是系統默認
goto xiugai
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 3389:TCP /t REG_SZ /d 3389:TCP:*:Enabled:@xpsp2res.dll,-22009 /f
:xiugai
set PortNumber=
set /p PortNumber=輸入即將修改的十進制端口號(1024-65535):
rem if "%PortNumber%"=="" exit
if not defined PortNumber (set /a PortNumber=3389 & echo 未輸入端口號，即將修改為默認值!PortNumber! & pause)
echo %PortNumber%|findstr "^[0-9]*$" >nul || (echo 必須純數字! & goto xiugai)
if %PortNumber% lss 1024 (echo 端口號不能小於1024 & goto xiugai)
if %PortNumber% gtr 65535 (echo 端口號不能大於65535 & goto xiugai)
echo %PortNumber%
rem 修改端口后開啟
rem 總開關
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
rem 修改端口號,默認會直接修改十進制值,注意：范圍在1024到65535，而且不能沖突，事實上，只修改第二處WinStations那一個也是可以的。
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v PortNumber /t REG_DWORD /d %PortNumber% /f
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %PortNumber% /f
@reg delete HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List /v !num!:TCP /f
@reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v %PortNumber%:TCP /t REG_SZ /d %PortNumber%:TCP:*:Enabled:@xpsp2res.dll,-22009 /f

 

復制我上述代碼后新建文本txt粘貼進去，將文件命名為xx.bat文件即可，然后雙擊文件。輸入自定義端口，比如6679，然后回車，把6679放行防火牆然后重啟即可。