nvmw安裝，用於控制node版本;

之前一直使用的是node v2.2.0版本，挺說新版本的node解決了npm安裝插件產生文件夾結構過深的問題，所以就想更新試試；

上網一看才發現，尼瑪的node已經到了6.+版本了，好吧，看來還是得跟上節奏；

但是呢，怎么更新node就成了個問題，卸載重裝？ 這樣又會出現一些配置的麻煩；

經過一番查找發現：可以使用 nvm 管理不同版本的 node 與 npm；

nvm 是 Mac 下的 node 管理工具，有點類似管理 Ruby 的 rvm，如果是需要管理 Windows 下的 node，官方推薦是使用 nvmw 或 nvm-windows 。

接下來就記錄一下我安裝nvmw的具體過程和一些坑；（不要問我為什么選nvmw，因為窮叼不會用Mac，而-windows貌似有些問題）

 

百度了一早上，終於完成了node的升級，從頭開始來吧，也整理了一下其中遇到的問題；
1、首先下載   nvmw https://github.com/hakobera/nvmw
方法：
git clone https://github.com/hakobera/nvmw.git；或者直接下載zip壓縮包；

由於本人的git不知道抽什么瘋，clone的時候一直出現

如果有大神知道是什么問題，請評論留言；萬分感謝；

 

2、配置環境變量
復制nvmw路徑，我的電腦右鍵→屬性→高級系統設置→高級→環境變量
這里我用戶環境和系統環境都該了，照理說改系統環境就可以了；

 

這里有個坑，就是修改變量后要重新關閉CMD，重開一次，才能正常運用；

3、配置完后打開CMD，輸入nvmw，如果正確配置的話可以查看幫助
百度的時候聽說 nvmw install v6.9.2 無法安裝成功；
我沒試過，不過我用的是沒有v的 nvmw install 6.9.2成功了；

 

4、不要高興的太早，這才是剛剛開始；
第一個坑： 直接使用nvmw install 6.9.2 來安裝新版本時提示：

解決辦法：這樣的錯誤,原因是因為JS擴展名的文件被其他軟件關聯了，需要取消關聯。
如系統中安裝了ULTRAEDIT或者E鑽加密軟件等，就需要去掉關聯；
或者如下解決方法：
在運行中輸入“regedit”進入注冊表，
只需要把[HKEY_CLASSES_ROOT\.js] 項下的那個默認值改成 "JSFile" 就可以正常運行JS 文件了。

第二個坑：
這貨直接在天朝是使用不了的，好在這個外國作者也知道中國的國情。提供了如何設置淘寶鏡像的方式
set "NVMW_NODEJS_ORG_MIRROR=http://npm.taobao.org/mirrors/node"
set "NVMW_IOJS_ORG_MIRROR=http://npm.taobao.org/mirrors/iojs"
set "NVMW_NPM_MIRROR=http://npm.taobao.org/mirrors/npm"
注：每次使用，都得重新在命令行中設置，或者可以這三個變量也設置到環境變量中，或改一下他的源碼，把這三個變量寫死。

第三個坑：我是windows7系統，對應的是x64沒錯，但是在淘寶NPM鏡像站和官方鏡像站上對應的都是win-x64 ；
進入nvmw的程序目錄。
1.修改nvmw.bat文件137行，x64改為win-x64
2.修改fget.js文件47行，XMLHTTP 更改為ServerXMLHTTP
其實有現成的修改版的nvmw.bat 一下就是代碼，可以留個副本；

