/*
customerlevel:客戶等級 數值型變量 1-9
working_status:是否工薪 字符型變量,是否
feerate:費率 數值型變量：
scorecard_type：評分卡類型,數值型變量1,2,3
*/
ods rtf file='D:\feerate_chart.doc';
OPTIONS NOCENTER LS=MAX PS=MAX;
LIBNAME S 'D:\';
DATA S.feerate_noerror_1(KEEP=customerlevel working_status scorecard_type FeeRate);
SET S.feerate_noerror;
RUN;
/*
SAS proc gchart 可以制作柱狀圖和餅圖（二維和三維）
可以做九種圖，分別是：hbar（水平條圖）、hbar3d（3d水平條圖）、vbar（垂直條圖）、vbar3d（3d垂直條圖）、pie（餅圖）、pie3d（3d餅圖）、dount（環形圖）、star(星形圖)、block（方塊圖）。
基本語法：
PROC GCHART DATA=數據集;
圖形名 分類變量</選項>;
RUN;
分類變量是字符型時，變量每個值是一個類別；
分類變量是數值型時，系統認為該變量是連續變化的，自動將分類變量的變化范圍划分為若干個等長區間，取區間中點為每個類的標簽；但是可以通過選項設置；
當程序不指明分析變量，作圖缺省使用的統計量是頻數（Freq）；若指明分析變量，缺省使用的統計量是總和（Sum）,
使用title和footnote為圖形加入標題和腳注。
*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
VBAR customerlevel;
TITLE c=red '客戶類型條形圖1';
RUN;
/*與分類有關的選項
customerlevel是數值型變量
LEVELS=N;對數值型變量設定其分為n個類
MIDPOINTS=值列；對字符型變量依次列舉每個類的變量值(如：'aa' 'bb' 'cc')；對數值分類變量列舉分類變量每個區間的中點（如：100 to 2000 by 100）。
DISCRETE;對數值型分類變量讓變量的每個值表示一個類（離散的數值型變量）
ASCENDING;按統計值的升序排序各個柱（餅的各個角）
DESCENDING;按統計值的降序排序各個柱（餅的各個角）
*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
VBAR customerlevel/DISCRETE TYPE=PERCENT;
TITLE c=red '客戶類型條形圖2';
RUN;
/*選擇分析變量和統計量
未指明分析變量時，取每個類的頻數為統計量
</選項>：
SUMVAR=變量名；設定分析變量
TYPE=FREQ|CFREQ|PERCENT|CPERCENT|MEAN|SUM;分別設定統計量為頻數、累計頻數、百分數、累計百分數、均值和或總和。若未設定分析變量，統計量缺省為FREQ；若設定分析變量，統計量缺省為SUM;使用MEAN和SUM必須設定分析變量，其他統計量可不設置分析變量
*/
/*顯示統計量的數值
可以顯示的統計量的值就是TYPE=允許的6個統計量
選項有：
NOSTATS;對水平柱狀圖不顯示統計量的值
OUTSIDE=統計量；在柱的外部顯示統計量的值
INSIDE=統計量；在(三維)垂直柱狀圖的內部顯示統計量的值
這里的統計量可以與“TYPE=統計量”的設定不同，但使用同一個分析變量。
*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
VBAR customerlevel/DISCRETE TYPE=PERCENT WIDTH=6 OUTSIDE=PERCENT;
TITLE c=red '客戶類型條形圖3';
RUN;
/*柱狀圖的修飾
1.加框及背景
2.坐標軸的修飾語參考線的加入
3.柱的顏色和花紋的設定
4.圖例的加入與修飾*/
/*坐標軸的修飾選項
NOAXIS:不顯示坐標軸及相關的內容
CAXIS=顏色；設定坐標軸的顏色
CTEXT=顏色；設定坐標軸用的字符的顏色
MNIOR=N；表示坐標軸主刻度之間加入n個次刻度
AUTOREF;自動加入與表示統計數值的坐標軸相交的參考線
NOFRAME:無邊框
CFRAME=顏色；設定框內背景顏色
與柱寬有關的選項
WIDTH=N;設定柱寬為n個CELL
SPACE=N;設定柱間空n個CELL
*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
VBAR customerlevel/DISCRETE TYPE=PERCENT OUTSIDE=PERCENT WIDTH=6 SPACE=1 AUTOREF;
TITLE c=red '客戶類型條形圖4';
RUN;
/*加入其它的分類變量
GROUP=變量名；制定分組變量，形成多個並列的柱狀圖
SUBGROUP=變量名;設定子組
PATTERNID=MIDPOINT|GROUP|SUBGROUP;設定按照哪個變量的不同值使用不同的PATTERN語句，缺省為SUBFROUP*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
VBAR customerlevel/DISCRETE TYPE=PERCENT OUTSIDE=PERCENT AUTOREF WIDTH=6 GROUP=scorecard_type PATTERNID=GROUP;
TITLE c=red '客戶類型條形圖5';
RUN;
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
HBAR customerlevel/DISCRETE TYPE=PERCENT OUTSIDE=PERCENT AUTOREF WIDTH=6 SUBGROUP=scorecard_type PATTERNID=SUBGROUP;
TITLE c=red '客戶類型條形圖6';
RUN;
/*圖例
LEGEND=LEGEND;描述圖例*/
GOPTIONS RESET=ALL;
PROC GCHART DATA=S.feerate_noerror_1;
HBAR customerlevel/DISCRETE TYPE=PERCENT OUTSIDE=PERCENT AUTOREF WIDTH=6 SUBGROUP=scorecard_type PATTERNID=SUBGROUP LEGEND=LEGEND1;
LEGEND1 POSITION=(TOP CENTER OUTSIDE) DOWN=2 FRAME;
TITLE c=red '客戶類型條形圖7';
RUN;
/*GOPTIONS 選項
RESET=ALL;將所有圖形的選項設置為默認狀態，並且刪除所有全局的語句，比如AXIS,PATTERN,SYMBOL
RESET=GLOBAL;將所有的全局設置恢復為默認狀態，其他設置不變
ROTATE;將圖形從其默認的方向旋轉為90度
CBACK=colour;指定圖形背景顏色，默認的是白色
FTEXT=font;選擇字體樣式，常用的有FTEXT=SWISS;
FTITLE=font;選擇抬頭字體，默認是SWISS;
HTEXT=text-height;設定文本的高度
HTITLE=title-height;設定抬頭的高度
HSIZE=horizontal-size<IN or CM or PT>指定圖形寬度
VSIZE=vertical-size<IN or CM or PT>指定圖形高度（默認單位IN.IN是inch英寸，pt是point點，1in=2.54cm=72pt ）
*/
ods rtf close;