命令行腳本是包含可執行命令的文本文件，這些命令一般和命令行窗口鍵入的命令一致。腳本文件中的命令就是標准的文本字符，因此可以通過普通的文本編輯器，如 Windows 記事本來編輯。在腳本中輸入命令時，需要注意的是，每一條命令，或者每一組需要一起執行的命令，都因該保存在腳本的單獨一行中，以便確保命令的正確執行。
在常見的編程語言中，如 C/C++/C# 等語言中每條語句都要用分號來表示結束。而在命令行腳本中，沒有諸如分號之類的特定終止符，而是通過斷行（比如按下Shift+Enter鍵）、回車與斷行（按下Enter鍵）、文件結尾標志三種方式來表示語句結束。
1、實用功能
1.1、為腳本添加注釋
rem 命令用於注釋單行命令，類似與 C# 等語言中注釋符//。需要注意的是，當在批處理文件中通過 rem 命令注釋了某一行之后，該行就不會被執行了，但默認被注釋的命令內容還是會被回顯到窗口上，這時候可以結合下面將要講到的 @ 命令，寫成 @rem 就一定不會顯示了。
1.2、控制命令的回顯
用echo和@兩個命令，echo命令用於在命令回顯消息、關閉或打開命令回顯（當回顯處於打開狀態，執行批處理文件時將逐條顯示批處理文件中的命令行；相反，當回顯處於關閉狀態時，不會顯示命令行本身），而@命令用於以行為單位控制命令的回顯方式。
示例 1：向命令行回顯一條消息(Hello Word!)
echo Hello Word!
示例 2：關閉命令行回顯（關閉回顯之后就看不到命令提示符前的路徑了）
echo off
示例 3：打開命令行回顯（默認打開）
echo on
示例 4：在任何一行命令前加上@即可關閉該行的回顯
@echo Hello Word!
1.3、使用數學表達式
命令行腳本支持算術運算、賦值運算、比較運算、按位運算等常見的數學運算。所有數學運算都得在set命令的參數/a之后進行。
示例：
set /a add=3+7
set /a sub=3-7
set /a mul=3*7
set /a div=5/2
set /a mod=5%2
set /a exp=2*2*2
1.4、向腳本傳遞參數
在調用命令行腳本的時候還可以向腳本傳遞參數。傳遞給腳本的每一個參數都可以用形參進行檢查和解釋。第1個參數用%1表示，第2個參數用%2表示，依次類推，第9個形參為%9。但如果向腳本傳遞的參數多於9個，則會被保存到一個特殊的參數變量%*中去，通過shift命令可以查看%*中的實參；另外在必要的時候，還可以通過shift命令進行形參移位，譬如shift /2表示忽略第2個參數，從第3個參數開始往前移動。還有一個特殊的形參是%0，它代表當前腳本的名稱。
示例：
在 D 盤新建一個記事本，然后鍵入下面的腳本：
@echo 當前腳本的名稱是：%0
@echo 第1個參數的值是：%1
@echo 第2個參數的值是：%2
@pause
將記事本改名為 try.bat，然后打開命令行(cmd.exe)調用該腳本：
try abc 123
結果如下：
2、使用變量
在命令行腳本中，我們通常所說的變量更可能是指環境變量。環境變量有多種來源，有內置在操作系統之中的，也有在系統啟動時來自系統硬件的，這些被稱之為內置系統變量，對所有 Windows 進程都可用。系統變量也可來自 Windows 注冊表。除內置系統變量之外，還有一些登錄時設置的變量，這種變量被稱為內置用戶變量。
通過set命令可以查看當前命令行實例中所有變量及變量值。除標准的系統變量和用戶變量之外，還可以通過set命令在命令行中隨時創建或設置變量。
有些變量在命令行中有着特殊的含義，如 path、computername、homedrive、errorlevel 等。其中 errorlevel 變量可以追蹤最近使用命令的退出代碼。如果命令正常執行，則錯誤級別為 0；如果命令在執行過程中出錯，則錯誤級別會被設置為一個適當的非 0 值（1 表示一般的錯誤，2 表示執行錯誤，意味着命令沒有正確執行，-2 表示算數錯誤）。
2.1、變量的命名及定義
在命令行腳本中，變量名是大小寫不敏感的，在定義變量的時候可以區分大小寫，但在調用的時候不區分大小寫。變量名可以是任意字母、數字或字符的組合，如 2s、38、? 等理論上都是合法的變量名。盡管如此，我們也還是應該要使用便於理解的名字來做為變量名。
在命令行中聲明變量時必須同時為其賦值，定義變量的語法如下：
set variable_name=variable_value
在變量名和變量值中，空格都是有效的，但一般不建議使用。命令行也不對具體的數據類型進行區分，所有的變量都是以字符的形式存儲，即使變量值設置為數值也是如此。但在進行數學運算的時候，命令行是可以判斷出字符串是否為數值的。
有些字符是命令行的保留字符，如 @、<、>、&、|、^ 等，在使用這些字符的時候，無論出現在變量值中的那個位置，都必須使用轉碼字符 ^ 對其進行轉碼。
示例：
set var1=abc
set var2=985
set var3=3.14
set var4="ok"
set var5="2^&3"
set "name=張三"
2.2、調用變量
在命令行中任何需要用到變量的地方都可以調用變量，調用的方式是用兩個百分號包裹變量名，即%variable_name%。
示例：
echo %var3% 輸出變量 var3 的值
echo %name% 輸出變量 name 的值
cd %systemroot%\system32 切換到系統目錄下的 system32 目錄中
set syspath=%systemroot%\system32 定義一個變量 syspath 並用其它變量為其賦值
綜合案例：
@rem 定義變量接收用戶輸入
@echo off
@set /p str=請輸入任意內容，然后回車：
@echo 您剛剛輸入的內容是：%str%
@pause
2.3、變量的作用域
在命令行中用set命令所做修改的作用范圍是局部化的，也就是說set命令的作用僅限當前會話窗口，窗口關閉后之前的修改就會失效。
有時候可能還需要對變量的作用范圍做進一步約束，使其僅作用於腳本的某一部分。要做到這一點，可以通過setlocal命令來標記一個局部范圍的開始，使用endlocal命令來標記一個局部范圍的結束。
示例：
setlocal
set cnt=5
endlocal
在一個比較長的作用范圍內，使用完變量之后，應該要對其進行適當處理，以便釋放該變量占用的內存，防止無意間再次引用該變量時出現預期之外的結果。在命令行中只要把變量的值設置為空，該變量就不復存在了。
示例：
set var3=
3、結構語句
3.1、選擇語句
命令行中的選擇語句是 if，該語句有 3 中不同的形式，本節將逐一介紹。
普通的 if 語句：如果條件為真則執行該語句，否則繞過該語句。
語法（語法中的圓括號並非必須，但使用圓括號會使語句結構更加清晰）：
if condition (statement1) [else (statement2)]
示例：
set v1=1
if %v1%==1 (echo is one) else (echo is not one)
if %v1%==1 (hostname & ver & ipconfig /all)
如果存在 try.bat 文件，則把該文件的內容輸出到控制台：
if exist try.bat type try.bat
if not 語句：如果條件為假則執行該語句，否則繞過該語句。
語法：
if not condition (statement1) [else (statement2)]
示例：
if not %errorlevel%==0 (echo error has occurred) else (echo running well)
if defined & if not defined：這兩個語句用於檢查某變量是否存在。
語法：
if defined variable_name statement
if not defined variable_name statement
在用於安全檢查的時候，這兩個語句非常有用。第一個語句是在變量存在的時候，執行某條命令。第二個語句是在變量不存在的時候，執行某條命令。
示例：
if defined v1 (echo %v1%)
3.2、迭代語句
命令行中的迭代語句是 for，該語句與常見的編程語言（如 C#）中的 for 循環有很大的不同。命令行中的 for 語句主要用於在成組的文件與目錄中進行迭代處理，並以行為基礎分析文本文件、字符串以及命令的輸出信息。
最常見的 for 語句語法如下：
for iterator do (statement)
語法中的 iterator 用於控制 for 循環的執行。對 iterator 中每一個步驟或元素，都會執行特定的語句。它可以是單一的一條命令，也可以是使用命令管道、命令鏈、命令分組等技術組合起來的多條命令。
iterator 通常包含一個初始化變量和一組需要反復執行的元素，比如需要遍歷的一組文件或某范圍內的一組值。初始化變量也就是要使用的值的占位符，使用初始化變量時，需要注意以下幾點：
- 變量只存在於 for 語句的上下文中。
- 變量名必須在 a~z 或 A~Z 的范圍內，比如 %%a、%%b、%%c。
- 變量名是大小寫敏感的，也就是說，%%a 與 %%A 是不同的。
常見迭代形式表如下：
| 迭代功能 | 語法格式 |
|---|---|
| 文件集合 | for %%variable in (fileSet) do statement |
| 目錄集合 | for /D %%variable in (directorySet) do statement |
| 子目錄中的文件 | for /R[path] %%variable in (fileSet) do statement |
| 遍歷一系列的值 | for /L %%variable in (stepRange) do statement |
| 分析文本文件、字符串以及命令輸出 | for /F[options] %%variable in (source) do statement |
上表中提供的迭代形式也可以在命令行中交互式地使用 for 語句，這種情況下，應該使用 %variable，而不是 %%variable。除此之外，腳本中的 for 語句與在命令行中使用 for 語句是完全一樣的。
遍歷一系列值：用於操作數值。
語法：
for /l %%variable in (start,step,end) do (statement)
示例（輸出 1~9 之間的奇數）：
@for /l %%v in (1,2,9) do @echo %%v
在成組的文件中迭代執行：用於操作文件組中的文件。
語法：
for %%variable in (fileSet) do statement
語法中的 fileSet 用於指定需要處理的文件集，文件集可以是如下形式。
- 通過文件名指定為單獨的文件，如 myfile.txt。
- 通過文件名通配符指定一組文件，如 *.txt。
- 使用空格分割的多個文件或文件組，如 myfile.txt *.doc *.docx。
示例 1（輸出 D:\Workspace 目錄中所有 txt 文件的全路徑名）：
for %%i in (D:\Workspace\*.txt) do (echo %%i)
示例 2（輸出 D:\Workspace 目錄及其子目錄中所有 txt 文件的全路徑名）：
for /r D:\Workspace %%i in (*.txt) do (echo %%i)
示例 3（輸出 D:\Workspace 目錄及其子目錄中所有 jpg 或 png 文件的全路徑名）：
for /r D:\Workspace %%i in (*jpg,*png) do (echo %%i)
示例 4（輸出 D:\Workspace 目錄及其子目錄中所有文件的全路徑名）：
for /r D:\Workspace %%i in (*) do (echo %%i)
示例 5（輸出 D:\Workspace 目錄及其子目錄中所有名稱包含 windows 的文件全路徑名）：
for /r D:\Workspace %%i in (*windows*) do (echo %%i)
示例 6（輸出 D:\Workspace 目錄及其子目錄中所有路徑包含 windows 的文件夾全路徑+windows）：
for /r D:\Workspace %%i in (windows) do (echo %%i)
從上述幾個例子中也能看出來，匹配模式中第一個字符必須是星號，否則就匹配不到文件了。如果完全不帶星號則會匹配到路徑包含指定字符的文件夾全路徑+指定字符。
在目錄中迭代執行：用於操作目錄組中的目錄。
示例（輸出 D:\Workspace\ 中所有的子目錄名）：
for /d %%v in (D:\Workspace\*) do echo %%v
3.3、子程序 & 過程
使用子程序：也就是通過goto跳轉到另一段程序繼續執行。goto的作用是將命令解釋器直接跳轉到批處理腳本中某個標記行。
示例：
@if not defined v (@echo error: Undefined parameters!) & (goto exit)
@if %v%==1 goto subroutine1
@if %v%==2 goto subroutine2
@if %v%==3 goto subroutine3
@goto exit
:subroutine1
@echo In subroutine 1
@goto exit
:subroutine2
@echo In subroutine 2
@goto exit
:subroutine3
@echo In subroutine 3
@goto exit
:exit
@echo Exiting...
使用過程：也就是在腳本中調用其它腳本，而又不會退出原腳本。進行過程調用時，命令行會執行調用的腳本，逐一執行其中的命令，結束后返回到原腳本，並從過程調用語句的下一行語句開始執行。
示例：
@if %v%==1 call file1
上例中，如果不適用call語句，也能調用 file1 腳本，但在 file1 腳本執行完畢之后控制權不會返回給調用者（原腳本）。
call 命令用於調用另外一個批處理文件。常用的方式就是call sample.bat，新擴展的一個用法是call :label arguments，也就是用 call 來調用 bat 文件內部的一段腳本，然后用 exit 來退出當前的 call 調用。
4、總結
本文主要講述了命令行腳本的注釋、回顯、參數、變量、結構控制語句等基礎內容。
本文鏈接：http://www.cnblogs.com/hanzongze/p/cmd-script-base.html
版權聲明：本文為博客園博主 韓宗澤 原創，作者保留署名權！歡迎通過轉載、演繹或其它傳播方式來使用本文，但必須在明顯位置給出作者署名和本文鏈接！個人博客，能力有限，若有不當之處，敬請批評指正，謝謝！