Oracle數據庫基本操作（四） —— PLSQL編程

　　Procedure Language 實際上是Oracle對SQL語言的能力擴展,讓SQL語言擁有了if條件判斷,for循環等處理。

一、PLSQL基本語法

DECLARE 
    -- 聲明部分
    變量名 變量類型 := 初始值 
    變量名 emp.sal % TYPE  -- 引用類型的變量
          emp % rowtype -- 記錄型變量           
BEGIN
    -- 業務邏輯
END ;

1、變量的聲明與使用

-- 已知數據類型的賦值聲明 
DECLARE 
    i NUMBER := 100 ;
BEGIN
    -- 輸出語句相當於 System.out.print();
    dbms_output.put_line('Hello World!' || i) ;
END ;

-- 未知數據類型的類型聲明
-- 輸出7369的工資

DECLARE 
    vsal emp.sal % TYPE ;
BEGIN
    -- 給變量賦值
    SELECT sal INTO vsal FROM emp WHERE empno = 7369 ; 
    dbms_output.put_line(vsal) ;
END ;

-- 記錄型變量聲明與賦值
-- 輸出7369的所有信息
DECLARE 
    vrow emp % rowtype ;
BEGIN    
    SELECT * INTO vrow FROM emp WHERE empno = 7369 ;
    dbms_output.put_line(vrow.empno||'   '|| vrow.ename);
END ;

2、if條件判斷語法與使用

-- 根據不同年齡輸出信息
DECLARE
    -- 由客戶端輸入     
    age number := &aaa;
BEGIN
    IF age <= 18 THEN
        dbms_output.put_line('未成年人');
    ELSIF age > 18 AND age <= 24 THEN
        dbms_output.put_line('年輕人');
    ELSIF age > 24 AND age < 48 THEN
        dbms_output.put_line('中年人');
    ELSE 
        dbms_output.put_line('老年人');
    END IF;
END;

3、三種循環

/*
   三種循環
   for 變量名 in 起始值..結束值  loop
     
   end loop; 
  ----------------------------------
   while 條件 loop
     
   end loop;
  -----------------------------------    
   loop
     exit when 退出的條件
     循環體
   end loop;
*/

-- for 循環
-- 輸出1-10
DECLARE 

BEGIN
    FOR i IN 1..10 LOOP
        dbms_output.put_line(i);
    END LOOP;
END;
-- 輸出10-1
DECLARE 

BEGIN
    FOR i IN REVERSE 1..10 LOOP
        dbms_output.put_line(i);
    END LOOP;
END;

-- while 循環
DECLARE 
    i NUMBER := 1;
BEGIN
    WHILE i <= 10 loop
        dbms_output.put_line(i);
        i := i+1;
    END LOOP;
END;

-- 簡單循環
DECLARE 
    i NUMBER := 1;
BEGIN 
    LOOP
        EXIT WHEN i > 10;
        dbms_output.put_line(i);
        i := i+1;
    END LOOP;
END;

二、游標

1、游標概述　　

1.1 游標: (光標/指針) 是對查詢結果集的封裝, 相當於是jdbc中的ResultSet

1.2 語法:

-- 聲明游標
    CURSOR 游標名 IS 查詢語句;
    CURSOR 游標名(參數名 參數類型) IS 查詢語句 WHERE 列名 = 參數名;

1.3 開發步驟:

1.打開游標 open 游標名

2.從游標中提取數據:

fetch 游標名 into 變量

　　   游標名%notfound 沒有數據

　　　游標名%found 找到數據

3.關閉游標 close 游標名

2、使用示例：

-- 無參 
-- 輸出所有員工的信息
DECLARE
   -- 聲明游標
  CURSOR vemps IS SELECT * FROM emp;
   -- 聲明變量
  vrow emp % rowtype;
BEGIN
   --1. 打開游標
   open vemps;
   --2. 提取數據
   LOOP
       FETCH vemps INTO vrow;
        -- 判斷是否有數據
       EXIT WHEN vemps % notfound;
        -- 打印數據
       dbms_output.put_line('姓名:'||vrow.ename||'  工資:'||vrow.sal);
   END LOOP;
   
   -- 關閉游標
   CLOSE vemps;
END;
---------------------------------------------------------------- 
-- for 變量游標        
DECLARE
   -- 聲明游標
   CURSOR vemps IS SELECT * FROM emp;
   -- 聲明記錄型變量
   vrow emp % rowtype;
BEGIN
   -- 循環遍歷游標
   FOR vrow IN vemps
   LOOP
        dbms_output.put_line('姓名:'||vrow.ename||' 工資:'||vrow.sal);
   END LOOP;
END;

-- ===============================================================
-- 有參
-- 輸出指定部門的員工信息
DECLARE
   -- 聲明游標
   CURSOR vemps(vdeptno NUMBER) IS SELECT * FROM emp WHERE deptno = vdeptno;
   -- 聲明記錄型變量
   vrow emp % rowtype;
