批處理bat標准化獲取當前系統日期的幾種方法，補0

首先有兩個推薦的方案。

一：

for /f "tokens=2 delims==" %%a in ('wmic path win32_operatingsystem get LocalDateTime /value') do (set t=%%a)
set Today=%t:~0,4%%t:~4,2%%t:~6,2%%t:~8,2%%t:~10,2%
echo %Today%

 

二：

if %time:~0,2% LEQ 9 (echo %date:~2,2%%date:~5,2%%date:~8,2%0%time:~1,1%%time:~3,2%) else (echo %date:~2,2%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%) 

 

 若要繼續研究請閱讀下面文章：

 

 使用0替換空格

有時候我們需要獲取當前系統的時間，如果小時小於10的話，獲取小時會出現空格的情況：

c:\>time
當前時間:  8:52:38.05
c:\>echo %time:~0,2%
 8    ------這個8前面是有空格的

c:\>
如何去掉空格讓時間正確的顯示呢？其實只需要將空格替換成0就可以了。

c:\>set h=%time:~0,2%

c:\>echo %h: =0%  -----這里的‘=’就是‘替換’的含意
08

c:\>
你也可以將這里的空格替換成其它值：
c:\>echo %h: =aaaaa%
aaaaa8
那現在獲取當前系統的日期和時間就可以這么寫了：

c:\>set h=%time:~0,2%

c:\>set h=%h: =0%

c:\>echo %date:~0,4%%date:~5,2%%date:~8,2%%h%%time:~3,2%%time:~6,2%
20150324090254
 
原：http://blog.csdn.net/chinadm123/article/details/44588891

多格式兼容

操作系統不同，日期格式也可能不同：
星期二 2008-07-29
2008-07-29 星期二
07/29/2008 Tue
Tue 07/29/2008
 
再考慮到中、英之外的其它語言的操作系統，日期格式的種類實在太多了。
要想標准化地獲取當前系統日期2008-07-28，直接截取%date%變量的方法是不行的。
【方案一】BAT + REG
@echo off
rem 無法保證在中、英之外的其它語言的操作系統上得到正確結果
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
set Today=%date: =%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set "Week=Mon Tue Wed Thu Fri Sat Sun 星期一 星期二 星期三 星期四 星期五 星期六 星期日"
for %%a in (%Week%) do (
  call set "Today=%%Today:%%a=%%"
)
echo,%Today%
pause
【方案二】BAT + REG
@echo off
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
set Today=%date: =%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
if "%Today:~0,1%" gtr "9" (
  set Today=%Today:~-10%
) else (
  set Today=%Today:~0,10%
)
echo,%Today%
pause
【方案三】BAT + REG
@echo off
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
type nul>"%temp%/MyFile.tmp"
for /f %%a in ('dir "%temp%/MyFile.tmp" ^| findstr /i "MyFile.tmp"') do (
  set Today=%%a
)
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
echo,%Today%
pause
【方案四】BAT + WMIC
@echo off
for /f "tokens=2 delims==" %%a in ('wmic path win32_operatingsystem get LocalDateTime /value') do (
  set t=%%a
)
set Today=%t:~0,4%-%t:~4,2%-%t:~6,2%
echo,%Today%
pause
【方案五】BAT + VBS
@echo off
>"%temp%/DateCalculate.vbs" echo dt=date()
>>"%temp%/DateCalculate.vbs" echo s=right(year(dt),4) ^& "-" ^& right("0" ^& month(dt),2) ^& "-" ^& right("0" ^& day(dt),2)
>>"%temp%/DateCalculate.vbs" echo wscript.echo s
for /f %%a in ('cscript /nologo "%temp%/DateCalculate.vbs"') do set (
  Today=%%a
)
echo,%Today%
pause
【方案六】BAT + REGEDIT
@echo off
rem 需要保證注冊表編輯器沒有處於鎖定狀態
regedit /e "%temp%/bak.reg" "HKEY_CURRENT_USER/Control Panel/International"
>"%temp%/new.reg" echo REGEDIT4
>>"%temp%/new.reg" echo,
>>"%temp%/new.reg" echo [HKEY_CURRENT_USER/Control Panel/International]
>>"%temp%/new.reg" echo "sShortDate"="yyyy-MM-dd"
regedit /s "%temp%/new.reg"
set Today=%date: =%
regedit /s "%temp%/bak.reg"
if "%Today:~0,1%" gtr "9" (
  set Today=%Today:~-10%
) else (
  set Today=%Today:~0,10%
)
echo,%Today%
pause 
【方案七】BAT + DEBUG
 @echo off
for /f "tokens=6,8 delims== " %%a in ('^(echo a100^&echo mov ah^,2a^&echo int 21^&echo.^&echo p 2^&echo q^)^|debug^|find "CX"') do (
  set /a y=0x%%a
  set md=%%b
)
set /a m=0x%md:~,2%
set /a d=0x%md:~-2%
set m=0%m%
set d=0%d%
set Today=%y%-%m:~-2%-%d:~-2%
echo,%Today%
pause

原：http://www.jb51.net/article/52749.htm