win10 切換網卡的bat

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
cd /D "%~dp0"    
::  以上代碼是獲取系統管理員權限

rem //設置變量 
set NAME_ENT="以太網"
set NAME_WLAN="WLAN"
rem //以下屬性值可以根據需要更改
set ADDR=192.168.31.101
set MASK=255.255.255.0
set GATEWAY=192.168.31.250
set DNS1=10.0.30.10
set DNS2=8.8.8.8
rem //以上屬性依次為IP地址、子網掩碼、網關、首選DNS、備用DNS

echo   *****************************************************************************************************************
echo.  *                                            Write by brian on 2019-03-04                                       *                                                                                                                             
echo.  *          1. 設置有線內網靜態IP          2. 設置無線動態IP           3. 退出                                   *                                                                                           
echo   *****************************************************************************************************************

set /p operate= 請輸入選擇項目：
   
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 (goto 3) else (
echo  ！！！！輸入錯誤！！！！！
echo  ！！！！請輸入正確的選項！！！！
goto 3)

rem *****************************************************************************************************************

:1

echo 正在設置有線內網靜態IP，請稍等............
echo 打開有線網卡
netsh interface set interface 以太網 enabled
echo 禁用無線網卡
netsh interface set interface WLAN disabled
rem //可以根據你的需要更改 
echo IP地址 = %ADDR%
echo 掩碼 = %MASK%
echo 網關 = %GATEWAY%
netsh interface ipv4 set address %NAME_ENT% static %ADDR% %MASK% %GATEWAY% 
echo 首選DNS = %DNS1% 
netsh interface ipv4 set dns %NAME_ENT% static %DNS1%
echo 備用DNS = %DNS2% 
if "%DNS2%"=="" (echo DNS2為空) else (netsh interface ipv4 add dns %NAME_ENT% %DNS2%) 
echo  PASS-------有線內網靜態IP已設置！
goto 3
rem  *****************************************************************************************************************

:2

echo 正在設置無線動態IP，請稍等.........
echo 打開無線網卡
netsh interface set interface WLAN enabled
echo 禁用有線網卡
netsh interface set interface 以太網 disabled
echo 正在從DHCP自動獲取IP地址..........
netsh interface ip set address %NAME_WLAN% dhcp
echo 正在從DHCP自動獲取DNS地址...
netsh interface ip set dns %NAME_WLAN% dhcp 
echo PASS-------無線動態IP已設置！
goto 3
rem  *****************************************************************************************************************


:3
echo  3秒后關閉窗口
ping -n 3 127.0.01>nul
exit