顯式游標和隱式游標的區別

【Oracle】PL/SQL 顯式游標、隱式游標、動態游標

在PL/SQL塊中執行SELECT、INSERT、DELETE和UPDATE語句時，ORACLE會在內存中為其分配上下文區（Context Area），即緩沖區。游標是指向該區的一個指針，或是命名一個工作區（Work Area），或是一種結構化數據類型。

在每個用戶會話中，可以同時打開多個游標，其數量由數據庫初始化參數文件中的OPEN_CURSORS參數定義。

對於不同的SQL語句，游標的使用情況不同：

SQL語句	游標
非查詢語句	隱式的
結果是單行的查詢語句	隱式的或顯示的
結果是多行的查詢語句	顯示的

處理顯式游標

例：

DECLARE
   CURSOR c4(dept_id NUMBER, j_id VARCHAR2) --1、聲明游標,有參數沒有返回值
   IS
      SELECT first_name f_name, hire_date FROM employees
      WHERE department_id = dept_id AND job_id = j_id;

    --基於游標定義記錄變量，比聲明記錄類型變量要方便，不容易出錯
    v_emp_record c4%ROWTYPE;
BEGIN
   OPEN c4(90, 'AD_VP');             --2、打開游標,傳遞參數值
   LOOP
      FETCH c4 INTO v_emp_record;    --3、提取游標fetch into
      IF c4%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_emp_record.f_name||'的雇佣日期是'
                            ||v_emp_record.hire_date);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經處理完結果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c4;                         --4、關閉游標
END;

退出LOOP或者用：

EXIT WHEN c4%NOTFOUND;

游標屬性：

 Cursor_name%FOUND     布爾型屬性，當最近一次提取游標操作FETCH成功則為 TRUE,否則為FALSE；

 Cursor_name%NOTFOUND   布爾型屬性，與%FOUND相反；——注意區別於DO_DATA_FOUND(select into拋出異常)

 Cursor_name%ISOPEN     布爾型屬性，當游標已打開時返回 TRUE；

 Cursor_name%ROWCOUNT   數字型屬性，返回已從游標中讀取的記錄數。

 

游標的for循環

PL/SQL語言提供了游標FOR循環語句，自動執行游標的OPEN、FETCH、CLOSE語句和循環語句的功能；

1. 當進入循環時，游標FOR循環語句自動打開游標，並提取第一行游標數據；
2. 當程序處理完當前所提取的數據而進入下一次循環時，游標FOR循環語句自動提取下一行數據供程序處理；
3. 當提取完結果集合中的所有數據行后結束循環，並自動關閉游標。

格式： 

  FOR index_variable IN cursor_name[(value[, value]…)] LOOP
    -- 游標數據處理代碼
  END LOOP;

 

其中：

index_variable為游標FOR 循環語句隱含聲明的索引變量，該變量為記錄變量，其結構與游標查詢語句返回的結構集合的結構相同。在程序中可以通過引用該索引記錄變量元素來讀取所提取的游標數據，index_variable中各元素的名稱與游標查詢語句選擇列表中所制定的列名相同。如果在游標查詢語句的選擇列表中存在計算列，則必須為這些計算列指定別名后才能通過游標FOR 循環語句中的索引變量來訪問這些列數據。

例：

DECLARE
  CURSOR c_cursor(dept_no NUMBER DEFAULT 10)
  IS
    SELECT department_name, location_id FROM departments WHERE department_id <= dept_no;
BEGIN
    --當dept_no參數值為30
    FOR c1_rec IN c_cursor(30) LOOP
         DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;

    --使用默認的dept_no參數值10
    FOR c1_rec IN c_cursor LOOP
         DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
END;

或者可以在游標FOR循環語句中使用子查詢

BEGIN
    FOR c1_rec IN(SELECT department_name, location_id FROM departments) LOOP
       DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
END;

 

處理隱式游標

