基於oracle 的PL/SQL編程 -變量使用

 

1. 需要開啟的服務：  本機安裝的oracle ，默認是開機啟動服務的，開機時間太慢，關閉了，需要手動打開：

OracleDBConsoleorcl

OracleOraDb10g_home1iSQL*Plus

OracleOraDb10g_home1TNSListener

OracleServiceORCL   這個后面的ORCL就是數據庫名字，官方術語叫做數據庫sid

2.打開PL/SQL工具，用戶名scott 登陸sid為ORCL的數據庫， 密碼 tiger

3.打開一個測試窗口，如下

-- Created on 2018/6/3 by ADMINISTRATOR 
declare
  -- 聲明本地變量的地方，包括游標(結果集類型變量)，如果沒有，declare可以去掉
  --相當於java的 public class A{}
  i integer;
begin
  -- 執行部分
  --相當於Java的public static void main(String[] args)
  --異常處理
end;

4.打印helloworld

結果如下：

dbms_output是oracle的程序包，put_line()是調用的方法

在命令行中打印：需要先設置 set serveroutput on ,才會將打印語句打印出來，否則只執行不打印。

 

 

5. PLSQL變量的使用：

PLSQL中的變量分兩種：

(1)普通數據類型：char varchar2 date number(整數和小數) boolean long

(2)特殊變量類型（引用變量、記錄型變量）

變量的聲明方式為：變量名 變量類型（變量長度） ,例如：v_name varchar2(20)

變量賦值：

　　(1)聲明時使用 := 直接賦值：v_name varchar2(20) := ‘zhangsan’        只寫=，則是進行比較

　　(2)語句賦值： select  值  into 變量名 

 5.1 普通變量的使用

-- 聲明一個人的信息 姓名 薪水 地址  
declare
  -- 姓名 不能使用name,這是保留字
  v_name varchar2(50) := '張三';
  -- 薪水   小數：number(總長度(小數加整數的位數)，小數位數) v_sal number(6,2) --1000.00
  v_sal number;
  --地址
  v_addr varchar2(200);
begin
  --直接賦值
  v_sal := 15000;
  --語句賦值
  select '上海市南京路' into v_addr from dual; --實際工作中應該是from 某個表 
  -- 打印變量  || 是拼接符，相當於java 的+
  dbms_output.put_line('姓名：' || v_name || ',薪水：' || v_sal || ',地址：' || v_addr);
end;

執行結果：

5.2 引用變量的使用

引用變量：變量的類型和長度取決於表中字段的類型和長度（變量的類型和長度引用表中字段的類型和長度），通過  表名.列名%TYPE 指定變量的類型和長度，例如 v_name emp.ename%TYPE

引用型變量的好處：使用普通變量定義方式，需要知道表中列的類型，而使用引用類型不需要考慮列的類型，使用%TYPE是非常號的編程風格，因為它使得PL/SQL更加靈活，更加適應於對數據庫定義的更新。

 

-- 查詢emp表中7839號員工的個人信息，打印姓名和薪水
declare
  -- 姓名 定義的是引用變量
  v_ename emp.ename%TYPE;
  -- 薪水  
  v_sal emp.sal%TYPE;

begin
  --查詢姓名和薪水並賦值給變量，。使用select into 語句賦值
  select ename, sal into v_ename, v_sal from emp where empno = 7839;
  dbms_output.put_line('姓名:' || v_ename || ',薪水:' || v_sal);

end;

結果：

5.3 記錄型變量

記錄型變量 默認接接收 表中的一行數據，不能指定字段，相當於java中的一個對象。

語法： 變量名稱 表名%ROWTYPE 例如 v_emp emp%rowtype;   通過 變量名.字段名 的方式獲取變量中的值

 

--記錄型變量示例：用該變量接收表中一行sql的信息
declare
  -- 記錄型變量
  v_emp emp%ROWTYPE;

begin
  --查詢所有字段並賦值給變量，字段名用v_emp.字段名 表示
  select * into v_emp from emp where empno = 7839;
  dbms_output.put_line('姓名:' || v_emp.ename || ',薪水:' || v_emp.sal);