@echo off
if not defined NVMW_HOME (
  set "NVMW_HOME=%~dp0"
)
if not defined PATH_ORG (
  set "PATH_ORG=%PATH%"
)
set IS64=FALSE
if exist "%PROGRAMFILES(X86)%" (
  set IS64=TRUE
)
if %IS64% == TRUE (
  set OS_ARCH=x64
) else (
  set OS_ARCH=x32
)
if not defined NVMW_NODEJS_ORG_MIRROR (
  set "NVMW_NODEJS_ORG_MIRROR=https://nodejs.org/dist"
)
if not defined NVMW_IOJS_ORG_MIRROR (
  set "NVMW_IOJS_ORG_MIRROR=https://iojs.org/dist"
)
if "%1" == "install" if not "%2" == "" (
  call :install %2 %3
  if not ERRORLEVEL == 1 call :use %2 %3
  exit /b %ERRORLEVEL%
)
if "%1" == "use" if not "%2" == "" (
  call :use %2 %3
  exit /b %ERRORLEVEL%
)
if "%1" == "ls" (
  call :ls
  exit /b %ERRORLEVEL%
)
if "%1" == "uninstall" if not "%2" == "" (
  call :uninstall %2 %3
  exit /b %ERRORLEVEL%
)
call :help
exit /b %ERRORLEVEL%
::===========================================================
:: help : Show help message
::===========================================================
:help
echo;
echo Node Version Manager for Windows
echo;
echo Usage:
echo   nvmw help                          Show this message
echo   nvmw install [version] [arch]      Download and install a [version]
echo                                        for [arch] architecture (optional)
echo   nvmw uninstall [version]           Uninstall a [version]
echo   nvmw use [version]                 Modify PATH to use [version]
echo   nvmw ls                            List installed versions
echo;
echo Example:
echo   nvmw install v0.10.21        Install a specific version number of node.js
echo   nvmw use v0.10.21            Use the specific version
echo   nvmw install iojs            Install the latest version of io.js
echo   nvmw install iojs-v1.0.2     Install a specific version number of io.js
echo   nvmw use iojs-v1.0.2         Use the specific version io.js
echo;
echo   nvmw install v0.10.35 x86    Install a 32-bit version
exit /b 0
::===========================================================
:: install : Install specified version node and npm
::===========================================================
:install
setlocal
set ARCH=%OS_ARCH%
if not "%2" == "" (
  set ARCH=%2
  :: x86, ia32 alias x32
  if "%2" == "x86" (
    set ARCH=x32
  )
  if "%2" == "ia32" (
    set ARCH=x32
  )
)
set NODE_TYPE=node
set NODE_VERSION=%1
:: nvmw install iojs-v1.0.2
if "%NODE_VERSION:~4,1%" == "-" (
  for /f "tokens=1,2,* delims=-" %%a in ("%NODE_VERSION%") do (
    set NODE_TYPE=%%a
    set NODE_VERSION=%%b
  )
)
:: nvmw install iojs
if %NODE_VERSION% == iojs (
  set NODE_TYPE=iojs
  set NODE_VERSION=latest
)
:: nvmw install node
if %NODE_VERSION% == node (
  set NODE_TYPE=node
  set NODE_VERSION=latest
)
:: iojs-1.0.0, iojs-latest
if not %NODE_VERSION:~0,1% == v if not %NODE_VERSION:~0,1% == l (
  set NODE_VERSION=v%NODE_VERSION%
)
if %NODE_TYPE% == iojs (
  set DIST_URL=%%
  if %ARCH% == x32 (
    set NODE_EXE_URL=%NVMW_IOJS_ORG_MIRROR%/%NODE_VERSION%/win-x86/iojs.exe
  ) else (
    set NODE_EXE_URL=%NVMW_IOJS_ORG_MIRROR%/%NODE_VERSION%/win-x64/iojs.exe
  )
) else if %NODE_VERSION:~0,1% == 0 (
  if %ARCH% == x32 (
    set NODE_EXE_URL=%NVMW_NODEJS_ORG_MIRROR%/%NODE_VERSION%/node.exe
  ) else (
    set NODE_EXE_URL=%NVMW_NODEJS_ORG_MIRROR%/%NODE_VERSION%/x64/node.exe
  )
) else (
  if %ARCH% == x32 (
    set NODE_EXE_URL=%NVMW_NODEJS_ORG_MIRROR%/%NODE_VERSION%/win-x86/node.exe
  ) else (
    set NODE_EXE_URL=%NVMW_NODEJS_ORG_MIRROR%/%NODE_VERSION%/win-x64/node.exe
  )
)
set "NODE_HOME=%NVMW_HOME%%NODE_VERSION%"
if %NODE_TYPE% == iojs (
  set "NODE_HOME=%NVMW_HOME%%NODE_TYPE%\%NODE_VERSION%"
)
if not %ARCH% == %OS_ARCH% (
  set "NODE_HOME=%NODE_HOME%-%ARCH%"
)
set "NODE_EXE_FILE=%NODE_HOME%\%NODE_TYPE%.exe"
set "NPM_ZIP_FILE=%NODE_HOME%\npm.zip"
if exist "%NODE_EXE_FILE%" (
  endlocal
  echo "%NODE_TYPE%/%NODE_VERSION% (%ARCH%)" already exists, please uninstall it first
  exit /b 1
)
mkdir "%NODE_HOME%"
echo Start installing %NODE_TYPE%/%NODE_VERSION% (%ARCH%) to %NODE_HOME%
cscript //nologo "%NVMW_HOME%\fget.js" %NODE_EXE_URL% "%NODE_EXE_FILE%"
if not exist "%NODE_EXE_FILE%" (
  echo Download %NODE_EXE_FILE% from %NODE_EXE_URL% failed
  goto install_error
) else (
  if %NODE_TYPE% == iojs (
    copy "%NVMW_HOME%\alias-node.cmd" "%NODE_HOME%\node.cmd"
  )
  echo Start install npm
  "%NODE_EXE_FILE%" "%NVMW_HOME%\get_npm.js" "%NODE_HOME%" "%NODE_TYPE%/%NODE_VERSION%"
  if not exist "%NPM_ZIP_FILE%" goto install_error
  set "CD_ORG=%CD%"
  %~d0
  cd "%NODE_HOME%"
  echo Start unzip "%NPM_ZIP_FILE%" to "%NODE_HOME%"
  cscript //nologo "%NVMW_HOME%\unzip.js" "%NPM_ZIP_FILE%" "%NODE_HOME%"
  mkdir "%NODE_HOME%\node_modules"
  rmdir /s /q "%NODE_HOME%\node_modules\npm"
  move npm-* "%NODE_HOME%\node_modules\npm"
  copy "%NODE_HOME%\node_modules\npm\bin\npm.cmd" "%NODE_HOME%\npm.cmd"
  cd "%CD_ORG%"
  if not exist "%NODE_HOME%\npm.cmd" goto install_error
  echo npm install ok
  echo Finished
  endlocal
  exit /b 0
)
:install_error
  rd /Q /S "%NODE_HOME%"
  endlocal
  exit /b 1
