SQL SERVER 正則替換

本文轉載自查看原文 2019-06-13 17:54 1287 SQL Server/ SQL

RegExp對象提供簡單的正則表達式支持功能：

1.Global屬性設置或返回一個 Boolean 值，該值指明在整個搜索字符串時模式是全部匹配還是只匹配第一個。
　　語法：
object.Global [= True | False ]
　　 object 參數總是 RegExp 對象。如果搜索應用於整個字符串，Global 屬性的值為 True，否則其值為 False。默認的設置為 True。

2.IgnoreCase屬性設置或返回一個Boolean值，指明模式搜索是否區分大小寫。
　　語法：
object.IgnoreCase [= True | False ]
　　 object 參數總是一個 RegExp 對象。如果搜索是區分大小寫的，則 IgnoreCase 屬性為 False;否則為 True。缺省值為 True。

3.Pattern屬性設置或返回被搜索的正則表達式模式。
　　語法：
object.Pattern [= "searchstring"]

4.Pattern 屬性的語法包含以下幾個部分：

設置
　　在書寫正則表達式的模式時使用了特殊的字符和序列。下面描述了可以使用的字符和序列，並給出了實例。
　\ 將下一個字符標記為特殊字符或字面值。例如"n"與字符"n"匹配。"\n"與換行符匹配。序列"\\"與"\"匹配對面，"\("與"("匹配。
　^ 匹配輸入的開始位置。
　$ 匹配輸入的結尾。
　* 匹配前一個字符零次或幾次。例如，"zo*"可以匹配"z"、"zoo"。
　+ 匹配前一個字符一次或多次。例如，"zo+"可以匹配"zoo",但不匹配"z"。
　? 匹配前一個字符零次或一次。例如，"a?ve?"可以匹配"never"中的"ve"。
　. 匹配換行符以外的任何字符。
　(pattern) 與模式匹配並記住匹配。匹配的子字符串可以從作為結果的 Matches 集合中使用 Item [0]...[n]取得。如果要匹配括號字符(和 )，可使用" $" 或 "$

--====================================
--標題: 應用實例之SQL SERVER 正則替換
--作者：maco_wang
--時間：2012-03-24
--說明：MS-SQL SERVER 中的正則替換
--補充說明：支持一下CSDN社區支持的活動
--====================================
 
/*
假設測試數據為：
col
----------------------
192abc168xx0yya101baaa
10hh176bag98job121zero
hello112u19aa110beyp45
a80abab230pppp120qu224
121nile21reply30vall90
想要得到的結果（把字段中的連續的字母替換成'.'）：
col
--------------
192.168.0.101
10.176.98.121
112.19.110.45
80.230.120.224
121.21.30.90
*/
 
--測試數據:
if object_id('[tb]') is not null drop table [tb]
create table [tb] (col varchar(100))
insert into [tb]
select '192abc168xx0yya101baaa' union all
select '10hh176bag98job121zero' union all
select 'hello112u19aa110beyp45' union all
select 'a80abab230pppp120qu224' union all
select '121nile21reply30vall90'
 
--本示例在SQL SERVER 2005版本即可適用。
 
--正常思路
--a)游標循環截取（略）
--b)自定義函數
go
create function [dbo].[fn_replace]
(
    @str nvarchar(100)
)
returns varchar(100)
as
begin
    while patindex('%[a-z]%',@str) > 0
    begin
        set @str = stuff(@str,patindex('%[a-z]%',@str),1,N'.');
    end
    while (charindex('..',@str)<>0)
    begin
        set @str=replace(@str,'..','.')
    end
    if(left(@str,1)='.') set @str=right(@str,len(@str)-1)
    if(right(@str,1)='.') set @str=left(@str,len(@str)-1)
    return @str
end
go
select dbo.[fn_replace](col) as col from [tb]
/*
col
---------------
192.168.0.101
10.176.98.121
112.19.110.45
80.230.120.224
121.21.30.90
*/
--c)其他方法，這里我主要介紹一下正則替換，因為patindex和like 能夠支持的正則還是非常少的
 
--正則替換
--開啟xp_cmdshell
--不開啟會提示：SQL Server blocked access to procedure 'xp_cmdshell'
go
sp_configure 'show advanced options', 1
go
reconfigure
go
sp_configure 'xp_cmdshell', 1
go
reconfigure
 
 
--開啟sp_OACreate
--不開啟會提示：SQL Server blocked access to procedure 'sys.sp_OACreate'
go
sp_configure 'show advanced options', 1;
go
reconfigure;
go
sp_configure 'ole automation procedures', 1;
go
reconfigure;
go
 
