PPM即Pulse Position Modulation（脈沖位置調制），利用脈沖的相對位置來傳遞信息的一種調制方式。在這種調制方式中，數據能夠高速的傳遞。本文就來詳細介紹一下PPM解碼器。
1、PPM的功能描述
輸入信號
- clk，時鍾周期為0.59us
- rst，異步復位信號，低電平有效
- din，輸入的PPM編碼后的數據
輸出信號
- [7:0] dout，PPM解碼后的8位數據
- d_en，輸出數據有效標志，高電平有效，持續一個時鍾周期
- f_en，幀頭檢測有效標志，高電平有效，持續一個時鍾周期
2、PPM的功能分析
計數器用來控制時序，移位寄存器用來暫存數據，狀態機用來進行狀態轉換。
2.1計數器
時鍾的周期是0.59us，而輸入的每一位數據寬度為9.44us=0.59us※16，解碼2bit的數據需要的時間為75.52us=0.59us※128，解碼一個完整的8位數據，需要302.08us=75.52us※4。基於以上分析，我們可以設置3個計數器來控制數據的采樣。
- count0，0~15，每16個時鍾周期采一位din信號。
- count1，0~7，解碼2bit需要采到8位din信號。
- count2，0~3，完成一個完整的8位信號，需要解碼2bit數據4次。
2.2移位寄存器
我們要對輸入數據的8位數據進行判讀，就要求我們對數據進行暫存。這里我們采用移位寄存器對輸入數據進行暫存。與此同時，輸出的8bit數據是2bit數據輸出累加到8bit，所以我們也需要移位寄存器對輸出數據進行暫存。
- [7:0] reg1，對輸入的數據進行移位操作，{reg1[6:0],din}。
- [7:0] reg2，對輸出的數據進行暫存，等待8bit移滿，就進行數據的輸出，{2'b11,reg2[7:2]}，{2'b00,reg2[7:2]}，{2'b10,reg2[7:2]}，{2'b01,reg2[7:2]}。
2.3狀態機
在傳送數據的時候，主要有兩個狀態。要么是收到幀頭解碼數據，要么是沒有收到幀頭不進行解碼。
- S0，表示沒有收到幀頭，處於未工作狀態。
- S1，表示收到幀頭，開始進行解碼。
注：以上電路圖和狀態轉移圖的判斷條件有所簡化。
具體代碼如下：
module PPM(
clk,
rst,
din,
dout,
d_en,
f_en);
input clk,rst;
input din;
output [7:0] dout;
output d_en,f_en;
reg [7:0] dout;
reg d_en,f_en;
reg [3:0] count0;
reg [2:0] count1;
reg [2:0] count2;
reg [7:0] reg1;
reg [7:0] reg2;
reg cs,ns;
parameter SOF=8'b01111011,
EOF=4'b1101,
d_00=8'b10111111,
d_01=8'b11101111,
d_10=8'b11111011,
d_11=8'b11111110,
S0=1'b0,
S1=1'b1;
always@(posedge clk or negedge rst)
begin
if(!rst)
cs<=S0;
else
cs<=ns;
end
always@(cs or count0 or count1 or reg1)
begin
case(cs)
S0:begin
if((count0==15)&&(reg1==SOF))
begin
ns=S1;
f_en=1'b1;
end
else
begin
ns=S0;
f_en=1'b0;
end
end
S1:begin
if((count0==15)&&(count1==3)&&(reg1[3:0]==EOF))
begin
ns=S0;
f_en=1'b0;
end
else
begin
ns=S1;
f_en=1'b0;
end
end
default:begin
ns=ns;
f_en=1'b0;
end
endcase
end
always@(posedge clk or negedge rst)
begin
if(!rst)
begin
count0<=0;
reg1<=8'b00000000;
end
else
begin
if(count0==15)
begin
reg1<={reg1[6:0],din};
count0<=0;
end
else
count0<=count0+1;
end
end
always@(posedge clk or negedge rst)
begin
if(!rst)
count1<=0;
else
begin
if(cs==S1)
if(count0==15)
if(count1==7)
count1<=0;
else
count1<=count1+1;
else
count1<=count1;
else
count1<=0;
end
end
always@(posedge clk or negedge rst)
begin
if(!rst)
count2<=0;
else
begin
if((count0==15)&&(cs==S1)&&(count1==7))
if(count2==3)
count2<=0;
else
count2<=count2+1;
end
end
always@(posedge clk or negedge rst)
begin
if(!rst)
d_en<=0;
else
begin
if((count0==15)&&(count1==7)&&(cs==S1)&&(count2==3))
d_en<=1;
else
d_en<=0;
end
end
always@(posedge clk or negedge rst)
begin
if(!rst)
reg2<=8'b00000000;
else
begin
if(cs==S1)
if((count0==15)&&(count1==7)&&(count2<=3))
begin
case(reg1)
d_00:reg2<={2'b00,reg2[7:2]};
d_01:reg2<={2'b01,reg2[7:2]};
d_10:reg2<={2'b10,reg2[7:2]};
d_11:reg2<={2'b11,reg2[7:2]};
default:reg2<=reg2;
endcase
end
else reg2<=reg2;
else reg2<=0;
end
end
always@(posedge clk or negedge rst)
begin
if(!rst)
dout<=0;
else
begin
if((d_en)&&(cs==S1))
dout<=reg2;
else if (cs==S0)
dout<=0;
end
end
endmodule
對以上代碼做如下說明：
用拼接符號{}實現了移位寄存器，在使用拼接符號時一定要指定每一個元素的位寬。在位拼接表達式中不允許存在沒有指明位數的信號。
3、testbench的編寫
我們下面舉一個例子來說明用文件讀入的方法對存儲器賦值。
先定義一個有256個地址的字節存貯器
reg [7:0] mem[40:0]; 地址為0~40，一個地址上存放着8bit的數據
利用文件讀入的方法對men賦值
- initial $readmemb("mem.txt",mem);
以二進制的方式讀取mem.txt中的數據到mem中。 - initial $readmemh("mem.txt",mem,16);
以十六進制的方式讀取mem.txt中的數據到mem[16]-mem[40]。 - initial $readmemh("mem.data",mem,23,1);
以十六進制的方式讀取mem.txt中的數據到mem[23]-mem[1]。
對讀入文件做幾點說明
-
不同地址的數據以空格鍵或者回車鍵結束，從mem[0]開始讀入數據。
-
對一個地址的數據讀入是從高位開始的，即從mem[0][7]開始讀入mem.txt中的第一個數據，第一位地址的第7個元素為mem[1][7]=0 。
-
對讀入文件的命名規則，比如.txt文件名為mem，那么讀入文件名應該為“mem.txt”。
-
在Verilog中支持的文件路徑格式為
C:/Users/XQ/Desktop/mem.txt，而不是傳統Windows底下的C:\Users\XQ\Desktop\mem.txt。 -
必須在run xx ns以后才能對存儲器進行復制，初始的存儲器的值都為xx。
下面是一個名為mem的txt文件：00000000 //無效輸入 01111011 //幀頭 10111111 //"00" 11101111 //"01" 11111011 //"10" 11111110 //"11"輸出數據e4 11111011 //"10" 11111110 //"11" 10111111 //"00" 11101111 //"01"輸出數據4e 11010000 //幀尾 00001100 01111011 //幀頭 11111011 //"10" 11111110 //"11" 10111111 //"00" 11101111 //"01"輸出數據4e 11111110 //"11" 11101111 //"01" 11111011 //"10" 11111110 //"11"輸出數據e7 10111111 //"00" 11101111 //"01" 11111110 //"11" 11101111 //"01"輸出數據74 11010010 //幀尾 11010010 01111011 //幀頭 10111111 //"00" 11101111 //"01" 11111011 //"10" 11111110 //"11"輸出數據e4 10111111 //"00" 11101111 //"01" 11111011 //"10" 11111110 //"11"輸出數據e4 11111011 //"10" 11111110 //"11" 10111111 //"00" 11101111 //"01"輸出數據4e 11010000 //幀尾
tb文件代碼如下：
`timescale 1ns/1ns
module PPM_top;
reg clk,rst;
reg din;
wire [7:0]dout;
wire d_en,f_en;
reg [7:0] mem[40:0];
integer i,j;
initial
begin
$readmemb("C:/Users/XQ/Desktop/mem.txt",mem);
for(i=0;i<41;i=i+1)
for(j=7;j>=0;j=j-1)
begin
#9440
din=mem[i][j];
$display("mem[%0d][%0d]=%b",i,j,mem[i][j]);
end
end
always
#295 clk=~clk;
initial
begin
clk=0;
rst=1;
#200
rst=0;
#259
rst=1;
end
PPM ut1(
.clk(clk),
.rst(rst),
.din(din),
.d_en(d_en),
.f_en(f_en),
.dout(dout)
);
endmodule
注：reg類型的數據默認為是無符號的數，若reg [7:0] j那么在j=j-1中就不會出現負數,而是0-1=8'b11111111=255；若integer [7:0] j那么就會出現0-1=-1，正好符合我們的本意。采用integer配合FOR語句，行數比較少，但是integer不能綜合，只能用來仿真。