BEGIN
   -- 1. 打開游標
   OPEN vemps(20);
   -- 2.循環遍歷游標
   LOOP
    FETCH vemps into vrow;
    EXIT when vemps % notfound;
      -- 打印數據
        dbms_output.put_line('姓名:'||vrow.ename||' 工資:'||vrow.sal);
   END LOOP;
   -- 3. 關閉游標
   CLOSE vemps;
END;

三、例外

1、例外概述

      例外 (意外): 相當於是java異常

　　語法: 

declare 
    聲明部分 
begin 
    業務邏輯
exception 
    處理例外 
    when 例外1 then 

    when 例外2 then 

    when others then 

end;

　　常見的系統的例外:

• • zero_divide : 除零例外
  • value_error : 類型轉換
  • no_data_found : 沒有找到數據例外
  • too_many_rows : 查詢出多行記錄,但是賦值給了單行變量

2、例外使用示例

DECLARE
    i NUMBER;
    vrow emp % rowtype;
BEGIN
--     i := 5/0;
--     i := 'aaa';
--     select * into vrow from emp where empno = 1234566;
    select * into vrow from emp;
EXCEPTION
    WHEN too_many_rows THEN
        dbms_output.put_line('查詢出多行記錄,但是賦值給了單行變量');
    WHEN no_data_found THEN
        dbms_output.put_line('發生了沒有找到數據例外');
    WHEN value_error THEN
        dbms_output.put_line('發生類型轉換的例外');
    WHEN zero_divide THEN
        dbms_output.put_line('發生除零的例外');
    WHEN others THEN
        dbms_output.put_line('發生未知的例外');
END;

3、自定義例外

　　語法：

DECLARE 
    -- 聲明例外
    例外名稱 EXCEPTION ;
BEGIN
    -- 拋出例外
    raise 例外名稱 ; 
EXCEPTION 
    -- 捕獲例外
    WHEN 例外名稱 THEN
    ....
END ;

　　使用示例：

-- 查詢指定編號的員工,若沒有找到,則拋出自定義例外
DECLARE 
    -- 聲明游標
    CURSOR vemps IS SELECT * FROM emp WHERE empno = 1234 ; 
    -- 記錄型變量
    vrow vemps % rowtype ; 
    -- 定義例外
    no_emp_found EXCEPTION ; 
BEGIN 
    --1.打開游標
    OPEN vemps ;
    --2.提取記錄 
    FETCH vemps INTO vrow ;
    -- 判斷是否有數據 
    IF vemps % notfound THEN 
        -- 拋出例外
        raise no_emp_found ; 
    END IF ; 
    -- 關閉游標
    CLOSE vemps ; 
EXCEPTION 
    WHEN no_emp_found THEN 
        dbms_output.put_line('沒有找到對應的員工') ; 
END ;

 四、存儲過程

1、概述　　

　　存儲過程: 實際上是將一段已經編譯好的PLSQL代碼片斷,封裝在數據庫中。

　　作用:

1. 提高執行效率

2. 提高代碼復用性

　　語法:

create [or replace] procedure 過程名稱[(參數1 in|out 參數類型,參數2 in|out 參數類型)]
is | as
　　-- 聲明　　　　
begin
 　 -- 業務
end;

2、使用示例

　　

-- 給指定員工漲薪,並打印漲薪前和漲薪后的工資
-- 員工編號 : 輸入參數
-- 漲多少 : 輸入參數
/*
   1. 查詢當前工
   2. 打印漲薪前工資
   3. 漲工資
   4. 打印漲薪后的工資
   5. 提交數據
*/
create or replace procedure proc_updatesal(vempno in number,vcount in number)
is
   -- 聲明變量記錄當前工資
   vsal number;    
begin
   --1. 查詢當前工資
   select sal into vsal from emp where empno=vempno;
   --2. 打印漲薪前工資
   dbms_output.put_line('漲薪前:'||vsal);
   --3. 漲工資
   update emp set sal=vsal+vcount where empno=vempno;
   -- 4. 打印漲薪后的工資
   dbms_output.put_line('漲薪后:'||(vsal+vcount));
   --5. 提交數據
   commit;
end;

-- 調用存儲過程
-- 方式1:
call proc_update_sal(7369,100);

-- 方式2:
declare

begin
   proc_updatesal(7369,100);
end;

s
-- 獲取指定編號員工的年薪
/*
   編號: in  輸入
   年薪: out 輸出
*/
create or replace procedure proc_getyearsal(vempno in number,vyearsal out number)
is
       
begin
  select sal*12+nvl(comm,0) into vyearsal from emp where empno=vempno;
end;

-- plsql代碼片斷中調用
declare
   yearsal number;
begin
   proc_getyearsal(7369,yearsal);
   dbms_output.put_line(yearsal);
end;


-- 封裝存儲過程,輸出的是游標類型, 所有員工
/*
   sys_refcursor : 系統引用游標
*/
create or replace procedure proc_getemps(vemps out sys_refcursor)
is

begin
    -- 打開游標, 誰調用誰關閉
    open vemps for select * from emp;   
end;

declare
  vemps sys_refcursor;
  vrow emp%rowtype;
