輕松看懂Java字節碼

java字節碼

計算機只認識0和1。這意味着任何語言編寫的程序最終都需要經過編譯器編譯成機器碼才能被計算機執行。所以，我們所編寫的程序在不同的平台上運行前都要經過重新編譯才能被執行。 而Java剛誕生的時候曾經提過一個非常著名的宣傳口號: "一次編寫，到處運行"。

Write Once, Run Anywhere.

為了實現該目的，Sun公司以及其他虛擬機提供商發布了許多可以運行在不同平台上的JVM虛擬機，而這些虛擬機都擁有一個共同的功能，那就是可以載入和執行同一種與平台無關的字節碼(ByteCode)。 於是，我們的源代碼不再必須根據不同平台翻譯成0和1，而是間接翻譯成字節碼，儲存字節碼的文件再交由運行於不同平台上的JVM虛擬機去讀取執行，從而實現一次編寫，到處運行的目的。 如今，JVM也不再只支持Java，由此衍生出了許多基於JVM的編程語言，如Groovy, Scala, Koltin等等。

 

 

源代碼中的各種變量，關鍵字和運算符號的語義最終都會編譯成多條字節碼命令。而字節碼命令所能提供的語義描述能力是要明顯強於Java本身的，所以有其他一些同樣基於JVM的語言能提供許多Java所不支持的語言特性。

例子

下面以一個簡單的例子來逐步講解字節碼。

//Main.java public class Main { private int m; public int inc() { return m + 1; } } 復制代碼

通過以下命令, 可以在當前所在路徑下生成一個Main.class文件。

javac Main.java
復制代碼

以文本的形式打開生成的class文件，內容如下:

cafe babe 0000 0034 0013 0a00 0400 0f09
0003 0010 0700 1107 0012 0100 016d 0100
0149 0100 063c 696e 6974 3e01 0003 2829
5601 0004 436f 6465 0100 0f4c 696e 654e
756d 6265 7254 6162 6c65 0100 0369 6e63
0100 0328 2949 0100 0a53 6f75 7263 6546
696c 6501 0009 4d61 696e 2e6a 6176 610c
0007 0008 0c00 0500 0601 0010 636f 6d2f
7268 7974 686d 372f 4d61 696e 0100 106a
6176 612f 6c61 6e67 2f4f 626a 6563 7400
2100 0300 0400 0000 0100 0200 0500 0600
0000 0200 0100 0700 0800 0100 0900 0000
1d00 0100 0100 0000 052a b700 01b1 0000
0001 000a 0000 0006 0001 0000 0003 0001
000b 000c 0001 0009 0000 001f 0002 0001
0000 0007 2ab4 0002 0460 ac00 0000 0100
0a00 0000 0600 0100 0000 0800 0100 0d00
0000 0200 0e
復制代碼

對於文件中的16進制代碼，除了開頭的cafe babe，剩下的內容大致可以翻譯成: 啥玩意啊這是......

英雄莫慌，我們就從我們所能認識的"cafe babe"講起吧。 文件開頭的4個字節稱之為 魔數，唯有以"cafe babe"開頭的class文件方可被虛擬機所接受，這4個字節就是字節碼文件的身份識別。 目光右移，0000是編譯器jdk版本的次版本號0，0034轉化為十進制是52,是主版本號，java的版本號從45開始，除1.0和1.1都是使用45.x外,以后每升一個大版本，版本號加一。也就是說，編譯生成該class文件的jdk版本為1.8.0。 通過java -version命令稍加驗證, 可得結果。

Java(TM) SE Runtime Environment (build 1.8.0_131-b11)
Java HotSpot(TM) 64-Bit Server VM (build 25.131-b11, mixed mode)
復制代碼

結果驗證成立。

繼續往下是常量池。但我並不打算繼續直接分析這個十六進制文件。

反編譯字節碼文件

使用到java內置的一個反編譯工具javap可以反編譯字節碼文件。 通過javap -help可了解javap的基本用法

用法: javap <options> <classes>
其中, 可能的選項包括:
  -help  --help  -?        輸出此用法消息
  -version                 版本信息
  -v  -verbose             輸出附加信息
  -l 輸出行號和本地變量表 -public 僅顯示公共類和成員 -protected 顯示受保護的/公共類和成員 -package 顯示程序包/受保護的/公共類 和成員 (默認) -p -private 顯示所有類和成員 -c 對代碼進行反匯編 -s 輸出內部類型簽名 -sysinfo 顯示正在處理的類的 系統信息 (路徑, 大小, 日期, MD5 散列) -constants 顯示最終常量 -classpath <path> 指定查找用戶類文件的位置 -cp <path> 指定查找用戶類文件的位置 -bootclasspath <path> 覆蓋引導類文件的位置 復制代碼

輸入命令javap -verbose -p Main.class查看輸出內容:

