使用cmd查看電腦連接過的wifi密碼(二)

上次寫了一個查看wifi的bat文件（https://www.cnblogs.com/feiquan/p/9823402.html），發現有個問題就沒法保存到記事本，而且還要處理不同的系統語言，這次重新更新了一下文件。

獲取方式：

　　1.可直接拷貝代碼到記事本后改后綴為bat

　　2.百度網盤：　　　　　　

　　　　鏈接：https://pan.baidu.com/s/11syCrBvehtpPo7R9cfpk0g 

　　　　提取碼：8qhn 

主要有3個文件：

Password是最后密碼的存放文件夾，其中的文件是以時間命名的，保證不會覆蓋

WiFiPassswordSave.bat 是功能選擇界面（直接雙擊它運行）

seeWiFi.bat ：是第一個功能（直接查看wifi密碼）

saveWiFi.bat：是第二個功能（保存密碼到當前目錄下的Password\wifiPassword.txt），如果是直接雙擊此文件或者不帶參數，在輸出完成后會自動打開密碼所在的文件夾，如果在命令行中輸入（ saveWiFi.bat  h）加入參數 h,將會定位到密碼所在的文件夾，並列出文件目錄

提示：這三個bat文件必須要放在同一個文件夾下，如果使用cmd命令可單獨調用seeWiFi.bat 和saveWiFi.bat

更新情況：

 

REM echo UpdataDate:2018/10/22 23:41
REM echo Version:1.1.1v
REM              修復wifi名為空時,打印不完全
rem                重命名保存的文件名 主機名+用戶名+wifiPassword+當前時間
rem                更改臨時文件的位置

 

上代碼（可直接拷貝代碼到記事本后改后綴為bat）：

WiFiPassswordSave.bat 

@echo off
if not "%OS%"=="Windows_NT" EXIT
REM if not "%0"=="WiFiPassswordSave.bat" exit
chcp 65001 >nul
if "%1"=="back" (
echo ====================================
goto fun
)
Title WiFiPasswordSave
echo WiFiPasswordSave
color 07
echo ====================================
echo Author:feiquan
echo Create:2018/10/20 17:39
echo UpdataDate:2018/10/22 23:41
echo Version:1.1.1v
echo Function:See and Save your computer connnect all WiFi password
REM echo Function:See and Save your computer connnect all WiFi password
REM              修復wifi名為空時,打印不完全
rem                重命名保存的文件名
rem                更改臨時文件的位置
REM echo =====================================

rem 刪除不需要的文件
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )
if exist "%temp%\userfiles2.txt"  ( del %temp%\userfiles2.txt )
if exist "%temp%\password.txt"  (del %temp%\password.txt)
if exist "%temp%\wifiPassword2.txt"  ( del %temp%\wifiPassword2.txt )


:fun
rem 選擇功能
echo Select function:
echo     1.See WiFi password
echo     2.Save all Wifi Password to wifipassword.txt
echo     3.exit
echo =====================================

set num=2
set /p num=請輸入你想執行那個功能^(默認:2^)^:

if %num%==1 (
rem 功能一：直接查看wifi密碼
call seeWiFi.bat 

) else if %num%==2 (
rem 功能二：保存密碼到當前目錄下的Password\wifi%temp%\password.txt
call saveWiFi.bat 

) else (
rem 刪除不需要的文件
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )
if exist "%temp%\userfiles2.txt"  ( del %temp%\userfiles2.txt )
if exist "%temp%\password.txt"  (del %temp%\password.txt)
if exist "%temp%\wifiPassword2.txt"  ( del %temp%\wifiPassword2.txt )

exit
)

pause
exit

 

seeWiFi.bat 

 

@echo off
if not "%OS%"=="Windows_NT" EXIT
if not "%0"=="seeWiFi.bat" exit
chcp 65001 >nul
title seeWiFi
REM echo WiFiPasswordSave
REM echo ====================================
REM echo Author:feiquan
REM echo Create:2018/10/20 17:39
REM echo UpdataDate:2018/10/22 23:41
REM echo Version:1.1.1v
REM echo Function:See and Save your computer connnect all WiFi password
REM              修復wifi名為空時,打印不完全
rem                重命名保存的文件名
rem                更改臨時文件的位置
REM echo =====================================