begin
  -- 調用存儲過程
  proc_getemps(vemps);
  
  loop
     fetch vemps into vrow; 
     exit when vemps%notfound;  
     dbms_output.put_line(vrow.ename);
  end loop;
  -- 關閉游標
  close vemps;
end;

五、存儲函數

1、存儲函數概述

　　存儲函數: 實際上是將一段已經編譯好的PLSQL代碼片斷,封裝在數據庫中。

　　作用:

1. 提高執行效率

2. 提高代碼復用性

　　語法: 

create [or replace] function 函數名稱(參數1 in|out 參數類型) return 返回類型 
is 

begin 

end;

　　存儲過程和存儲函數:

1. 函數有返回值,過程沒有返回值

2. 函數可以直接在SQL語句中使用,過程不可以

3. 函數能實現的功能,過程能實現

4. 過程能實現的功能,函數也能實現

5. 函數和過程本質上沒有區別 通常情況下,我們自己開發封裝的是存儲過程

2、使用示例

-- 存儲函數:獲取年薪
create or replace function func_getyearsal(vempno number) return number
is
  vyearsal number;
begin
  select sal*12+nvl(comm,0) into vyearsal from emp where empno=vempno;
  return vyearsal;
end;

-- 調用
declare
   yearsal number;
begin
   yearsal := func_getyearsal(7369);
   dbms_output.put_line(yearsal);
end;

select emp.*,func_getyearsal(emp.empno) from emp;

 六、觸發器

　　1、數據庫觸發器是一個與表相關的、存儲的PL/SQL程序。每當一個特定的數據操作語句（insert，update，delete）在指定的表上發出是，Oracle自動地執行觸發器中定義的語句序列。

　　2、作用：

• • 監聽表中的數據變化；
  • 對表中的數據進行校驗

　　3、語法：

CREATE [OR REPLACE] TRIGGER 觸發器名稱 
{BEFORE | AFTER}
{INSERT | UPDATE | DELETE} 
ON 表名 
[ FOR EACH ROW [WHEN(條件)]]
DECLARE
    ....
BEGIN
    PLSQL塊
END 觸發器名;

　　4、觸發器的類型

• 行級觸發器：一條SQL語句，影響了多少行記錄，觸發器就會執行多少次；
  • 兩個內置對象：
    • :new 新的記錄
    • :old 舊的記錄
• 語句級觸發器：一條SQL語句，無論影響了多少行記錄，都只觸發一次；

　　5、使用示例

-- 若用戶向表中插入數據之后, 打印一句話
create or replace trigger tri_test1
after
insert 
on emp
declare

begin
   dbms_output.put_line('有人插入了....');
end;

insert into emp(empno,ename) values(9527,'華安');
-- 執行一條更新工資的語句

-- 周二老板不在,不能辦理員工入職(不能向員工表中插入數據)
-- 觸發器
-- before insert
-- 判斷今天是否是周二
select trim(to_char(sysdate,'day')) from dual;

create or replace trigger tri_checkday
before
insert
on emp
declare
   vday varchar2(20);
begin
   -- 查詢當前周幾
   select trim(to_char(sysdate,'day')) into vday from dual;
   -- 判斷是否為周二,若為周二,則需要中斷插入操作
   if vday = 'tuesday' then
     --                   -20000 - -20999
     raise_application_error(-20001,'周二老板不在,不能插入');
   end if;
end;

insert into emp(empno,ename) values(9527,'華安');

select * from emp;

-- 語句級觸發器
create trigger tri_test3
before
update
on emp
declare

begin
  dbms_output.put_line('語句級觸發器'); 
end;

-- 行級觸發器
create or replace trigger tri_test4
before
update
on emp
for each row
declare

begin
  dbms_output.put_line('行級觸發器,舊的工資:'||:old.sal||'  新的工資:'||:new.sal); 
end;

update emp set sal=sal+100;

-- 6個月 ---> 人事 加薪 ---> 加10塊錢 ---> 老板簽字
-- 校驗員工薪資 調整后的工資一定要 大於 薪資調整前的工資
-- 觸發器:  before update on emp
-- 行級觸發器
create or replace trigger tri_checksal
before
update
on emp
for each row
declare

begin
  -- 調整后的工資 <= 薪資調整前的工資 ,則中斷更新操作
  -- :new.sal    <= :old.sal
  if :new.sal <= :old.sal then
     raise_application_error(-20002,'坑爹的,降薪啦!');
  end if;
end;

update emp set sal=sal-100;

/*
     使用觸發器模擬類似auto_increment功能
     當用戶插入的時候,若為sid為null,則給sid賦值一個編號
*/
create table stu(
     sid number primary key,
     name varchar2(20)
);

-- 創建一個序列
create sequence seq_stu;

-- 觸發器: before insert on stu
-- 行級觸發器
create or replace trigger tri_auto
before
insert 
on stu
for each row
declare

begin
   -- 從序列中查詢一個數字出來,賦值給sid
   select seq_stu.nextval into :new.sid from dual;
end;

-- 同樣一張表,有時候自己指定id, 有時候需要數據庫自動生成id
insert into stu values(null,'zs');
insert into stu values(4,'zs');
select * from stu;