Classfile /E:/JavaCode/TestProj/out/production/TestProj/com/rhythm7/Main.class
  Last modified 2018-4-7; size 362 bytes
  MD5 checksum 4aed8540b098992663b7ba08c65312de
  Compiled from "Main.java"
public class com.rhythm7.Main
  minor version: 0
  major version: 52
  flags: ACC_PUBLIC, ACC_SUPER
Constant pool:
   #1 = Methodref          #4.#18         // java/lang/Object."<init>":()V
   #2 = Fieldref           #3.#19         // com/rhythm7/Main.m:I
   #3 = Class              #20            // com/rhythm7/Main
   #4 = Class              #21            // java/lang/Object
   #5 = Utf8               m
   #6 = Utf8               I
   #7 = Utf8               <init>
   #8 = Utf8               ()V
   #9 = Utf8               Code
  #10 = Utf8               LineNumberTable
  #11 = Utf8               LocalVariableTable
  #12 = Utf8               this
  #13 = Utf8               Lcom/rhythm7/Main;
  #14 = Utf8               inc
  #15 = Utf8               ()I
  #16 = Utf8               SourceFile
  #17 = Utf8               Main.java
  #18 = NameAndType        #7:#8          // "<init>":()V
  #19 = NameAndType        #5:#6          // m:I
  #20 = Utf8               com/rhythm7/Main
  #21 = Utf8               java/lang/Object
{
  private int m;
    descriptor: I
    flags: ACC_PRIVATE

  public com.rhythm7.Main();
    descriptor: ()V
    flags: ACC_PUBLIC
    Code:
      stack=1, locals=1, args_size=1
         0: aload_0
         1: invokespecial #1                  // Method java/lang/Object."<init>":()V
         4: return
      LineNumberTable:
        line 3: 0
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       5     0  this   Lcom/rhythm7/Main;

  public int inc();
    descriptor: ()I
    flags: ACC_PUBLIC
    Code:
      stack=2, locals=1, args_size=1
         0: aload_0
         1: getfield      #2                  // Field m:I
         4: iconst_1
         5: iadd
         6: ireturn
      LineNumberTable:
        line 8: 0
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       7     0  this   Lcom/rhythm7/Main;
}
SourceFile: "Main.java"
復制代碼

字節碼文件信息

開頭的7行信息包括:Class文件當前所在位置，最后修改時間，文件大小，MD5值，編譯自哪個文件，類的全限定名，jdk次版本號，主版本號。 然后緊接着的是該類的訪問標志：ACC_PUBLIC, ACC_SUPER，訪問標志的含義如下:

標志名稱	標志值	含義
ACC_PUBLIC	0x0001	是否為Public類型
ACC_FINAL	0x0010	是否被聲明為final，只有類可以設置
ACC_SUPER	0x0020	是否允許使用invokespecial字節碼指令的新語義．
ACC_INTERFACE	0x0200	標志這是一個接口
ACC_ABSTRACT	0x0400	是否為abstract類型，對於接口或者抽象類來說， 次標志值為真，其他類型為假
ACC_SYNTHETIC	0x1000	標志這個類並非由用戶代碼產生
ACC_ANNOTATION	0x2000	標志這是一個注解
**ACC_ENUM **	0x4000	標志這是一個枚舉

常量池

Constant pool意為常量池。 常量池可以理解成Class文件中的資源倉庫。主要存放的是兩大類常量：字面量(Literal)和符號引用(Symbolic References)。字面量類似於java中的常量概念，如文本字符串，final常量等，而符號引用則屬於編譯原理方面的概念，包括以下三種:

• 類和接口的全限定名(Fully Qualified Name)
• 字段的名稱和描述符號(Descriptor)
• 方法的名稱和描述符

不同於C/C++, JVM是在加載Class文件的時候才進行的動態鏈接，也就是說這些字段和方法符號引用只有在運行期轉換后才能獲得真正的內存入口地址。當虛擬機運行時，需要從常量池獲得對應的符號引用，再在類創建或運行時解析並翻譯到具體的內存地址中。

直接通過反編譯文件來查看字節碼內容：

#1 = Methodref          #4.#18         // java/lang/Object."<init>":()V
#4 = Class              #21            // java/lang/Object
#7 = Utf8               <init>
#8 = Utf8               ()V
#18 = NameAndType        #7:#8          // "<init>":()V
#21 = Utf8               java/lang/Object
復制代碼

第一個常量是一個方法定義，指向了第4和第18個常量。以此類推查看第4和第18個常量。最后可以拼接成第一個常量右側的注釋內容:

java/lang/Object."<init>":()V 復制代碼

這段可以理解為該類的實例構造器的聲明，由於Main類沒有重寫構造方法，所以調用的是父類的構造方法。此處也說明了Main類的直接父類是Object。 該方法默認返回值是V, 也就是void，無返回值。

