【sql server郵件】sql server如何把查詢結果發郵件出去

【0】使用圖形界面 配置郵件服務器

前提：如果要使用QQ郵箱測試，參考（Sql server用QQ郵箱發送郵件）

圖形界面配置郵件服務器，參考：數據庫郵件功能

更改郵件附件大小，參考：http://blog.163.com/yzc_5001/blog/static/2061963420083278856394/

EXEC msdb.dbo.sysmail_configure_sp 'MaxFileSize', 100000000

【1】使用T-SQL 配置郵件服務器

原文：https://zhidao.baidu.com/question/1819725575342685788.html
--0.檢查Service Broker是否在數據庫級別被啟用，如果沒有，啟用它。后續需要用它來存放郵件隊列信息。
use msdb
go

if exists(
select 1 from sys.databases where name = 'test' and is_broker_enabled=0
)
begin
ALTER DATABASE msdb SET NEW_BROKER WITH ROLLBACK IMMEDIATE;
alter database msdb set enable_broker;
end

--1.啟用Database Mail擴展存儲過程
sp_configure 'show advanced options', 1
GO
RECONFIGURE
GO
sp_configure 'Database Mail XPs', 1
GO
RECONFIGURE
GO
sp_configure 'show advanced options', 0
GO
RECONFIGURE
GO
 
--2.添加account
exec msdb..sysmail_add_account_sp
        @account_name            = 'zhanghao' --郵件帳戶名稱SQL Server內使用
       ,@email_address           = '[e-mail]' --發件人郵件地址
　　　　,@display_name            = '張好'              --發郵件出去后顯示的名稱
       ,@mailserver_name         = 'smtp.126.com'        --郵件服務器地址
       ,@mailserver_type         = 'SMTP'                --郵件協議SQL 2005只支持SMTP
       ,@port                    = 25                    --郵件服務器端口
       ,@username                = 'zhanghao' --用戶名
       ,@password                = 'mima' --密碼
        
--3.添加profile
exec msdb..sysmail_add_profile_sp
@profile_name = 'dba_profile'-- profile 名稱
   ,@description  = 'dba mail profile'-- profile 描述
   ,@profile_id   = null
    
--4.映射account和profile
exec msdb..sysmail_add_profileaccount_sp  
@profile_name    = 'dba_profile'-- profile 名稱
   ,@account_name    = 'zhanghao'-- account 名稱
   ,@sequence_number = 1-- account 在profile中順序
  
--5.1發送文本郵件
exec msdb..sp_send_dbmail
@profile_name =  'dba_profile'
   ,@recipients   =  '[e-mail]'
   ,@subject      =  'SQL Server郵件測試'
   ,@body         =  '內容啊'
   ,@body_format  =  'TEXT'
    
--5.2發送附件
EXEC sp_send_dbmail
    @profile_name = 'dba_profile',
    @recipients = '[e-mail]',
    @subject = '這是附件',
@file_attachments ='G:\亂七八糟\sql.txt'
 
--5.3發送查詢結果
EXEC sp_send_dbmail
    @profile_name = 'dba_profile',
    @recipients = '[e-mail]',
    @subject = '這是查詢',
@query='select * from test.dbo.apo_city'

--5.4以HTML格式發送查詢結果（要是列太多，請自行想辦法使用動態SQL）
declare @temp1 table(id int,name varchar(100),[desc] varchar(100));
insert into @temp1 
select 1 as id ,'q' as name,'我是一個測試q' as 'desc' 
union all
select 2 as id ,'w' as name,'我是q的兄弟w啊' as 'desc'

declare @tableHTML nvarchar(max)
set @tableHTML = N'<H1>test for xml result</H1>' 
+ N'<table border="1">' 
+ N'<tr>'
+ N'<th> id </th>' 
+ N'<th>Name</th>' 
+ N'<th>desc</th></tr>' 
+ CAST(
        (
         select td=id,'', 
                td=name,'',
                td=[desc],''
                from @temp1
                for xml path('tr')
        )
     as nvarchar(max)
    )
    
+'</table>' 
print @tableHTML

EXEC msdb.dbo.sp_send_dbmail 
    @profile_name = 'dba_profile'
    , @recipients = '[e-mail]'
    , @subject = 'test for xml result'
    , @body = @tableHTML
    , @body_format = 'HTML';

  