end;

結果：

6.流程控制：

6.1  條件分支，語法：

BEGIN

 　　IF 條件1 then  執行1；

 　　　　Elsif 條件2 then 執行2 ；   --注意不是 elseif  ，是elsif

　　　　 Else  執行3

         End if；

END

 

-- 判斷emp表中記錄是否超過20條，10-20 之間，或者10條以下 
declare
  --聲明變量接收emp表中記錄數
  v_count number;
begin
  -- 查詢並賦值給變量
  select count(1)  into v_count from emp;
  --判斷打印
  if v_count > 20 then
    dbms_output.put_line('emp表中的記錄數在20條以上為' || v_count);
  elsif v_count >= 10 then
    dbms_output.put_line('emp表中的記錄數在10-20條之間為' || v_count);
  else
    dbms_output.put_line('emp表中的記錄數在10條以下為' || v_count);
  end if;

end;

執行結果：

   select * 結果如下：

6.2  loop循環.此處只記錄loop循環的使用。 循環兩個要點：1.循環變量初值，循環體中循環變量值要發生變化，

-- 循環打印1-10
declare
  -- 聲明一個循環變量並賦初值
  v_num number := 1;
begin
  loop
    exit when v_num > 10; 
    dbms_output.put_line(v_num);
    --循環變量的自增長
    v_num := v_num + 1;
  end loop;
end;

 7.特殊的變量—— 游標，本質上是一條查詢語句的結果的封裝，只能往前，不能往后

用於臨時存儲一個查詢返回的多行數據（結果集，類似於Java的jdbc連接返回的resultset集合），通過遍歷游標，可以逐行訪問處理該結果集的數據

游標使用方法：聲明 打開 讀取 關閉

語法：

游標聲明：    CURSOR  游標名[(參數列表)] IS 查詢語句

游標打開：    Open 游標名;

游標的取值： FETCH 游標名 into  變量列表;

游標關閉：    CLOSE 游標名

游標屬性:

 

%NOTFOUND 是在游標中找不到元素時返回TRUE，通常用於判斷，退出循環

7.1 不帶參數的游標 示例：

-- 使用游標查詢emp表中所有員工的姓名和工資，並將其依次打印出來 
declare
  -- 聲明游標
  cursor c_emp is
    select ename, sal from emp;
  --聲明變量接收游標中的數據
  v_ename emp.ename%TYPE;
  v_sal   emp.sal%TYPE;
begin
  -- 打開游標
  open c_emp;
  -- 遍歷游標
  loop
    --獲取游標中的數據，如果有的話就賦值給變量
    fetch c_emp
      into v_ename, v_sal;
    exit when c_emp%notfound; --c_emp%notfound 沒有數據時返回true
    dbms_output.put_line('姓名:' || v_ename || ',薪水:' || v_sal);
  end loop;

  --關閉游標
  close c_emp;

end;

結果如下:

7.2 帶輸入參數的游標：

-- 使用游標查詢emp表中某個部門員工的姓名和工資，並將其依次打印出來 
declare
  -- 聲明帶參數的游標，在聲明時加上形參，select語句里面加上查詢條件
  cursor c_emp(v_deptno emp.deptno%TYPE) is
    select ename, sal from emp where deptno = v_deptno;
  --聲明變量接收游標中的數據
  v_ename emp.ename%TYPE;
  v_sal   emp.sal%TYPE;
begin
  open c_emp(10); -- 打開游標時加上實參
  loop  -- 遍歷游標
    fetch c_emp into v_ename, v_sal;  --獲取游標中的數據，如果有的話就賦值給變量
    --在判斷之前先獲取一下數據，看有還是沒有 
    exit when c_emp%notfound; --c_emp%notfound 沒有數據時返回true
    dbms_output.put_line('姓名:' || v_ename || ',薪水:' || v_sal);
  end loop;
  close c_emp;  --關閉游標

end;

上述游標使用語句，相當於一個匿名的函數，當測試窗口關閉，語句也就沒有了，無法實現復用。如果想要在窗口關閉了之后還能使用上面那段語句，就需要存儲過程了。參見下文存儲過程學習記錄。