向頂點着色器提供頂點參數

對於 CG/HLSL 頂點程序，模型網格頂點數據被作為輸入傳遞給頂點着色器函數。每個輸入都需要一個語義來詳細指定。比如，POSITION輸入是 頂點的位置，NORMAL是頂點的法線。

 

通常，頂點數據輸入被聲明成一個結構體，而不是一個個的羅列他們。幾個常用的頂點結構體都被丁艷在UnityCG.cginc include file里面了，並且大多數情況下，這些都夠用了。這些結構體是：

• appdata_base:位置、法線還有一個貼圖坐標
• appdata_tan:位置、切線、法線、還有一個貼圖坐標
• appdata_full: 位置、切線、法線、四個貼圖坐標和顏色

比如：這個着色器根據頂點的法線來給網格上色，使用 appdata_base作為頂點程序輸入：

Shader "VertexInputSimple" {
    SubShader {
        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
         
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
            };
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color.xyz = v.normal * 0.5 + 0.5;
                o.color.w = 1.0;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target { return i.color; }
            ENDCG
        }
    } 
}

為了使用不同的頂點數據，你需要自己去聲明你的頂點結構體，或者增加輸入參數。頂點數據是通過 Cg/HLSL 語義來識別的，所以必須要遵循下面的規則：

• POSITION: 頂點的位置，一般為float3 或者float4類型。
• NORMAL: 頂點的法線，一般為float3。
• TEXCOORD0：第一個UV坐標，一般為 float2 、float3、float4。
• TEXCOORD1，TEXCOORD2，TEXCOORD3，就是2、3 、4個UV坐標，以此類推。
• TANGENT: 切線向量（用來做法線映射），一般為float4
• COLOR: 每個頂點的顏色，一般為float4

當一個網格數據包含的數據少於頂點着色器的輸入時，剩下的都會被0填充，除卻w會被填充為1.比如，網格貼圖坐標經常為2D向量，只有x和y元素，如果一個頂點着色器聲明了一個float4的輸入，並且標記為TEXCOORD0，那么這個值接受到的數據為 (x,y,0,1).

例子

可見的UV

下面的shader例子使用頂點位置和第一個貼圖的坐標作為頂點着色器的輸入。這個shader在調試網格的UV坐標時非常有用。

Shader "Debug/UV 1" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord : TEXCOORD0;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

 

這里，UV坐標被顯示為紅色和綠色，而額外的藍色是那些坐標超出了0-1范圍的貼圖坐標

 

同樣的，這個着色器將第二個UV顯示與模型之上：

Shader "Debug/UV 2" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, second UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord1 : TEXCOORD1;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord1.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

可見的頂點顏色

下面的shader使用頂點位置和每個頂點的顏色作為頂點着色器的輸入

Shader "Debug/Vertex color" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, color
        struct appdata {
            float4 vertex : POSITION;
            fixed4 color : COLOR;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.color;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

可視的法線

下面的shader使用頂點位置和法線作為頂點着色器的輸入，法線的 X,Y&Z 分量被轉化為可視化的RGB 顏色，因為法線分量范圍為 -1到1，我們可以進行縮放與偏移，從而將其映射到0-1的范圍內。

Shader "Debug/Normals" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, normal
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color.xyz = v.normal * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

可視化切線和次法線

切線和次法線向量用作法線映射。在unity中只有切線才被存儲進頂點數據，次法線是通過法線和切線推到出來的。

 

下面的shader使用頂點位置和切線作為輸入，切線的 x、y 和z分量被轉化為可視的RGB顏色，因為法線的分量是-1到1，所以需要映射到0-1.

Shader "Debug/Tangents" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, tangent
        struct appdata {
            float4 vertex : POSITION;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.tangent * 0.5 + 0.5;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

 下面的shader將雙切線可視化。它使用頂點位置，法線和切線值作為頂點着色器的輸入。雙切線（有時候也叫作次法線）是從法線和切線值中計算出來的。它需要被映射到0-1的范圍。

Shader "Debug/Bitangents" {
SubShader {
    Pass {
        Fog { Mode Off }
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // vertex input: position, normal, tangent
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            // calculate bitangent
            float3 bitangent = cross( v.normal, v.tangent.xyz ) * v.tangent.w;
            o.color.xyz = bitangent * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}