【2】郵件查閱及刪改

--6.查看郵件發送情況
use msdb 
go
select * from sysmail_allitems 
select * from sysmail_mailitems 
select * from sysmail_event_log 
--常用標紅

select * from sysmail_profile --郵件配置文件信息
select * from sysmail_principalprofile
select * from sysmail_account --郵件賬戶信息
select * from sysmail_profileaccount --郵件賬戶與配置文件關系表
select * from sysmail_servertype --使用服務類型
select * from sysmail_server --郵件賬戶與服務修改詳細信息
select * from sysmail_configuration --郵件功能參數配置表
select * from sysmail_mailitems--郵件發送條目詳情
select * from sysmail_attachments
select * from sysmail_send_retries
select * from sysmail_log --郵件功能的日志信息
select * from sysmail_query_transfer
select * from sysmail_attachments_transfer



--7.刪除郵件配置
Exec msdb..sysmail_delete_profileaccount_sp  
@profile_name = 'dba_profile',
    @account_name = 'zhanghao'
Exec msdb..sysmail_delete_profile_sp
@profile_name = 'dba_profile'
Exec msdb..sysmail_delete_account_sp
@account_name ='zhanghao'

--8.常用腳本
--查看賬號
select * FROM msdb..sysmail_account
--查看配置文件
select * from msdb..[sysmail_profile]
--查看是否已啟動數據庫郵件激活
EXEC msdb.dbo.sysmail_help_status_sp;
--啟動數據庫郵件激活
EXEC msdb.dbo.sysmail_start_sp;
--檢查郵件隊列的狀態
--如果郵件隊列的狀態不正常，
--請使用 sysmail_stop_sp 嘗試停止隊列，然后再使用 sysmail_start_sp 啟動隊列。
EXEC msdb.dbo.sysmail_help_queue_sp @queue_type = 'mail';
 
--查看最近的郵件發送情況
select top 5 m.mailitem_id
,m.profile_id
,p.name as profileName
,g.description AS [log_desc]--郵件發送有異常，這里會有顯示
,m.sent_status
,CASE sent_status when 1 then 'Successed' else 'Failed' END AS sent_status_desc
,m.subject
,m.body
,m.body_format
,m.send_request_date
from msdb..[sysmail_mailitems] AS m 
left join msdb..sysmail_profile AS p on m.profile_id=p.profile_id
left join msdb..sysmail_log g on m.mailitem_id = g.mailitem_id
order by mailitem_id desc
 
--清除30天前的郵件和日志
DECLARE @DeleteBeforeDate DateTime
SELECT @DeleteBeforeDate = DATEADD(d,-30, GETDATE())
EXEC msdb..sysmail_delete_mailitems_sp @sent_before = @DeleteBeforeDate
EXEC msdb..sysmail_delete_log_sp @logged_before = @DeleteBeforeDate

【3】sp_send_dbmail 郵件SP參數詳解

上面代碼copy到新建查詢中運行，並適當修改，就能發送郵件了！下面說一說SP_send_dbmail 存儲過程中的參數含義(下面為copy過來，為了讀者方便)：

sp_send_dbmail [ [ @profile_name = ] 'profile_name' ]
    [ , [ @recipients = ] 'recipients [ ; n ]' ]
    [ , [ @copy_recipients = ] 'copy_recipient [ ; n ]' ]
    [ , [ @blind_copy_recipients = ] 'blind_copy_recipient [ ; n ]' ]
    [ , [ @subject = ] 'subject' ] 
    [ , [ @body = ] 'body' ] 
    [ , [ @body_format = ] 'body_format' ]
    [ , [ @importance = ] 'importance' ]
    [ , [ @sensitivity = ] 'sensitivity' ]
    [ , [ @file_attachments = ] 'attachment [ ; n ]' ]
    [ , [ @query = ] 'query' ]
    [ , [ @execute_query_database = ] 'execute_query_database' ]
    [ , [ @attach_query_result_as_file = ] attach_query_result_as_file ]
    [ , [ @query_attachment_filename = ] query_attachment_filename ]
    [ , [ @query_result_header = ] query_result_header ]
    [ , [ @query_result_width = ] query_result_width ]
    [ , [ @query_result_separator = ] 'query_result_separator' ]
    [ , [ @exclude_query_output = ] exclude_query_output ]
    [ , [ @append_query_error = ] append_query_error ]
    [ , [ @query_no_truncate = ] query_no_truncate ]
    [ , [ @mailitem_id = ] mailitem_id ] [ OUTPUT ]

 

 參數

