[oracle] Oracle存儲過程里操作BLOB的字節數據的辦法，例如寫入32位整數

作者： zyl910

一、緣由

BLOB是指二進制大對象，也就是英文Binary Large Object的縮寫。
在很多時候，我們是通過其他編程語言（如Java）訪問BLOB的字節數據，進行字節級的操作的。
但是有些時候工作量很小，感覺專門為BLOB字節級操作而專門開發個程序，是比較麻煩的。於是我研究了一下如何直接在Oracle存儲過程里操作BLOB的字節數據。

二、辦法

2.1 基本操作

使用 length 函數，可以獲取blob的字節長度。如 v_len := length(i_blob); 。
與字符串（如 varchar2 等）一樣，blob為 null 時，length的返回值是 null。故建議加上 nvl 做一下轉換，如 v_len := nvl(length(i_blob), 0); 。

為了避免 null 問題，可使用 empty_blob 函數，它的作用是返回一個長度為0的blob。如 v_blob := empty_blob(); 。

empty_blob返回的blog只是一個初始化，它是不能修改字節數據的。於是需要使用 dbms_lob.createtemporary 來創建一個能進行字節數據操作的臨時blob。如 dbms_lob.createtemporary(v_blob, TRUE); 。

2.2 DBMS_LOB包

為了便於BLOB類型的使用，Oracle官方提供了 DBMS_LOB 包，它提供了很多工具函數。例如先前我們使用了createtemporary函數。
DBMS_LOB所提供的過程有——

• APPEND：將源LOB中的內容加到目的LOB中。
• CLOSE：關閉已經打開的LOB。
• CREATETEMPORARY：在用戶的臨時表空間中，建立臨時LOB。
• FILECLOSE：關閉打開的BFILE定位符所指向的OS文件。
• FILECLOSEALL：關閉當前會話已經打開的所有BFILE文件。
• FILEEXISTS：確定file_loc對應的OS文件是否存在，1：存在。0：不存在。
• FILEGETNAME：獲取BFILE定位符所對應的目錄別名和文件名。
• FILEISOPEN：確定BFILE對應的OS文件是否打開。
• FREETEMPORARY：釋放在默認臨時表空間中的臨時LOB。
• FILEOPEN：打開文件。
• GETCHUNKSIZE：當建立包含CLOB/BLOB列的表時，通過指定CHUNK參數可以指定操縱LOB需要分配的字節數（數據庫尺寸的整數倍）默認為數據塊的尺寸。
• COPY：從源LOB中復制數據到目的LOB。
• ERASE：刪除LOB中全部或部分內容。
• TRIM：將LOB值減少到指定的長度。
• WRITE：向LOB中寫入數據。
• INSTR：返回特定樣式數據從LOB某偏移位置開始出現N次的具體位置。
• IDOPEN：確定LOB是否打開，打開：1，未打開：0。
• ISTEMPORARY：確定定位符是否為臨時LOB。
• LOADFROMFILE：將BFILE的部分或全部內容復制到目標LOB變量。
• LOADBLOBFROMFILE：將BFILE數據裝載到BLOB中，並且在裝載后取得最新的偏移位置。
• OPEN：打開LOB，open_mode（只讀：dbms_lob.lob_readonly，寫：dbms_lob.lob_readwrite）。
• COMPARE：比較兩個同種數據類型的LOB的部分或全部值是否相同。
• GETLENGTH：獲取LOB的長度。
• READ：從LOB中讀出數據。
• SUBSTR：與字符處理函數SUBSTR使用方法一樣。
• WRITEAPPEND：將緩沖區數據寫到LOB尾部。

有了DBMS_LOB包后，對於（變量級的）BLOB操作就比較方便了。例如我們想將兩個blob的內容，連續拼接到1個blob中，則可以這樣做——

  function test_blob_join(i_blob1 in blob, i_blob2 in blob) return blob is
    v_rt blob := empty_blob();
  begin
    dbms_lob.createtemporary(v_rt, TRUE);  -- 分配臨時的 blob .
    dbms_lob.append(v_rt, i_blob1);        -- 拼接 i_blob1 .
    dbms_lob.append(v_rt, i_blob2);        -- 拼接 i_blob2 .
    return v_rt;
  end;

可這樣測試——

select PKG_FINGER.test_blob_join(hextoraw('0102'), hextoraw('A1A2')) from dual;

它返回blob的字節數據是 01 02 A1 A2。驗證通過。

2.3 字節級操作與RAW數據類型

現在對實現BLOB的的變量級操作是沒有問題了。那么，該怎樣實現BLOB的字節級操作呢？
例如——怎么從blob中截取位置開始的一串字節？在blob中替換每個位置的字節？在blob的最后追加字節數據？
其實dbms_lob的 substr、write、writeappend 可分別解決這3個問題。
然后仔細一看，會發現這些過程使用了 RAW 類型。
對於RAW類型，很多資料是這樣說的——