同理可分析第二個常量:

#2 = Fieldref           #3.#19         // com/rhythm7/Main.m:I
#3 = Class              #20            // com/rhythm7/Main
#5 = Utf8               m
#6 = Utf8               I
#19 = NameAndType        #5:#6          // m:I
#20 = Utf8               com/rhythm7/Main
復制代碼

此處聲明了一個字段m，類型為I, I即是int類型。關於字節碼的類型對應如下：

標識字符	含義
B	基本類型byte
C	基本類型char
D	基本類型double
F	基本類型float
I	基本類型int
J	基本類型long
S	基本類型short
Z	基本類型boolean
V	特殊類型void
L	對象類型，以分號結尾，如Ljava/lang/Object;

對於數組類型，每一位使用一個前置的"["字符來描述，如定義一個java.lang.String[][]類型的維數組，將被記錄為"[[Ljava/lang/String;"

方法表集合

在常量池之后的是對類內部的方法描述，在字節碼中以表的集合形式表現，暫且不管字節碼文件的16進制文件內容如何，我們直接看反編譯后的內容。

private int m; descriptor: I flags: ACC_PRIVATE 復制代碼

此處聲明了一個私有變量m，類型為int，返回值為int

public com.rhythm7.Main();
   descriptor: ()V
   flags: ACC_PUBLIC
   Code:
     stack=1, locals=1, args_size=1
        0: aload_0
        1: invokespecial #1                  // Method java/lang/Object."<init>":()V
        4: return
     LineNumberTable:
       line 3: 0
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0       5     0  this   Lcom/rhythm7/Main;
復制代碼

這里是構造方法：Main()，返回值為void, 公開方法。 code內的主要屬性為:

• stack 最大操作數棧，JVM運行時會根據這個值來分配棧幀(Frame)中的操作棧深度,此處為1

• locals: 局部變量所需的存儲空間，單位為Slot, Slot是虛擬機為局部變量分配內存時所使用的最小單位，為4個字節大小。方法參數(包括實例方法中的隱藏參數this)，顯示異常處理器的參數(try catch中的catch塊所定義的異常)，方法體中定義的局部變量都需要使用局部變量表來存放。值得一提的是，locals的大小並不一定等於所有局部變量所占的Slot之和，因為局部變量中的Slot是可以重用的。

• args_size: 方法參數的個數，這里是1，因為每個實例方法都會有一個隱藏參數this

• attribute_info 方法體內容，0,1,4為字節碼"行號"，該段代碼的意思是將第一個引用類型本地變量推送至棧頂，然后執行該類型的實例方法，也就是常量池存放的第一個變量，也就是注釋里的"java/lang/Object."":()V", 然后執行返回語句，結束方法。

• LineNumberTable 該屬性的作用是描述源碼行號與字節碼行號(字節碼偏移量)之間的對應關系。可以使用 -g:none 或-g:lines選項來取消或要求生成這項信息，如果選擇不生成LineNumberTable，當程序運行異常時將無法獲取到發生異常的源碼行號，也無法按照源碼的行數來調試程序。

• LocalVariableTable 該屬性的作用是描述幀棧中局部變量與源碼中定義的變量之間的關系。可以使用 -g:none 或 -g:vars來取消或生成這項信息，如果沒有生成這項信息，那么當別人引用這個方法時，將無法獲取到參數名稱，取而代之的是arg0, arg1這樣的占位符。 start 表示該局部變量在哪一行開始可見，length表示可見行數，Slot代表所在幀棧位置，Name是變量名稱，然后是類型簽名。

同理可以分析Main類中的另一個方法"inc()": 方法體內的內容是：將this入棧，獲取字段#2並置於棧頂, 將int類型的1入棧，將棧內頂部的兩個數值相加，返回一個int類型的值。

SourceFile

源碼文件名稱

---

實戰

分析try-catch-finally

通過以上一個最簡單的例子，可以大致了解源碼被編譯成字節碼后是什么樣子的。 下面利用所學的知識點來分析一些Java問題:

public class TestCode { public int foo() { int x; try { x = 1; return x; } catch (Exception e) { x = 2; return x; } finally { x = 3; } } } 復制代碼

試問當不發生異常和發生異常的情況下，foo()的返回值分別是多少。 使出老手段

javac TestCode.java
javap -verbose TestCode.class
復制代碼

查看字節碼的foo方法內容:

