更改Windows IP 地址的bat腳本

版本一、選擇網卡，並選擇要設置的IP地址

@echo off
title netsh-ipv4 (by huanu)
:nc
rem //選擇網卡
echo --請根據網卡名選擇網卡：
echo ex 、退出(exit)
echo 01 、以太網(win8\win10)
echo 02 、本地連接(win xp\win7)
echo 03 、WLAN
echo 04 、Enternet
echo 05 、Local Area Connection
echo.
echo --請選擇后回車：
set /p netname=
if %netname%==ex exit
if %netname%==01 set NAME="以太網"
if %netname%==02 set NAME="本地連接"
if %netname%==03 set NAME="WLAN"
if %netname%==04 set NAME="Enternet"
if %netname%==05 set NAME="Local Area Connection"
echo 您選擇的網卡是%NAME%
echo.

rem //選擇要設置的IP地址：
:list
echo ---選擇要設置的IP地址：
echo nc 、返回重新選擇網卡(back)
echo ex 、退出(exit)
echo 01 、從DHCP自動獲取IP地址
echo 02 、公司工位 IP：192.168.90.5
echo.
echo ---請選擇后回車：
set /p operate=
if %operate%==nc goto nc
if %operate%==ex exit
if %operate%==01 goto dhcp
if %operate%==02 goto 02
echo.

rem //設置IP地址
:dhcp
echo 正在設置動態IP，請稍等...
echo 正在從DHCP自動獲取IP地址...
netsh interface ip set address %NAME% dhcp
echo 正在從DHCP自動獲取DNS地址...
netsh interface ip set dns %NAME% dhcp 
echo %NAME%地址已自動獲取成功！
pause & exit

:02
rem //可以根據你的需要更改 
set ADDR=192.168.90.5
set MASK=255.255.255.0
set GATEWAY=192.168.90.1
set DNS1=114.114.114.114
set DNS2=8.8.8.8
echo 正在設置%NAME% IP地址，請稍等...
rem //設置並打印在屏幕上
echo IP地址 = %ADDR%
echo 掩碼 = %MASK%
echo 網關 = %GATEWAY%
netsh interface ipv4 set address %NAME% static %ADDR% %MASK% %GATEWAY% 
echo 首選DNS = %DNS1% 
netsh interface ipv4 set dns %NAME% static %DNS1%
echo 備用DNS = %DNS2% 
if "%DNS2%"=="" (echo DNS2為空) else (netsh interface ipv4 add dns %NAME% %DNS2%) 
echo %NAME% IP已設置完成！
pause & exit

分離版本點擊這里

啊~

PS：windows 添加route,打開cmd命令界面輸入以下l例舉指令

查詢路由命令 route print 

添加路由命令 route -p add 5.48.25.0 mask 255.255.255.240 5.48.25.14 

刪除路由命令 route delete 5.48.25.0