RAW類型是Oracle中用於保存位串的一種數據類型，類似於CHAR，使用RAW（L) 方式聲明，最長可達32767字節。

RAW與BLOB的關系——

• BLOB中的一段字節數據，就是RAW類型的。例如通過 dbms_lob.substr 截取得到的數據。
• 其次可根據 RAW數據 去替換BLOB中的某段字節數據。即使用 dbms_lob.write 。
• 可在BLOB的最后追加 RAW數據 。即使用 dbms_lob.writeappend 。
• Oracle支持 RAW 隱式轉型為 BLOB 類型。

觀察dbms_lob的幫助文檔，會發現每個函數既有BLOB版，又有CLOB版。而且，CLOB版用VARCHAR2類型時，其BLOB版是RAW類型。即 RAW與VARCHAR2 是類似的，一個是字節串，一個是字符串。
許多常用的字符串函數也對 RAW 是有效的。例如 length 與 sustr 。

RAW 可用十六進制字符串來表示。所以一般使用 hextoraw 函數，將十六進制字符串轉為RAW。例如 hextoraw('A1A2') 。
RAW 可看作十六進制字符串。所以對raw變量使用length函數時，其返回值是 字節長度的2倍（因為對於十六進制字符串，一個字節是用2個十六進制字符表示的）。substr 等函數也存在同樣的情況。
還可以用 rawtohex，將 RAW類型的數據 轉換為 十六進制字符串（VARCHAR2）。

2.4 UTL_RAW包

上面提到 RAW 的length結果是 字節長度的2倍，它是不太方便的。這時可以使用 UTL_RAW包。例如 utl_raw.length的結果就是 字節長度。
常見的UTL_RAW過程有——

• length：長度計算函數，得到一個raw類型變量的長度，單位為字節
• concat：拼接函數，用於拼接兩個raw類型變量
• substr：獲取子串函數
• bit_and：位與函數
• bit_or：位或函數
• bit_xor：位異或函數
• overlay：給指定字節賦值
• cast_to_raw：字符串 轉 RAW
• cast_to_varchar2：RAW 轉 varchar2
• cast_to_nvarchar2：RAW 轉 nvarchar2
• cast_to_number：RAW 轉 number
• cast_from_number：number 轉 RAW
• cast_to_binary_integer：RAW 轉 binary_integer
• cast_from_binary_integer：binary_integer 轉 RAW

三、使用心得

3.1 32位整數轉換函數

最開始不知道 binary_integer就是32位整數。於是自己寫了32位整數與 RAW 的轉換函數。雖然現在用不上了，但覺得它們還是很適合作為應用示范的。

  -- 將數字轉為 raw(4)類型的 大端方式32位整數 .
  function TO_INT32BE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負數.
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  
  -- 將數字轉為 raw(4)類型的 小端方式32位整數 .
  function TO_INT32LE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負數.
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  
  -- 將 存儲在raw(4)中的大端方式32位整數 轉為數字. 值域為 0~4294967295 .
  function FROM_INT32BE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個字節看作 2個（十六進制）字符.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := '000000' || rawtohex(i_src);
      v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    end if;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;
  
  -- 將 存儲在raw(4)中的小端方式32位整數 轉為數字. 值域為 0~4294967295 .
  function FROM_INT32LE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個字節看作 2個（十六進制）字符.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := rawtohex(i_src) || '000000';
      v_hexstr := substr(v_hexstr, 1, 8);
    end if;
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;

3.2 將32位整數追加到blob

很多時候需要給blob追加一個 32位整數。現在利用上面的函數，可以這樣做——

      v_tempraw := TO_INT32LE(nvl(i_int32, 0));
      dbms_lob.writeappend(v_blob, 4, v_tempraw);

（完）

參考文獻

• Oracle Database Online Documentation / DBMS_LOB . https://docs.oracle.com/cd/E11882_01/timesten.112/e21645/d_lob.htm#TTPLP600
• Oracle Database Online Documentation / UTL_RAW . https://docs.oracle.com/cd/E11882_01/timesten.112/e21645/u_raw.htm#TTPLP072
• 旺仔丶小饅頭《DBMS_LOB》 . https://www.cnblogs.com/wang-chen/p/5756475.html
• Hornsey《Oracle RAW類型基本操作函數及使用示例》 . https://blog.csdn.net/nalw2012/article/details/72466256
• jimeper《ORACLE十進制與十六進制的轉換》 . https://www.cnblogs.com/jimeper/archive/2013/01/24/2875245.html