::===========================================================
:: uninstall : Uninstall specified version
::===========================================================
:uninstall
setlocal
set ARCH=%OS_ARCH%
if not "%2" == "" (
  set ARCH=%2
  :: x86, ia32 alias x32
  if "%2" == "x86" (
    set ARCH=x32
  )
  if "%2" == "ia32" (
    set ARCH=x32
  )
)
set NODE_TYPE=node
set NODE_VERSION=%1
if "%NODE_VERSION:~4,1%" == "-" (
  for /f "tokens=1,2,* delims=-" %%a in ("%NODE_VERSION%") do (
    set NODE_TYPE=%%a
    set NODE_VERSION=%%b
  )
)
:: nvmw uninstall iojs
if %NODE_VERSION% == iojs (
  set NODE_TYPE=iojs
  set NODE_VERSION=latest
)
:: nvmw uninstall node
if %NODE_VERSION% == node (
  set NODE_TYPE=node
  set NODE_VERSION=latest
)
if not %NODE_VERSION:~0,1% == v if not %NODE_VERSION:~0,1% == l (
  set NODE_VERSION=v%NODE_VERSION%
)
if "%NVMW_CURRENT_TYPE%" == "%NODE_TYPE%" if "%NVMW_CURRENT%" == "%NODE_VERSION%" if "%NVMW_CURRENT_ARCH%" == "%ARCH%" (
  echo Cannot uninstall currently-active %NODE_TYPE%/%NODE_VERSION% %ARCH%
  exit /b 1
)
set "NODE_HOME=%NVMW_HOME%%NODE_VERSION%"
if %NODE_TYPE% == iojs (
  set "NODE_HOME=%NVMW_HOME%%NODE_TYPE%\%NODE_VERSION%"
)
if not %ARCH% == %OS_ARCH% (
  set "NODE_HOME=%NODE_HOME%-%ARCH%"
)
if not exist "%NODE_HOME%" (
  echo %NODE_TYPE%/%NODE_VERSION% %ARCH% is not installed
  exit /b 1
) else (
  rd /Q /S "%NODE_HOME%"
  if ERRORLEVEL == 1 (
    echo Cannot uninstall %NODE_TYPE%/%NODE_VERSION% %ARCH%
    exit /b 1
  ) else (
    echo Uninstalled %NODE_TYPE%/%NODE_VERSION% %ARCH%
    endlocal
    exit /b 0
  )
)
::===========================================================
:: use : Change current version
::===========================================================
:use
setlocal
set ARCH=%OS_ARCH%
if not "%2" == "" (
  set ARCH=%2
  :: x86, ia32 alias x32
  if "%2" == "x86" (
    set ARCH=x32
  )
  if "%2" == "ia32" (
    set ARCH=x32
  )
)
set NODE_TYPE=node
set NODE_VERSION=%1
if "%NODE_VERSION:~4,1%" == "-" (
  for /f "tokens=1,2,* delims=-" %%a in ("%NODE_VERSION%") do (
    set NODE_TYPE=%%a
    set NODE_VERSION=%%b
  )
)
:: nvmw use iojs
if %NODE_VERSION% == iojs (
  set NODE_TYPE=iojs
  set NODE_VERSION=latest
)
:: nvmw use node
if %NODE_VERSION% == node (
  set NODE_TYPE=node
  set NODE_VERSION=latest
)
if not %NODE_VERSION:~0,1% == v if not %NODE_VERSION:~0,1% == l (
  set NODE_VERSION=v%NODE_VERSION%
)
set "NODE_HOME=%NVMW_HOME%%NODE_VERSION%"
if %NODE_TYPE% == iojs (
  set "NODE_HOME=%NVMW_HOME%%NODE_TYPE%\%NODE_VERSION%"
)
if not %ARCH% == %OS_ARCH% (
  set "NODE_HOME=%NODE_HOME%-%ARCH%"
)
if not exist "%NODE_HOME%" (
  echo %NODE_TYPE%/%NODE_VERSION% is not installed
  exit /b 1
)
endlocal
set NVMW_CURRENT_ARCH=%OS_ARCH%
if not "%2" == "" (
  set NVMW_CURRENT_ARCH=%2
  :: x86, ia32 alias x32
  if "%2" == "x86" (
    set NVMW_CURRENT_ARCH=x32
  )
  if "%2" == "ia32" (
    set NVMW_CURRENT_ARCH=x32
  )
)
set NVMW_CURRENT_TYPE=node
set NVMW_CURRENT=%1
if "%NVMW_CURRENT:~4,1%" == "-" (
  for /f "tokens=1,2,* delims=-" %%a in ("%NVMW_CURRENT%") do (
    set NVMW_CURRENT_TYPE=%%a
    set NVMW_CURRENT=%%b
  )
)
if %NVMW_CURRENT% == iojs (
  set NVMW_CURRENT_TYPE=iojs
  set NVMW_CURRENT=latest
)
if %NVMW_CURRENT% == node (
  set NVMW_CURRENT_TYPE=node
  set NVMW_CURRENT=latest
)
if not %NVMW_CURRENT:~0,1% == v if not %NVMW_CURRENT:~0,1% == l (
  set NVMW_CURRENT=v%NVMW_CURRENT%
)
echo Now using %NVMW_CURRENT_TYPE% %NVMW_CURRENT% %NVMW_CURRENT_ARCH%
set "NODE_HOME=%NVMW_HOME%%NODE_VERSION%"
if %NVMW_CURRENT_TYPE% == iojs (
  set "NODE_HOME=%NVMW_HOME%%NODE_TYPE%\%NODE_VERSION%"
)
if not %NVMW_CURRENT_ARCH% == %OS_ARCH% (
  set NVMW_CURRENT_ARCH_PADDING=-%NVMW_CURRENT_ARCH%
) else (
  set NVMW_CURRENT_ARCH_PADDING=
)
if %NVMW_CURRENT_TYPE% == iojs (
  set "PATH=%NVMW_HOME%;%NVMW_HOME%%NVMW_CURRENT_TYPE%\%NVMW_CURRENT%%NVMW_CURRENT_ARCH_PADDING%;%PATH_ORG%"
  set "NODE_PATH=%NVMW_HOME%%NVMW_CURRENT_TYPE%\%NVMW_CURRENT%%NVMW_CURRENT_ARCH_PADDING%\node_modules"
) else (
  set "PATH=%NVMW_HOME%;%NVMW_HOME%\%NVMW_CURRENT%%NVMW_CURRENT_ARCH_PADDING%;%PATH_ORG%"
  set "NODE_PATH=%NVMW_HOME%\%NVMW_CURRENT%%NVMW_CURRENT_ARCH_PADDING%\node_modules"
)
exit /b 0
::===========================================================
:: ls : List installed versions
::===========================================================
:ls
setlocal
echo node:
if exist "%NVMW_HOME%" (
  dir "%NVMW_HOME%v*" /b /ad
)
echo;
echo iojs:
if exist "%NVMW_HOME%iojs" (
  dir "%NVMW_HOME%iojs\*" /b /ad
)
echo;
if not defined NVMW_CURRENT (
  set NVMW_CURRENT_V=none
) else (
  set NVMW_CURRENT_V=%NVMW_CURRENT%
)
echo Current: %NVMW_CURRENT_TYPE%/%NVMW_CURRENT_V% %NVMW_CURRENT_ARCH%
endlocal
exit /b 0