public int foo(); descriptor: ()I flags: ACC_PUBLIC Code: stack=1, locals=5, args_size=1 0: iconst_1 //int型1入棧 ->棧頂=1 1: istore_1 //將棧頂的int型數值存入第二個局部變量 ->局部2=1 2: iload_1 //將第二個int型局部變量推送至棧頂 ->棧頂=1 3: istore_2 //!!將棧頂int型數值存入第三個局部變量 ->局部3=1 4: iconst_3 //int型3入棧 ->棧頂=3 5: istore_1 //將棧頂的int型數值存入第二個局部變量 ->局部2=3 6: iload_2 //!!將第三個int型局部變量推送至棧頂 ->棧頂=1 7: ireturn //從當前方法返回棧頂int數值 ->1 8: astore_2 // ->局部3=Exception 9: iconst_2 // ->棧頂=2 10: istore_1 // ->局部2=2 11: iload_1 //->棧頂=2 12: istore_3 //!! ->局部4=2 13: iconst_3 // ->棧頂=3 14: istore_1 // ->局部1=3 15: iload_3 //!! ->棧頂=2 16: ireturn // -> 2 17: astore 4 //將棧頂引用型數值存入第五個局部變量=any 19: iconst_3 //將int型數值3入棧 -> 棧頂3 20: istore_1 //將棧頂第一個int數值存入第二個局部變量 -> 局部2=3 21: aload 4 //將局部第五個局部變量(引用型)推送至棧頂 23: athrow //將棧頂的異常拋出 Exception table: from to target type 0 4 8 Class java/lang/Exception //0到4行對應的異常，對應#8中儲存的異常 0 4 17 any //Exeption之外的其他異常 8 13 17 any 17 19 17 any 復制代碼

在字節碼的4,5，以及13,14中執行的是同一個操作，就是將int型的3入操作數棧頂，並存入第二個局部變量。這正是我們源碼在finally語句塊中內容。也就是說，JVM在處理異常時，會在每個可能的分支都將finally語句重復執行一遍。 通過一步步分析字節碼，可以得出最后的運行結果是：

• 不發生異常時: return 1
• 發生異常時: return 2
• 發生非Exception及其子類的異常，拋出異常，不返回值

以上例子來自於《深入理解Java虛擬機 JVM高級特性與最佳實踐》 關於虛擬機字節碼指令表，也可以在《深入理解Java虛擬機 JVM高級特性與最佳實踐-附錄B》中獲取。

kotlin 函數擴展的實現

kotlin提供了擴展函數的語言特性，借助這個特性，我們可以給任意對象添加自定義方法。 以下示例為Object添加"sayHello"方法

//SayHello.kt package com.rhythm7 fun Any.sayHello() { println("Hello") } 復制代碼

編譯后，使用javap查看生成SayHelloKt.class文件的字節碼。

Classfile /E:/JavaCode/TestProj/out/production/TestProj/com/rhythm7/SayHelloKt.class
Last modified 2018-4-8; size 958 bytes
 MD5 checksum 780a04b75a91be7605cac4655b499f19
 Compiled from "SayHello.kt"
public final class com.rhythm7.SayHelloKt
 minor version: 0
 major version: 52
 flags: ACC_PUBLIC, ACC_FINAL, ACC_SUPER
Constant pool:
    //省略常量池部分字節碼
{
 public static final void sayHello(java.lang.Object);
   descriptor: (Ljava/lang/Object;)V
   flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
   Code:
     stack=2, locals=2, args_size=1
        0: aload_0
        1: ldc           #9                  // String $receiver
        3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
        6: ldc           #17                 // String Hello
        8: astore_1
        9: getstatic     #23                 // Field java/lang/System.out:Ljava/io/PrintStream;
       12: aload_1
       13: invokevirtual #28                 // Method java/io/PrintStream.println:(Ljava/lang/Object;)V
       16: return
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0      17     0 $receiver   Ljava/lang/Object;
     LineNumberTable:
       line 4: 6
       line 5: 16
   RuntimeInvisibleParameterAnnotations:
     0:
       0: #7()
}
SourceFile: "SayHello.kt"
復制代碼

觀察頭部發現,koltin為文件SayHello生成了一個類，類名"com.rhythm7.SayHelloKt". 由於我們一開始編寫SayHello.kt時並不希望SayHello是一個可實例化的對象類，所以，SayHelloKt是無法被實例化的，SayHelloKt並沒有任何一個構造器。 再觀察唯一的一個方法：發現Any.sayHello()的具體實現是靜態不可變方法的形式:

public static final void sayHello(java.lang.Object); 復制代碼

所以當我們在其他地方使用Any.sayHello()時，事實上等同於調用java的SayHelloKt.sayHello(Object)方法。 順便一提的是，當擴展的方法為Any時，意味着Any是non-null的，這時，編譯器會在方法體的開頭檢查參數的非空，即調用 kotlin.jvm.internal.Intrinsics.checkParameterIsNotNull(Object value, String paramName) 方法來檢查傳入的Any類型對象是否為空。如果我們擴展的函數為Any?.sayHello()，那么在編譯后的文件中則不會有這段字節碼的出現。

作者：咸魚不思議
鏈接：https://juejin.im/post/5aca2c366fb9a028c97a5609
來源：掘金