[ @profile_name= ] 'profile_name'
發送郵件的配置文件的名稱。profile_name 的類型為 sysname，默認值為 NULL。profile_name 必須是現有數據庫郵件配置文件的名稱。如果未指定 profile_name，則 sp_send_dbmail 使用當前用戶的默認專用配置文件。如果該用戶沒有默認專用配置文件，sp_send_dbmail 會使用 msdb 數據庫的默認公共配置文件。如果用戶沒有默認的專用配置文件，而且數據庫也沒有默認的公共配置文件，則必須指定 @profile_name。

[ @recipients= ] 'recipients'
要向其發送郵件的電子郵件地址列表，以分號分隔。收件人列表的類型為 varchar(max)。雖然此參數是可選參數，但是必須至少指定 @recipients、@copy_recipients 或 @blind_copy_recipients 中的一個，否則 sp_send_dbmail 將返回錯誤。

[ @copy_recipients= ] 'copy_recipients'
要向其抄送郵件的電子郵件地址列表，以分號分隔。抄送件收件人列表的類型為 varchar(max)。雖然此參數是可選參數，但是必須至少指定 @recipients、@copy_recipients 或 @blind_copy_recipients 中的一個，否則 sp_send_dbmail 將返回錯誤。

[ @blind_copy_recipients= ] 'blind_copy_recipients'
要向其密件抄送郵件的電子郵件地址列表，以分號分隔。密件副本收件人列表的類型為 varchar(max)。雖然此參數是可選參數，但是必須至少指定 @recipients、@copy_recipients 或 @blind_copy_recipients中的一個，否則 sp_send_dbmail 將返回錯誤。

[ @subject= ] 'subject'
電子郵件的主題。主題的類型為 nvarchar(255)。如果未指定主題，則默認為“SQL Server 消息”。

[ @body= ] 'body'
電子郵件的正文。郵件正文的類型為 nvarchar(max)，默認值為 NULL。

[ @body_format= ] 'body_format'
郵件正文的格式。該參數的類型為 varchar(20)，默認值為 NULL。如果已指定，則待發郵件的標頭設置會指示郵件正文具有指定格式。該參數可能包含下列值之一：

TEXT
HTML
默認為 TEXT。

[ @importance= ] 'importance'
郵件的重要性。該參數的類型為 varchar(6)。該參數可能包含下列值之一：

Low
Normal
High
默認值為 Normal。

[ @sensitivity= ] 'sensitivity'
郵件的敏感度。該參數的類型為 varchar(12)。該參數可能包含下列值之一：

Normal
Personal
Private
Confidential
默認值為 Normal。

[ @file_attachments= ] 'file_attachments',
電子郵件附件的文件名列表，以分號分隔。必須使用絕對路徑指定列表中的文件。附件列表的類型為nvarchar(max)。

[ @query= ] 'query'
要執行的查詢。查詢結果可以作為文件附加，或包含在電子郵件的正文中。查詢的類型為 nvarchar(max)，並且可以包含任何有效的 Transact-SQL 語句。請注意，查詢在單獨的會話中執行，所以調用 sp_send_dbmail的腳本中的局部變量不可用於查詢。

[ @execute_query_database= ] 'execute_query_database'
存儲過程在其中運行查詢的數據庫上下文。該參數的類型為 sysname，默認為當前數據庫。只有在指定@query 時，此參數才適用。

[ @attach_query_result_as_file= ] attach_query_result_as_file
指定查詢結果集是否作為附件返回。attach_query_result_as_file 的數據類型為 bit，默認值為 0。

如果該值為 0，則查詢結果包含在電子郵件的正文中，在 @body 參數的內容之后。如果該值為 1，則結果作為附件返回。只有在指定 @query 時，此參數才適用。

[ @query_attachment_filename= ] query_attachment_filename
指定查詢結果集附件使用的文件名。query_attachment_filename 的數據類型為 nvarchar(255)，默認值為 NULL。如果 attach_query_result 為 0，則忽略此參數。如果 attach_query_result 為 1 且此參數為 NULL，則數據庫郵件會創建任意文件名。