顯式游標主要是用於對查詢語句的處理，尤其是在查詢結果為多條記錄的情況下；

而對於非查詢語句，如修改、刪除操作，則由ORACLE 系統自動地為這些操作設置游標並創建其工作區，隱式游標的名字為SQL，這是由ORACLE 系統定義的。

對於隱式游標的操作，如定義、打開、取值及關閉操作，都由ORACLE 系統自動地完成，無需用戶進行處理。用戶只能通過隱式游標的相關屬性，來完成相應的操作。在隱式游標的工作區中，所存放的數據是與用戶自定義的顯示游標無關的、最新處理的一條SQL 語句所包含的數據。

格式調用為： SQL%

DECLARE
   v_rows NUMBER;
BEGIN
   --更新數據
   UPDATE employees SET salary = 30000
     WHERE department_id = 90 AND job_id = 'AD_VP';
   --獲取默認游標的屬性值
   v_rows := SQL%ROWCOUNT;
   DBMS_OUTPUT.PUT_LINE('更新了'||v_rows||'個雇員的工資');

    --刪除指定雇員；如果部門中沒有雇員，則刪除部門
    DELETE FROM employees WHERE department_id=v_deptno;
    IF SQL%NOTFOUND THEN
        DELETE FROM departments WHERE department_id=v_deptno;
    END IF;
END;

更新或刪除當前游標數據

游標查詢語句中必須使用FOR UPDATE選項，以便在打開游標時鎖定游標結果集合在表中對應數據行的所有列和部分列。

如果另一個會話已對活動集中的行加了鎖，那么SELECT FOR UPDATE操作一直等待到其它的會話釋放這些鎖后才繼續自己的操作；對於這種情況，當加上NOWAIT子句時，如果這些行真的被另一個會話鎖定，則OPEN立即返回並給出：

ORA-0054 ：resource busy  and  acquire with nowait specified.

 

 

DECLARE
    V_deptno employees.department_id%TYPE :=&p_deptno;
    CURSOR emp_cursor
  IS
  SELECT employees.employee_id, employees.salary
    FROM employees WHERE employees.department_id=v_deptno
  FOR UPDATE NOWAIT;                    --1、for update
BEGIN
    FOR emp_record IN emp_cursor LOOP
      IF emp_record.salary < 1500 THEN
        UPDATE employees SET salary=1500
            WHERE CURRENT OF emp_cursor; --2、WHERE CURRENT OF cursor_name子句
      END IF;
    END LOOP;
END;

動態游標

與游標一樣，動態游標（游標變量）也是一個指向多行查詢結果集合中當前數據行的指針。但與游標不同的是，游標變量是動態的，而游標是靜態的。

游標只能與指定的查詢相連，即固定指向一個查詢的內存處理區域，而游標變量則可與不同的查詢語句相連，它可以指向不同查詢語句的內存處理區域（但不能同時指向多個內存處理區域，在某一時刻只能與一個查詢語句相連），只要這些查詢語句的返回類型兼容即可。

 

DECLARE
   --定義一個游標數據類型
   TYPE emp_cursor_type IS REF CURSOR;
   --聲明一個游標變量
   c1 EMP_CURSOR_TYPE;
   --聲明兩個記錄變量
   v_emp_record employees%ROWTYPE;
   v_reg_record regions%ROWTYPE;

BEGIN
   OPEN c1 FOR SELECT * FROM employees WHERE department_id = 20;
   LOOP
      FETCH c1 INTO v_emp_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_emp_record.first_name||'的雇佣日期是'
                            ||v_emp_record.hire_date);
   END LOOP;
   --將同一個游標變量對應到另一個SELECT語句
   OPEN c1 FOR SELECT * FROM regions WHERE region_id IN（1，2）;
   LOOP
      FETCH c1 INTO v_reg_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_reg_record.region_id||'表示'
                            ||v_reg_record.region_name);
   END LOOP;
   CLOSE c1;
END;