溫濕度傳感器DHT11程序示例

 

DHT11概述

                       

HT11數字溫濕度傳感器是一款含有已校准數字信號輸出的溫濕度復合傳感器。 它應用專用的數字模塊采集技術和溫濕度傳感技術，確保產品具有極高的可靠性與卓越的長期穩定性。傳感器包括一個電阻式感濕元件和一個NTC測溫元件，並與一個高性能8位單片機相連接。因此該產品具有品質卓越、超快響應、抗干擾能力強、性價比極高等優點。每個DHT11傳感器都在極為精確的濕度校驗室中進行校准。校准系數以程序的形式儲存在OTP內存中，傳感器內部在檢測信號的處理過程中要調用這些校准系數。 單線制串行接口，使系統集成變得簡易快捷。超小的體積、極低的功耗，信號傳輸距離可達20米以上，使其成為各類應用甚至最為苛刻的應用場合的最佳選則。產品為 4 針單排引腳封裝。連接方便，特殊封裝形式可根據用戶需求而提供。

 

主要應用

 

 

 典型接線

引腳定義

 

電氣特性

 

單線雙向串行通信協議

DATA 用於微處理器與 DHT11之間的通訊和同步，采用單總線數據格式，一次通訊時間4ms左右，數據分小數部分和整數部分，具體格式在下面說明，當前小數部分用於以后擴展，現讀出為零。操作流程如下:
    一次完整的數據傳輸為40bit，高位先出。數據格式：8bit濕度整數數據+8bit濕度小數數據+8bi溫度整數數據+8bit溫度小數數據+8bit校驗和數據，傳送正確時校驗和數據等於“ 8bit濕度整數數據+8bit濕度小數數據+8bi溫度整數數據+8bit溫度小數數據”所得結果的末8位。

用戶MCU發送一次開始信號后,DHT11從低功耗模式轉換到高速模式，等待主機開始信號結束后，DHT11發送響應信號，送出40bit的數據，並觸發一次信號采集，用戶可選擇讀取部分數據。從模式下，DHT11接收到開始信號觸發一次溫濕度采集，如果沒有接收到主機發送開始信號，DHT11不會主動進行溫濕度采集，采集數據后轉換到低速模式。

通訊過程如圖1，2所示

圖1

圖2

總線空閑狀態為高電平,主機把總線拉低等待DHT11響應，主機把總線拉低必須大於18毫秒，保證DHT11能檢測到起始信號。主機發送開始信號結束后, 可以切換到輸入模式，或者輸出高電平，延時等待20-40us后, 讀取DHT11的響應信號。 DHT11接收到主機的開始信號后，等待主機開始信號結束，然后發送80us低電平響應信號。如果讀取響應信號為高電平，則DHT11沒有響應，請檢查線路是否連接正常。

DHT11發送響應信號后,再把總線拉高80us，准備發送數據。每一bit數據都以50us低電平時隙開始，高電平的長短決定了數據位是0還是1。格式見下面圖示。當最后一bit數據傳送完畢后，DHT11拉低總線50us，隨后總線由上拉電阻拉高進入空閑狀態。

數字0信號表示方法如圖4所示

圖3

數字1信號表示方法.如圖5所示

 

圖4

 

DHT11的Arduino程序示例

double Fahrenheit(double celsius) 
{  
  return 1.8 * celsius + 32;   //攝氏溫度度轉化為華氏溫度
}

double Kelvin(double celsius)
{  
  return  celsius + 273.15;   //攝氏溫度轉化為開氏溫度
}

// 露點（點在此溫度時，空氣飽和並產生露珠）
// 參考: http://wahiduddin.net/calc/density_algorithms.htm 
double dewPoint(double celsius, double humidity)
{
    double A0= 373.15/(273.15 + celsius);
    double SUM = -7.90298 * (A0-1);
    SUM += 5.02808 * log10(A0);
    SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
    SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
    SUM += log10(1013.246);
    double VP = pow(10, SUM-3) * humidity;
    double T = log(VP/0.61078);   // temp var
    return (241.88 * T) / (17.558-T);
}

// 快速計算露點，速度是5倍dewPoint()
// 參考: http://en.wikipedia.org/wiki/Dew_point
double dewPointFast(double celsius, double humidity)
{
        double a = 17.271;
        double b = 237.7;
        double temp = (a * celsius) / (b + celsius) + log(humidity/100);
        double Td = (b * temp) / (a - temp);
        return Td;
}

#include <dht11.h>  //加入dht11類庫
dht11 DHT11;    //定義DHT11
#define DHT11PIN 2   // DHT11的數字口接控制板的2號引腳

void setup()
{
  Serial.begin(9600);
  Serial.println("DHT11 TEST PROGRAM ");
  Serial.print("LIBRARY VERSION: ");
  Serial.println(DHT11LIB_VERSION);
  Serial.println();
}

void loop()
{
  Serial.println("\n");
  int chk = DHT11.read(DHT11PIN);   // 庫函數DHT11.read()的返回值
  Serial.print("Read sensor: ");
  switch (chk)
  {
    case DHTLIB_OK:   //沒有錯誤
                Serial.println("OK"); 
                break;
    case DHTLIB_ERROR_CHECKSUM:   //校驗錯誤
                Serial.println("Checksum error"); 
                break;
    case DHTLIB_ERROR_TIMEOUT:    //超時錯誤
                Serial.println("Time out error"); 
                break;
    default:       //未名的錯誤
                Serial.println("Unknown error"); 
                break;
  }

  Serial.print("Humidity (%): ");
  Serial.println((float)DHT11.humidity, 2);

  Serial.print("Temperature (oC): ");
  Serial.println((float)DHT11.temperature, 2);

  Serial.print("Temperature (oF): ");
  Serial.println(Fahrenheit(DHT11.temperature), 2);

  Serial.print("Temperature (K): ");
  Serial.println(Kelvin(DHT11.temperature), 2);

  Serial.print("Dew Point (oC): ");
  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));

  Serial.print("Dew PointFast (oC): ");
  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));

  delay(2000);
}

 

 

運行效果：