[ @query_result_header= ] query_result_header
指定查詢結果是否包含列標題。query_result_header 值的數據類型為 bit。如果該值為 1，則查詢結果包含列標題。如果該值為 0，則查詢結果不包含列標題。該參數的默認值為 1。只有在指定 @query 時，此參數才適用。

[ @query_result_width = ] query_result_width
用於設置查詢結果的格式的線條寬度（字符）。query_result_width 的數據類型為 int，默認值為 256。提供的值必須介於 10 和 32767 之間。只有在指定 @query 時，此參數才適用。

[ @query_result_separator= ] 'query_result_separator'
用於分隔查詢輸出中的列的字符。分隔符的類型為 char(1)。默認為“ ”（空格）。

[ @exclude_query_output= ] exclude_query_output
指定是否使用電子郵件返回查詢執行的輸出。exclude_query_output 的數據類型為 bit，默認值為 0。當此參數為 0 時，sp_send_dbmail 存儲過程的執行將在控制台上打印作為查詢執行結果而返回的消息。當此參數為 1 時，sp_send_dbmail 存儲過程的執行不會在控制台上打印任何查詢執行消息。

[ @append_query_error= ] append_query_error
指定是否在 @query 參數指定的查詢返回錯誤時發送電子郵件。append_query_error 的數據類型為 bit，默認值為 0。如果此參數的值為 1，則數據庫郵件會發送電子郵件，並電子郵件的正文中顯示查詢錯誤消息。如果此參數的值為 0，則數據庫郵件不發送電子郵件，sp_send_dbmail 在結束時會返回代碼 1，指示失敗。

[ @query_no_truncate= ] query_no_truncate
指定是否使用可避免截斷大型可變長度數據類型（varchar(max)、nvarchar(max)、varbinary(max)、xml、text、ntext、image 和用戶定義類型）的選項執行查詢。設置該選項后，查詢結果將不包含列標題。query_no_truncate 值的數據類型為 bit。當該值為 0 或未指定時，查詢中的列將截斷為 256 個字符。當該值為 1 時，不截斷查詢中的列。此參數的默認值為 0。

注意：
與大量數據一起使用時，@query_no_truncate 選項會占用其他資源，並可降低服務器的性能。
 

 

[ @mailitem_id= ] mailitem_id [ OUTPUT ]
可選輸出參數將返回消息的 mailitem_id。mailitem_id 的類型為 int。

 返回代碼值
0（成功）或 1（失敗）

 結果集
成功時，返回消息“郵件已排隊”。

 備注
使用前，必須使用數據庫郵件配置向導、SQL Server 外圍應用配置器工具或 sp_configure 啟用數據庫郵件。

sysmail_stop_sp 通過停止外部程序使用的 Service Broker 對象來停止數據庫郵件。使用sysmail_stop_sp 停止數據庫郵件后，sp_send_dbmail 仍會接受郵件。若要啟動數據庫郵件，請使用sysmail_start_sp。

如果未指定 @profile，則 sp_send_dbmail 使用默認配置文件。如果發送電子郵件的用戶具有默認專用配置文件，則數據庫郵件使用該配置文件。如果該用戶沒有默認的專用配置文件，則 sp_send_dbmail 將使用默認的公共配置文件。如果用戶沒有默認的專用配置文件和默認的公共配置文件，則 sp_send_dbmail 將返回錯誤。

sp_send_dbmail 不支持沒有任何內容的電子郵件。若要發送電子郵件，至少必須指定@body、@query、@file_attachments 或 @subject 之一。否則，sp_send_dbmail 會返回錯誤。

數據庫郵件使用當前用戶的 Microsoft Windows 安全上下文控制對文件的訪問。因此，經過 SQL Server 身份驗證的用戶無法使用 @file_attachments 附加文件。Windows 不允許 SQL Server 從一台遠程計算機向另一台遠程計算機提供憑據。所以，如果從運行 SQL Server 的計算機以外的計算機運行該命令，則數據庫郵件可能無法從網絡共享附加文件。

如果已同時指定 @query 和 @file_attachments 且未找到文件，則查詢仍然會執行，但是不會發送電子郵件。

