智能合約語言 Solidity 教程系列3 - 函數類型

最新內容會更新在主站深入淺出區塊鏈社區
原文鏈接:智能合約語言 Solidity 教程系列3 - 函數類型

Solidity 教程系列第三篇 - Solidity 函數類型介紹。

寫在前面

Solidity 是以太坊智能合約編程語言，閱讀本文前，你應該對以太坊、智能合約有所了解，如果你還不了解，建議你先看以太坊是什么

本文前半部分是參考Solidity 官方文檔（當前最新版本：0.4.20）進行翻譯，后半部分函數可見性（ public, external, internal, privite ）深度分析（僅針對專欄訂閱用戶）。

函數類型（Function Types）

函數也是一種類型，且屬於值類型。
可以將一個函數賦值給一個函數類型的變量。還可以將一個函數作為參數進行傳遞。也可以在函數調用中返回一個函數。
函數類型有兩類:內部(internal)和外部(external)函數

內部(internal)函數只能在當前合約內被調用（在當前的代碼塊內，包括內部庫函數，和繼承的函數中）。
外部(external)函數由地址和函數方法簽名兩部分組成，可作為外部函數調用的參數，或返回值。

函數類型定義如下：

function (<parameter types>) {internal|external} [pure|constant|view|payable] [returns (<return types>)]

如果函數不需要返回，則省去returns ( )
函數類型默認是internal， 因此internal可以省去。但以此相反，合約中函數本身默認是public的， 僅僅是當作類型名使用時默認是internal的。

有兩個方式訪問函數，一種是直接用函數名f, 一種是this.f， 前者用於內部函數，后者用於外部函數。

如果一個函數變量沒有初始化，直接調用它將會產生異常。如果delete了一個函數后調用，也會發生同樣的異常。

如果外部函數類型在Solidity的上下文環境以外的地方使用，他們會被視為function類型。它會編碼為20字節的函數所在地址，和在它之前的4字節的函數方法簽名一起作為bytes24類型。
合約中的public的函數，可以使用internal和external兩種方式來調用。
internal訪問形式為f, external訪問形式為this.f

成員: 屬性 selector

public (或 external) 函數有一個特殊的成員selector, 它對應一個ABI 函數選擇器。
```js
pragma solidity ^0.4.16;

contract Selector {
function f() public view returns (bytes4) {
    return this.f.selector;
}
}
```

下面的代碼顯示內部（internal）函數類型的使用：

pragma solidity ^0.4.16;

library ArrayUtils {
  // internal functions can be used in internal library functions because
  // they will be part of the same code context
  function map(uint[] memory self, function (uint) pure returns (uint) f)
    internal
    pure
    returns (uint[] memory r)
  {
    r = new uint[](self.length);
    for (uint i = 0; i < self.length; i++) {
      r[i] = f(self[i]);
    }
  }
  function reduce(
    uint[] memory self,
    function (uint, uint) pure returns (uint) f
  )
    internal
    pure
    returns (uint r)
  {
    r = self[0];
    for (uint i = 1; i < self.length; i++) {
      r = f(r, self[i]);
    }
  }
  function range(uint length) internal pure returns (uint[] memory r) {
    r = new uint[](length);
    for (uint i = 0; i < r.length; i++) {
      r[i] = i;
    }
  }
}

contract Pyramid {
  using ArrayUtils for *;
  function pyramid(uint l) public pure returns (uint) {
    return ArrayUtils.range(l).map(square).reduce(sum);
  }
  function square(uint x) internal pure returns (uint) {
    return x * x;
  }
  function sum(uint x, uint y) internal pure returns (uint) {
    return x + y;
  }
}

下面的代碼顯示外部（external）函數類型的使用：

pragma solidity ^0.4.11;

contract Oracle {
  struct Request {
    bytes data;
    function(bytes memory) external callback;
  }
  Request[] requests;
  event NewRequest(uint);
  function query(bytes data, function(bytes memory) external callback) public {
    requests.push(Request(data, callback));
    NewRequest(requests.length - 1);
  }
  function reply(uint requestID, bytes response) public {
    // Here goes the check that the reply comes from a trusted source
    requests[requestID].callback(response);
  }
}

contract OracleUser {
  Oracle constant oracle = Oracle(0x1234567); // known contract
  function buySomething() {
    oracle.query("USD", this.oracleResponse);
  }
  function oracleResponse(bytes response) public {
    require(msg.sender == address(oracle));
    // Use the data
  }
}

函數可見性分析

• public - 任意訪問
• private - 僅當前合約內
• internal - 僅當前合約及所繼承的合約
• external - 僅外部訪問（在內部也只能用外部訪問方式訪問）

public 還是 external 最佳實踐

請訂閱區塊鏈技術查看。

參考視頻

我們也推出了目前市面上最全的視頻教程：深入詳解以太坊智能合約語言Solidity
目前我們也在招募體驗師，可以點擊鏈接了解。

參考文檔

Solidity官方文檔-類型

深入淺出區塊鏈 - 系統學習區塊鏈，打造最好的區塊鏈技術博客