簡單UART的verilog實現

下面摘錄我寫的簡單的UART代碼，對於靈活性和健壯性做了如下設計：

1、系統時鍾及串口波特率以參數形式輸入，例化時可以靈活設置

2、接受模塊在起始位會檢測中點電平是否仍然為低，否則判定為抖動

 

接收機代碼

`timescale 1ns/1ps

// 系統時鍾200MHz，波特率115200
module uart_rx  #(
    parameter BAUDRATE = 115200, 
    parameter FREQ = 200_000_000)(
    input clk, nrst,
    input rx,
    output reg [7:0] rdata,
    output reg vld
    );

    localparam T = FREQ / BAUDRATE;

    // flag接受處理標志位，為1表明當前處於接受狀態
    reg flag;
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            flag <= 0; 
        else if(flag == 0 && rx == 0)
            flag <= 1;
        else if(cnt_bit == 1 - 1 && cnt_clk == T / 2 - 1 && rx == 1)
            flag <= 0;
        else if(end_cnt_bit)
            flag <= 0;
    end
    
    // 兩層計數結構，cnt_clk計數每一位所占的時鍾數，cnt_bit計數1個開始位，8個數據位，一個停止位，共10位
    reg [3:0] cnt_bit;
    reg [31:0] cnt_clk;
    assign end_cnt_clk = cnt_clk == T - 1;
    assign end_cnt_bit = end_cnt_clk && cnt_bit == 10 - 1;
    
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            cnt_clk <= 0;
        else if(flag) begin
            if(end_cnt_clk)
                cnt_clk <= 0;
            else
                cnt_clk <= cnt_clk + 1'b1;
        end
        else
            cnt_clk <= 0;
    end
    
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            cnt_bit <= 0;
        else if(end_cnt_clk) begin
            if(end_cnt_bit)
                cnt_bit <= 0;
            else
                cnt_bit <= cnt_bit + 1'b1;
        end
    end    
    
    // 讀數據及數據有效指示信號
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            rdata <= 0;
        else if(cnt_clk == T / 2 - 1 && cnt_bit != 1 - 1 && cnt_bit != 10 - 1)
            rdata[cnt_bit - 1] <= rx;
    end
    
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            vld <= 0;
        else if(end_cnt_bit)
            vld <= 1;
        else
            vld <= 0;
    end
    
endmodule

 

發送機代碼

`timescale 1ns/1ps

// 系統時鍾200MHz，波特率115200，帶忙閑指示信號rdy
module uart_tx #(
    parameter BAUDRATE = 115200, 
    parameter FREQ = 200_000_000)(
    input clk, nrst,
    input wrreq,
    input [7:0] wdata,
    output reg tx,
    output reg rdy
    );
    
    reg [3:0] cnt_bit;
    reg [31:0] cnt_clk;
    
    localparam T = FREQ / BAUDRATE;

    // 有寫請求時將rdy信號拉底，待到數據發送完畢再將信號拉
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            rdy <= 1;
        else if(wrreq)
            rdy <= 0;
        else if(end_cnt_bit)
            rdy <= 1;
    end
    
    // 兩層計數結構，cnt_clk計數每一位所占的時鍾數，cnt_bit計數1個開始位，8個數據位，一個停止位，共10位
    wire end_cnt_clk;
    wire end_cnt_bit;
    assign end_cnt_clk = cnt_clk == T - 1;
    assign end_cnt_bit = end_cnt_clk && cnt_bit == 10 - 1;
    
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            cnt_clk <= 0;
        else if(rdy == 0) begin
            if(end_cnt_clk)
                cnt_clk <= 0;
            else
                cnt_clk <= cnt_clk + 1'b1;
        end
    end
    
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            cnt_bit <= 0;
        else if(end_cnt_clk) begin
            if(end_cnt_bit)
                cnt_bit <= 0;
            else
                cnt_bit <= cnt_bit + 1'b1;
        end
    end
    
    // 先發送一個起始位0，然后8位數據位，最后是停止位1
    always @(posedge clk or negedge nrst) begin
        if(nrst == 0)
            tx <= 1;
        else if(rdy == 0 && cnt_clk == 0) begin
            if(cnt_bit == 1 - 1)
                tx <= 0;
            else if(cnt_bit == 10 - 1)
                tx <= 1;
            else
                tx <= wdata[cnt_bit - 1];
        end
    end
    
endmodule

 

在Xilinx Artix-7平台上驗證的頂層代碼

`timescale 1ns / 1ps

module uart_top(
    input clk_p, clk_n, nrst,
    input rx,
    output tx
    );
    
    localparam BAUDRATE = 115200;
    localparam FREQ = 200_000_000;
    
    // 差分時鍾信號轉為單端信號
    IBUFGDS #(
        .DIFF_TERM("FALSE"),
        .IBUF_LOW_PWR("TRUE"),
        .IOSTANDARD("DEFAULT")
    )  IBUFGDS_inst(
        .O(clk),
        .I(clk_p),
        .IB(clk_n)
    );
    
    wire [7:0] data;
    wire vld;
    
    uart_rx #(BAUDRATE, FREQ) uart_rx_u(
    .clk    (clk    ),
    .nrst    (nrst    ),
    .rx        (rx        ),
    .rdata    (data    ),
    .vld    (vld    )
    );
    
    uart_tx #(BAUDRATE, FREQ) uart_tx_u(
    .clk    (clk    ),
    .nrst    (nrst    ),
    .wrreq    (vld    ),
    .wdata    (data    ),
    .tx        (tx        ),
    .rdy    (        )
    );
    
    ila_0 ila_0_u(
    .clk     (clk    ), 
    .probe0  (nrst   ),
    .probe1  ({tx,rx}),
    .probe2  (data   ),
    .probe3  (vld    )
    );
    
endmodule