指定查詢后，結果集的格式被設置為內聯文本。使用十六進制格式發送結果中的二進制數據。

參數 @recipients、@copy_recipients 和 @blind_copy_recipients 是以分號分隔的電子郵件地址列表。至少必須提供以上參數之一，否則 sp_send_dbmail 會返回錯誤。

在沒有事務上下文的情況下執行 sp_send_dbmail 時，數據庫郵件將啟動並提交隱式事務。從現有事務內執行sp_send_dbmail 時，數據庫郵件將依賴用戶提交或回滾任何更改。它不會啟動內部事務。

 權限
默認情況下，msdb 數據庫中的 DatabaseMailUser 數據庫角色的所有成員對 sp_send_dbmail 都有執行權限。不過，如果發送郵件的用戶不具有使用該請求的配置文件的權限，sp_send_dbmail 會返回錯誤且不發送該郵件。

【4】sp_send_dbmail  演示

A. 發送電子郵件

此示例使用電子郵件地址 [e-mail] 向 Dan Wilson 發送電子郵件。

該郵件的主題為Automated Success Message。郵件正文包含一句話 'The stored procedure finished successfully'。

EXEC msdb.dbo.sp_send_dbmail 
@profile_name = 'AdventureWorks Administrator',
@recipients = '[e-mail]',
@body = 'The stored procedure finished successfully.',
@subject = 'Automated Success Message' ;

B. 發送包含查詢結果的電子郵件

此示例使用電子郵件地址 [e-mail] 向 Dan Wilson 發送電子郵件。

該郵件的主題為 Work Order Count，並執行查詢以顯示 DueDate 在 2004 年 4 月 30 日后的兩日內的工單數。數據庫郵件將該結果附加為文本文件。

EXEC msdb.dbo.sp_send_dbmail
@profile_name = 'AdventureWorks Administrator',
@recipients = '[e-mail]',
@query = 'SELECT COUNT(*) FROM AdventureWorks.Production.WorkOrderWHERE DueDate > ''2004-04-30''AND DATEDIFF(dd, ''2004-04-30'', DueDate) < 2' ,
@subject = 'Work Order Count',@attach_query_result_as_file = 1 ;

C. 發送 HTML 電子郵件

此示例使用電子郵件地址 [e-mail] 向 Dan Wilson 發送電子郵件。

郵件的主題為 Work Order List，並包含一個 HTML 文檔，其中列出 DueDate 在 2004 年 4 月 30 日后的二日內的工單。數據庫郵件使用 HTML 格式發送該郵件。

 

DECLARE @tableHTML NVARCHAR(MAX);
SET @tableHTML = N'<H1>Work Order Report</H1>' + N'<table border="1">' + N'<tr><th>Work Order ID</th><th>Product ID</th>' + N'<th>Name</th><th>Order Qty</th><th>Due Date</th>' + N'<th>Expected Revenue</th></tr>' + CAST((
            SELECT td = wo.WorkOrderID
                , ''
                , td = p.ProductID
                , ''
                , td = p.Name
                , ''
                , td = wo.OrderQty
                , ''
                , td = wo.DueDate
                , ''
                , td = (p.ListPrice - p.StandardCost) * wo.OrderQty
　　　　　　　　   FROM AdventureWorks.Production.WorkOrder AS woJOIN AdventureWorks.Production.Product AS pON wo.ProductID = p.ProductIDWHERE DueDate > '2004-04-30'
                AND DATEDIFF(dd, '2004-04-30', DueDate) < 2
            
            ORDER BY DueDate ASC
                , (p.ListPrice - p.StandardCost) * wo.OrderQty DESC
　　　　　　　　　　FOR XML PATH('tr')
                , TYPE
            ) AS NVARCHAR(MAX)) + N'</table>';
            
EXEC msdb.dbo.sp_send_dbmail @recipients = '[e-mail]'
    , @subject = 'Work Order List'
    , @body = @tableHTML
    , @body_format = 'HTML';

 

如何添加多個收件人？收件人用;號分割

EXEC msdb.dbo.sp_send_dbmail 
    @profile_name = 'dba_profile'
    , @recipients = '[e-mail];[e-mail];[e-mail]'
    , @subject = 'test for xml result'
    , @body = @tableHTML
    , @body_format = 'HTML';