--創建函數
create function [dbo].[regexReplace]
(
    @source varchar(8000),    --字符串
    @regexp varchar(500),     --正則表換式
    @replace varchar(500),    --替換值
    @globalReplace bit = 0,   --是否是全局替換
    @ignoreCase bit = 0       --是否忽略大小寫
)
returns varchar(1000) AS
begin
    declare @hr int
    declare @objRegExp int
    declare @result varchar(5000)
 
    exec @hr = sp_OACreate 'VBScript.RegExp', @objRegExp output
    if @hr <> 0 
    begin
        exec @hr = sp_OADestroy @objRegExp
        return null
    end
    exec @hr = sp_OASetProperty @objRegExp, 'Pattern', @regexp
    if @hr <> 0 
    begin
        exec @hr = sp_OADestroy @objRegExp
        return null
    end
    exec @hr = sp_OASetProperty @objRegExp, 'Global', @globalReplace
    if @hr <> 0 
    begin
        exec @hr = sp_OADestroy @objRegExp
        return null
    end
    exec @hr = sp_OASetProperty @objRegExp, 'IgnoreCase', @ignoreCase
    if @hr <> 0 
    begin
        exec @hr = sp_OADestroy @objRegExp
        return null
    end 
    exec @hr = sp_OAMethod @objRegExp, 'Replace', @result output, @source, @replace
    if @hr <> 0 
    begin
        exec @hr = sp_OADestroy @objRegExp
        return null
    end
    exec @hr = sp_OADestroy @objRegExp
    if @hr <> 0 
    begin
        return null
    end
/* 注釋A
--    while (charindex('..',@result)<>0)
--    begin
--        set @result=replace(@result,'..','.')
--    end
--    if(left(@result,1)='.')
--        set @result=right(@result,len(@result)-1)
--    if(right(@result,1)='.')
--        set @result=left(@result,len(@result)-1)
*/
    return @result
end
 
--查看結果
go
select dbo.regexReplace(col,'[a-z]','.',1,0) as col from [tb]
/*
col
-----------------------
192...168..0...101....
10..176...98...121....
.....112.19..110....45
.80....230....120..224
121....21.....30....90
*/
 
--根據正則把字母替換成'.'后的結果和想要結果並不相同
--需要把函數中的"注釋A"取消注釋，才能保證結果相同，那就不如直接用上述自定義函數
--那么有沒有其他辦法呢？
 
--tb表中的字符長度為100,那么修改正則表達式，把連續的替換成'.'試一試
--匹配的模式是包含a-z的任何字母，匹配次數可以是1-100次，把字母替換成'.'，不區分大小寫
select dbo.regexReplace(col,'[a-z]{1,100}','.',1,0) as col from [tb]
/*
col
------------------
192.168.0.101.
10.176.98.121.
.112.19.110.45
.80.230.120.224
121.21.30.90
*/
 
--結果還是不相同
--開頭結尾還是有多余的'.'
--不想用left,right,substring截取，修改正則能不能搞定呢？
 
--再修改一下
--內部的：匹配的模式是包含a-z的任何字母，匹配次數可以是1-100次，把字母替換成'.'，不區分大小寫
--外部的：匹配開頭是一個'.'或者結尾是一個'.'的，替換成空格。
select 
col=dbo.regexReplace(dbo.regexReplace(col,'[a-z]{1,100}','.',1,0),'^\.{1}|\.{1}$','',1,0)
from [tb]
 
/*
col
----------------
192.168.0.101
10.176.98.121
112.19.110.45
80.230.120.224
121.21.30.90
*/
 
--這個例子對正則的應用還是比較簡單的，我這里只是介紹一個思路。

免責聲明！

本站轉載的文章為個人學習借鑒使用，本站對版權不負任何法律責任。如果侵犯了您的隱私權益，請聯系本站郵箱yoyou2525@163.com刪除。

猜您在找 SQL Server中利用正則表達式替換字符串 SQL SERVER 正則匹配實例 SQL Server 替換某個字段的值 sql server 正則匹配查詢數據 SQL Server:替換文本中的回車和換行符 nodpad++正則替換【python】正則替換 webstorm正則搜索與替換 idea 正則替換 Sublime 正則替換