第四個坑：更新node到4.0及以上的時候會出現安裝失敗 提示 node v6.9.2 does not include npm；
辦法： https://github.com/hakobera/nvmw/issues/58
https://my.oschina.net/bakuman/blog/637316
http://blog.5ibc.net/p/49266.html
按文章內容修改了nvmw.bat，然后手動下載npm-master.zip並改名為npm.zip后放到nvmw目錄下新建的v4.4.0目錄下，然后重新的執行 nvmw install 4.4.0，終於安裝成功。（CMD執行 nvmw install 6.9.2的時候會在nvmw安裝目錄中生產一個對應版本的文件夾，這時候把npm.zip壓縮包放進去，就能完成升級）；

這樣我們就可以控制nodejs的版本了，我的天，真心的麻煩~~

最后一步，我們可以使用  npm install npm -g 來獲得新版的npm了；

總算大功告成，大多數的解決辦法都是從網上找到的；

 

2017.02.22補充說明；

使用nvmw install 版本號  安裝了之后，並不會馬上轉變成安裝的版本，

需要使用nvmw use v6.9.2 (版本號看個人需求)進行版本的轉換，install只是保存到本地供版本替換使用；

 

下面是參考鏈接：

http://www.tuicool.com/articles/Vzquy2 

http://blog.csdn.net/duanyachao/article/details/51822015

http://www.wtoutiao.com/p/193HWBp.html

https://segmentfault.com/a/1190000004855835

https://my.oschina.net/bakuman/blog/637316

http://blog.5ibc.net/p/49266.html

https://github.com/hakobera/nvmw/issues/58

 

好了，希望能幫到需要的同學們。

2017.01.06

 

2018.10.11

換win10的環境后安裝沒有這么多的麻煩了，具體參考：https://segmentfault.com/a/1190000004855835

其中第三點.修改get_npm.js文件42行路徑，其實為

使用nvmw install 5.9.1安裝特定版本node時，最后會提示D:\nvmw\v5.9.1\node.exe - 另一個程序正在使用此文件，進程無法訪問。  

但是實質上是安裝成功的

nvmw use 5.9.1 

node -v

可以查看node版本已經切換為特定版本了