[No0000C1]Excel 刪除空白行和空白列VBA代碼

在exce中刪除空行和空列的方法有很多，相對而言刪除空行較為簡單，只需進行篩選，將空白行篩選出來，刪除即可，但要刪除空列比較困難。因為你不能按列進行篩選刪除。Excel中沒有這個功能。當然你可以用另外一種方法，就是按列進行排序將空白列排序在一起，然后刪除，但這種方法面臨着列的順序被打亂的問題，吃力不討好。本文將利用Excel中強大VBA功能來完成。

假設要刪除如下圖中的空白行或空白列：

 

 文件-》選項-》自定義功能區-》主選項卡-》開發工具

插入按鈕

表單控件或者ActiveX控件都可以。

先以表單控件介紹：

Alt+F11 打開vb宏編輯器，插入模塊，並輸入如下代碼：

'刪除空行
Sub DeleteEmptyRows()
Dim LastRow As Long, r As Long
LastRow = ActiveSheet.UsedRange.Rows.Count
LastRow = LastRow + ActiveSheet.UsedRange.Row - 1

For r = LastRow To 1 Step -1
    If WorksheetFunction.CountA(Rows(r)) = 0 Then Rows(r).Delete
    Next r
    
End Sub
'刪除空列
Sub DeleteEmptyColumns()
Dim LastColumn As Long, c As Long
LastColumn = ActiveSheet.UsedRange.Columns.Count
LastColumn = LastColumn + ActiveSheet.UsedRange.Column

For c = LastColumn To 1 Step -1
    If WorksheetFunction.CountA(Columns(c)) = 0 Then Columns(c).Delete
    Next c
    
End Sub

關閉編輯器后，在界面拖畫一個按鈕，在彈出的窗口中選中DeleteEmptyColumns（即剛才插入的刪除空列）函數方法。

右鍵剛才拖出的按鈕，右鍵 編輯文字 修改為 刪除空列

之后在非"設計模式"下，點擊測試

同樣的，添加 刪除空行按鈕

保存時，會彈出警告：

因此需要另存為"啟用宏的工作簿"。

然后保存。

再以ActiveX控件為例：

拖出按鈕后，打開設計模式

在設計模式下，右鍵修改button的名稱，即Caption屬性

雙擊打開消息框

在打開的編輯器中，輸入

    MsgBox ("消息框")

 

關閉設計模式和編輯器，點擊按鈕測試

同樣的可以創建兩個ActiveX按鈕，完成刪除所選區空列和刪除所選區空行

下面的方法是用VBA代碼來刪除工作表指定區域中的空行和空列：
在運行代碼前，先選擇需要刪除空行和空列的區域。如果要刪除空行，則運行Delete_Empty_Rows()，指定區域中的空行將被刪除。

注意所謂空行是在指定區域中的，如果在指定區域內是空行，而在指定區域外不是空行，那么這些空行還是將會被刪除。刪除空列則運行Delete_Empty_Columns()。

不過，此刻的代碼作用在Sheet1 上

Private Sub CommandButton1_Click()
    MsgBox ("消息框")
End Sub

Private Sub CommandButton2_Click()
    Delete_Empty_Rows
End Sub

Private Sub CommandButton3_Click()
    Delete_Empty_Columns
End Sub
'Option Explicit
'刪除所選區空行
Sub Delete_Empty_Rows()
    Dim rnArea As Range
    Dim lnLastRow As Long, i As Long, j As Long
 
    Application.ScreenUpdating = False
    lnLastRow = Selection.Rows.Count
    Set rnArea = Selection

     If rnArea.Rows.Count <= 1 Then
        MsgBox ("請先選中一塊多行包含文字的區域")
        GoTo LastLine
     End If

    j = 0
 
    For i = lnLastRow To 1 Step -1
        If Application.CountA(rnArea.Rows(i)) = 0 Then
            rnArea.Rows(i).Delete
            j = j + 1
        End If
    Next i
 
    If (lnLastRow - j) > 0 Then
        rnArea.Resize(lnLastRow - j).Select
    End If
    
    Application.ScreenUpdating = True
    
LastLine:

End Sub
 '刪除所選區空列
Sub Delete_Empty_Columns()
    Dim lnLastColumn As Long, i As Long, j As Long
    Dim rnArea As Range
 
    Application.ScreenUpdating = False
    lnLastColumn = Selection.Columns.Count
    Set rnArea = Selection
 
    If rnArea.Columns.Count <= 1 Then
            MsgBox ("請先選中一塊多列包含文字的區域")
            GoTo LastLine
     End If
     
    j = 0
 
    For i = lnLastColumn To 1 Step -1
        If Application.CountA(rnArea.Columns(i)) = 0 Then
            rnArea.Columns(i).Delete
            j = j + 1
        End If
    Next i
    
    If (lnLastColumn - j) > 0 Then
        rnArea.Resize(, lnLastColumn - j).Select
    End If
 
    Application.ScreenUpdating = False
    
LastLine:

End Sub

 

調整好按鈕位置就可以用了。不過有時候按鈕會擋住文字部分，所以可以把它移動到快速訪問工具欄上。

自定義到工具欄，快速訪問

excel選項-自定義-從下列位置選擇命令-選擇宏-》STEP添加到自定義快速訪問工具欄中

 附件