常用oracle可重復執行的腳本模板

為保證腳本的可重復執行以及丟失,涉及到數據庫環境的移植等,就會使用可重復執行腳本,此處僅提供相關一些模板

說明下:該腳本需要在命令窗口執行,而不是在SQL窗口執行

創建序的腳本

/**
 *  作者：zkongbai
 *  時間：11-30 09:22:10
 *  描述：創建序列【SEQ_ZZ_DOUBLE_RANDOM_TASK】
 *  腳本可重復執行
 */
PROMPT SEQ_ZZ_DOUBLE_RANDOM_TASK  雙隨機事件腳本 創建序列
DECLARE
    FLAG_NUM NUMBER;
BEGIN
    SELECT COUNT(*) INTO FLAG_NUM
    FROM USER_SEQUENCES ASQ
    WHERE ASQ.SEQUENCE_NAME = UPPER('SEQ_ZZ_DOUBLE_RANDOM_TASK');
    IF FLAG_NUM = 0 THEN 
        EXECUTE IMMEDIATE 'CREATE SEQUENCE SEQ_ZZ_DOUBLE_RANDOM_TASK MINVALUE 1 MAXVALUE 999999999 START WITH 1 INCREMENT BY 1 CACHE 20'; 
    END IF;
END;
/
COMMIT;

 

創建表的腳本

/**
 *  作者：zkongbai
 *  時間：11-21 09:22:10
 *  描述：創建表【雙隨機任務,序:SEQ_ZZ_DOUBLE_RANDOM_TASK】
 *  腳本可重復執行
 */
PROMPT T_ZZ_DOUBLE_RANDOM_TASK 創建表
DECLARE
    FLAG_NUM NUMBER;
BEGIN
    SELECT COUNT(*) INTO FLAG_NUM
    FROM USER_TABLES ATS
    WHERE ATS.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK');
    IF FLAG_NUM = 0 THEN
        EXECUTE IMMEDIATE 'CREATE TABLE T_ZZ_DOUBLE_RANDOM_TASK
            (
                ID              NUMBER(8) not null,
                EVENT_ID        NUMBER(8),
                JUDGE_COMMENT   VARCHAR2(500),
                JUDGE_RESULE    CHAR(1),
                JUDGE_PERSON    NUMBER(8),
                CREATE_TIME     DATE,
                STATUS          CHAR(1),
                UPDATE_TIME     DATE,
                CREATE_USER_ID  NUMBER(8),
                CREATE_ORG_CODE VARCHAR2(32),
                CONSTRAINT PK_T_ZZ_DOUBLE_RANDOM_TASK PRIMARY KEY (ID)
            )';
        -- ADD COMMENTS TO THE TABLE 
        EXECUTE IMMEDIATE 'COMMENT ON TABLE T_ZZ_DOUBLE_RANDOM_TASK IS ''雙隨機任務,序:SEQ_ZZ_DOUBLE_RANDOM_TASK'''; 
        -- ADD COMMENTS TO THE COLUMNS 
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.EVENT_ID  IS ''事件ID''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_COMMENT  IS ''評價意見''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_RESULE  IS ''評價結果(1:合格,2:不合格)''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_PERSON  IS ''評價人''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.STATUS  IS ''狀態.1:有效,0:無效''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.CREATE_USER_ID  IS ''創建人''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.CREATE_ORG_CODE  IS ''創建組織''';
    END IF;
END;
/
COMMIT;

 

修改字段的腳本

/**
 *  作者：zkongbai
 *  時間：2018/1/11
 *  描述：雙隨機任務添加字段 TASK_TYPE
 *  腳本可重復執行
 */
PROMPT T_ZZ_DOUBLE_RANDOM_TASK 雙隨機任務添加字段 TASK_TYPE
DECLARE
  FLAG_NUM NUMBER;
BEGIN
  SELECT COUNT(*) INTO FLAG_NUM
  FROM USER_TABLES ATS
  WHERE ATS.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK');
  IF FLAG_NUM > 0 THEN
    SELECT COUNT(*) INTO FLAG_NUM FROM USER_TAB_COLUMNS T 
    WHERE T.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK') AND T.COLUMN_NAME = UPPER('TASK_TYPE');
    IF FLAG_NUM=0 THEN
      EXECUTE IMMEDIATE 'ALTER TABLE T_ZZ_DOUBLE_RANDOM_TASK ADD TASK_TYPE CHAR(1)';
      -- ADD COMMENTS TO THE COLUMNS 
      EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.TASK_TYPE  IS ''任務類型: 1或空:市級雙隨機任務,2:鎮街級隨機任務''';
    END IF;
  END IF;
END;
/
COMMIT;