使用VS2015編譯grpc_1.3.1

環境：

　　win7_x64，VS2015

開始：

一、安裝工具

　　1. 安裝cmake

　　2. 安裝ActivePerl

　　3. 安裝golang

　　4. 安裝nasm

　　驗證安裝是否安裝成功：

　　cmake -version

　　perl -version

　　go version

　　nasm -v

如果出現錯誤，請檢查是否安裝成功；若安裝成功，則需要檢查安裝目錄是否添加到環境變量path中。

二、下載源碼

　　1. grpc-1.3.1.tar.gz　　　　　　　　　 解壓到D:/grpc-1.3.1

　　2. benchmark-1.1.0.tar.gz　　　　　　解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/benchmark

　　3. boringssl-master.zip　　　　　　　  解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/boringssl

　　4. c-ares-cares-1_12_0.tar.gz　　　　 解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/cares/cares

　　5. gflags-2.2.0.tar.gz　　　　　　　　  解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/gflags

　　6. protobuf-3.0.0.tar.gz　　　　　　 　解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/protobuf

　　6. zlib-1.2.11.tar.gz　　　　　　　　　 解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/zlib

　　除grpc外，其他的第三方庫可以下載其他的版本，只要按照上面的路徑解壓到相應的目錄即可。注意一定要將c-ares-cares-1_12_0.tar.gz解壓到D:/grpc-1.3.1/grpc-1.3.1/third_party/cares/cares目錄，否是編譯會報錯。

三、編譯

　　1. 編寫腳本do_build.bat

@echo off
::Release,Debug,RelWithDebInfo
set CMAKE_BUILD_TYPE=%1%
::x86,x64
set PLATFORM=%2%
set OUTPUT_PATH=%3%
set CMAKE_PATH=%4%

if not exist %PLATFORM% (
    mkdir %PLATFORM%
)
cd %PLATFORM%

if %PLATFORM% == x86 (
    call "%VS140COMNTOOLS%..\..\VC\vcvarsall.bat" x86
)
if %PLATFORM% == x64 (
    call "%VS140COMNTOOLS%..\..\VC\vcvarsall.bat" amd64
)

echo cmake -G "NMake Makefiles" -D CMAKE_BUILD_TYPE=%CMAKE_BUILD_TYPE% -D EXECUTABLE_OUTPUT_PATH=%OUTPUT_PATH% -D LIBRARY_OUTPUT_PATH=%OUTPUT_PATH% -D CMAKE_C_FLAGS_RELEASE="/MT /WX-" -D CMAKE_CXX_FLAGS_RELEASE="/MT /WX-" -D BUILD_SHARED_LIBS=0 %CMAKE_PATH%
::CMAKE_BUILD_TYPE=%CMAKE_BUILD_TYPE%　　　　構建類型(Release,Debug,RelWithDebInfo)
::EXECUTABLE_OUTPUT_PATH=%OUTPUT_PATH%    　可執行程序的路徑
::LIBRARY_OUTPUT_PATH=%OUTPUT_PATH%         靜態庫的路徑
::CMAKE_C_FLAGS_RELEASE="/MT /WX-"       　 使用靜態運行時庫,禁止將警告視為錯誤
::CMAKE_CXX_FLAGS_RELEASE="/MT /WX-"    　　使用靜態運行時庫,禁止將警告視為錯誤
::BUILD_SHARED_LIBS=0                    　 生成靜態庫
cmake -G "NMake Makefiles" -D CMAKE_BUILD_TYPE=%CMAKE_BUILD_TYPE% -D EXECUTABLE_OUTPUT_PATH=%OUTPUT_PATH% -D LIBRARY_OUTPUT_PATH=%OUTPUT_PATH% -D CMAKE_C_FLAGS_RELEASE="/MT /WX-" -D CMAKE_CXX_FLAGS_RELEASE="/MT /WX-" -D BUILD_SHARED_LIBS=0 %CMAKE_PATH%
nmake grpc grpc++ grpc_cpp_plugin protoc

 　　主要作用是根據傳入的參數生成nmake文件，其中"/MT /WX-"是傳遞給cl編譯器的參數，分別為"使用靜態運行時庫"和"禁止將警告視為錯誤"。這個有個技巧如果想要將其他的參數傳遞給編譯器，只需要在后面添加即可。

　　2. 編寫腳本build_x64.bat

@echo off

set CURRENT_DIR=%~dp0
set CMAKE_BUILD_TYPE=Release
set PLATFORM=x64
set OUTPUT_PATH=%CURRENT_DIR%/x64/bin
set CMAKE_PATH=%CURRENT_DIR%/../../

call do_build.bat %CMAKE_BUILD_TYPE% %PLATFORM% %OUTPUT_PATH% %CMAKE_PATH%

@pause

 　　生成Release x64平台庫文件

　　3. 編寫腳本build_x86.bat

@echo off

set CURRENT_DIR=%~dp0
set CMAKE_BUILD_TYPE=RelWithDebInfo
set PLATFORM=x86
set OUTPUT_PATH=%CURRENT_DIR%/x86/bin
set CMAKE_PATH=%CURRENT_DIR%/../../

call do_build.bat %CMAKE_BUILD_TYPE% %PLATFORM% %OUTPUT_PATH% %CMAKE_PATH%

@pause

 　　生成Release x86平台庫文件

 　　4. 開始編譯

　　將build_x64.bat、build_x86.bat和do_build.bat腳本，拷貝到D:/grpc-1.3.1/grpc-1.3.1/cmake目錄下

　　運行build_x64.bat和build_x86.bat進行編譯

 

所有資源下載鏈接：http://pan.baidu.com/s/1pL8sOcz 提取密碼vm8v