rem 獲取用戶配置文件，實時刷新
netsh wlan show profiles |find "All User Profile" >%temp%\userfiles.txt
rem 提取SSID name 
powershell -Command "(gc %temp%\userfiles.txt) -replace '    All User Profile     : ', ''" >%temp%\userfiles2.txt

rem 刪除不需要的文件
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )

rem 功能一：直接查看wifi密碼
rem 列出wifi名
echo Your computer connnect all WiFi name:
for /f "tokens=*"  %%f in (%temp%\userfiles2.txt) do echo        %%f
rem 選擇wifi,給name賦值
echo =====================================
:loop
set /p name=Please input your WiFi name(SSID):
( netsh wlan show profiles name="%name%" key=clear |find "SSID name" ) ||echo     SSID name              : "%name%" 
( netsh wlan show profiles name="%name%" key=clear |find "Key Content" ) ||echo     Key Content            : NO exist
echo =====================================
:continue
set con=y
set /p con=Continue to look up other WiFi password^(默認:y^/n^/q^)^:
if "%con%"=="y" (
goto loop
) else if "%con%"=="n" (
call WiFiPassswordSave.bat back

) else if "%con%"=="q" (
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )
if exist "%temp%\userfiles2.txt"  ( del %temp%\userfiles2.txt )
exit
) else (
goto continue
)
rem 功能一：end

 

saveWiFi.bat

 

@echo off
if not "%OS%"=="Windows_NT" EXIT
if not "%0"=="saveWiFi.bat" exit
@echo off
chcp 65001 >nul
title saveWiFi
REM echo WiFiPasswordSave
REM echo ====================================
REM echo Author:feiquan
REM echo Create:2018/10/20 17:39
REM echo UpdataDate:2018/10/22 23:41
REM echo Version:1.1.1v
REM echo Function:See and Save your computer connnect all WiFi password
REM              修復wifi名為空時,打印不完全
rem                重命名保存的文件名
rem                更改臨時文件的位置
REM echo =====================================

echo Starting working ....

rem 刪除不需要的文件
if "%1"=="h" (
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )
if exist "%temp%\userfiles2.txt"  ( del %temp%\userfiles2.txt )
if exist "%temp%\password.txt"  (del %temp%\password.txt)
if exist "%temp%\wifiPassword2.txt"  ( del %temp%\wifiPassword2.txt )
)

rem 獲取用戶配置文件,實時刷新
netsh wlan show profiles |find "All User Profile" >%temp%\userfiles.txt
rem 提取SSID name 
powershell -Command "(gc %temp%\userfiles.txt) -replace '    All User Profile     : ', ''" >%temp%\userfiles2.txt

rem 刪除不需要的文件
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )

rem 功能二：保存密碼到%temp%\password.txt

rem 遍歷SSID name
for /F "tokens=*" %%i in (%temp%\userfiles2.txt) do (
echo ==========================================================>>%temp%\password.txt
((netsh wlan show profiles name="%%i" key=clear |find "SSID name")||echo     SSID name              : "%%i"  )>>%temp%\password.txt
((netsh wlan show profiles name="%%i" key=clear |find "Key Content")||echo     Key Content            : NO exist )>>%temp%\password.txt
)

rem 替換關鍵字
powershell -Command "(gc %temp%\password.txt) -replace 'SSID name',  'Wifi name'" >%temp%\wifiPassword2.txt
set cName=%computername%
set uName=%username%
powershell -Command "(gc %temp%\wifiPassword2.txt) -replace 'Key Content','Password   '>%cName%_%uName%_wifiPassword"$(Get-Date -Format 'yyyyMd Hms')".txt"

rem 刪除不需要的文件
if exist "%temp%\userfiles.txt"  ( del %temp%\userfiles.txt )
if exist "%temp%\userfiles2.txt"  ( del %temp%\userfiles2.txt )
if exist "%temp%\password.txt"  (del %temp%\password.txt)
if exist "%temp%\wifiPassword2.txt"  ( del %temp%\wifiPassword2.txt )

rem 移動文件
if not exist Password mkdir Password 
move %cName%_%uName%_wifiPassword* .\Password
cd Password

if not "%1"=="h" (
start .\ 
exit
)

dir
rem 功能二:end