VBA中msgbox的用法小結

1、作用
在消息框中顯示信息，並等待用戶單擊按鈕，可返回單擊的按鈕值(比如“確定”或者“取消”)。通常用作顯示變量值的一種方式。
2、語法
MsgBox(Prompt[,Buttons][,Title][,Helpfile,Context])
參數說明：
(1)Prompt，必需的參數，為字符串，作為顯示在消息框中的消息文本。其最大長度約為1024個字符，由所用字符的寬度決定。如果prompt的內容超過一行，則可以在每一行之間用回車符(Chr(13))、換行符(Chr(10))或是回車與換行符的組合(Chr(13)&Chr(10))將各行分隔開來。
(2)Buttons，可選的參數，為數值表達式的值之和，指定顯示的按鈕的數目及形式、使用的圖標樣式、缺省按鈕及消息框的強制回應等，可以此定制消息框。若省略該參數，則其缺省值為0。設置值見下表。
(3)Title，可選的參數，表示在消息框的標題欄中所顯示的文本。若省略該參數，則將應用程序名放在標題欄中。
(4)Helpfile，可選的參數，為字符串表達式，提供幫助文件。若有Helpfile，則必須有Context。
(5)Context，可選的參數，為數值表達式，提供幫助主題。若有Context，則必須有Helpfile。
3、Button參數
用於MsgBox函數中Button參數的常量
常量                值               說明
vbOKOnly             0   只顯示“確定”按鈕
VbOKCancel           1   顯示“確定”和“取消”按鈕
VbAbortRetryIgnore   2   顯示“終止”、“重試”和“忽略” 按鈕
VbYesNoCancel        3   顯示“是”、“否”和“取消”按鈕
VbYesNo              4   顯示“是”和“否”按鈕
VbRetryCancel        5   顯示“重試”和“取消”按鈕
VbCritical           16 顯示“關鍵信息”圖標
VbQuestion           32 顯示“警告詢問”圖標
VbExclamation        48 顯示“警告消息”圖標
VbInformation        64 顯示“通知消息”圖標
vbDefaultButton1      0 第一個按鈕是缺省值(缺省設置)
vbDefaultButton2     256第二個按鈕是缺省值
vbDefaultButton3     512第三個按鈕是缺省值
vbDefaultButton4     768第四個按鈕是缺省值
vbApplicationModal     0應用程序強制返回；應用程序一直被掛起，直到用戶對消息框
作出響應才繼續工作
vbSystemModal        4096系統強制返回；全部應用程序都被掛起，直到用戶對消息框作
出響應才繼續工作
vbMsgBoxHelpButton    16384將Help按鈕添加到消息框
VbMsgBoxSetForeground 65536指定消息框窗口作為前景窗口
vbMsgBoxRight         524288文本為右對齊
vbMsgBoxRtlReading   1048576指定文本應為在希伯來和阿拉伯語系統中的從右到左顯示
說明：
(1)第一組值(0–5)描述了消息框中顯示的按鈕的類型與數目；第二組值(16,32,48,64)描述了圖標的樣式；第三組值(0,256,512,768)說明哪一個按鈕是缺省值；而第四組值(0,4096)則決定消息框的強制返回性。將這些數字相加以生成Buttons參數值的時候，只能由每組值取用一個數字。
(2)這些常數都是VBA指定的，可以在程序代碼中使用這些常數名稱代替實際數值。
4、返回值
用於MsgBox函數返回值的常量
常數          值       說明
vbOK          1        確定
vbCancel      2        取消
vbAbort       3        終止
vbRetry       4        重試
vbIgnore      5        忽略
vbYes         6        是
vbNo          7        否
5、相關說明
(1) 如果同時提供了Helpfile與Context參數，可以按F1鍵來查看與Context相應的幫助主題，Excel通常會在輸入框中自動添加一個幫助(Help)按鈕。
(2)若在消息框中顯示“取消”按鈕，則按下ESC鍵與單擊“取消”按鈕效果相同。若消息框中有“幫助”按鈕，則提供相關的幫助信息。
(3)如果要輸入多個參數並省略中間的某些參數，則必須在相應位置加入逗號分界符。
6、示例
(1)使用 MsgBox 函數，在具有“是”及“否”按鈕的對話框中顯示一條嚴重錯誤信息。示例中的缺省按鈕為“否”，MsgBox函數的返回值視用戶按哪一個鈕而定。並假設DEMO.HLP為一幫助文件，其中有一個幫助主題代碼為1000。
Dim Msg,Style,Title,Help,Ctxt,Response,MyString
Msg="Do you want to continue ?"    ’定義消息文本
Style = vbYesNo + vbCritical + vbDefaultButton2    ' 定義按鈕
Title = "MsgBox Demonstration"    ' 定義標題文本
Help = "DEMO.HLP"    ' 定義幫助文件
Ctxt = 1000    ' 定義幫助主題
Response = MsgBox(Msg, Style, Title, Help, Ctxt)
If Response = vbYes Then    ' 用戶按下“是”
    MyString = "Yes"    ' 完成某操作
Else    ' 用戶按下“否”
    MyString = "No"    ' 完成某操作
End If
(2)只顯示某消息
MsgBox “Hello!” 
(3)將消息框返回的結果賦值給變量
Ans=MsgBox(“Continue?”,vbYesNo)
If MsgBox(“Continue?”,vbYesNo)<>vbYes Then Exit Sub
(4)使用常量的組合，賦值組Config變量，並設置第二個按鈕為缺省按鈕
Config=vbYesNo+vbQuestion+vbDefaultButton2
(5)若要在消息中強制換行，可在文本中使用vbCrLf(或vbNewLine)常量，用&加空格與字符隔開。如
MsgBox “This is the first line.” & vbNewLine & “Second line.”
(6)可以在消息框中使用vbTab常量插入一個制表符。下面的過程使用一個消息框來顯示5×5單元格區域中的所有值，用vbTab常量分隔列並使用vbCrLf常量插入一個新行。注意在MsgBox函數最多只顯示1024個字符，因此限制了可顯示的單元格數。
Option Explicit
Sub ShowRangeValue()
Dim Msg As String
Dim r As Integer, c As Integer
Msg = ""
For r = 1 To 5
For c = 1 To 5
    Msg = Msg & Cells(r, c) & vbTab
Next c
Msg = Msg & vbCrLf
Next r
MsgBox Msg
End Sub
(7)在消息框語句中運用工作表函數以及設置顯示的數置格式，如下面語句所示：
MsgBox " selection has " & m & " cells ." & Chr(13) & " the sum is :" & Application.WorksheetFunction.Sum(Selection) & Chr(13) & "the average is :" & Format(Application.WorksheetFunction.Average(Selection), "#,##0.00"), vbInformation, "selection count & sum & average" & Chr(13)