SQL作業的操作全

--定義創建作業 轉自http://hi.baidu.com/procedure/blog/item/7f959fb10d76f95d092302dd.html
DECLARE @jobid uniqueidentifier
EXEC msdb.dbo.sp_add_job
        @job_name = N'作業名稱',
        @job_id = @jobid OUTPUT

--定義作業步驟
DECLARE @sql nvarchar(400),@dbname sysname
SELECT @dbname=DB_NAME(), --作業步驟在當前數據庫中執行
        @sql=N'--作業步驟內容' --一般定義的是使用TSQL處理的作業,這里定義要執行的Transact-SQL語句
EXEC msdb.dbo.sp_add_jobstep
        @job_id = @jobid,
        @step_name = N'作業步驟名稱',
        @subsystem = 'TSQL', --步驟的類型,一般為TSQL
        @database_name=@dbname,
        @command = @sql

--創建調度(使用后面專門定義的幾種作業調度模板)
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=0x8,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=1,     --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--添加目標服務器
DECLARE @servername sysname
SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))
EXEC msdb.dbo.sp_add_jobserver 
        @job_id = @jobid,
        @server_name = @servername --使用當前SQL實例


--調度模板定義
--/*--日調度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=0x8,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=1,     --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS
--*/

--/*--周調度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 8,              --每周
        @freq_recurrence_factor = 1, --每多少周執行一次,這里是每周
        @freq_interval = 62,         --在星期幾執行,由POWER(2,N)表示,N的值為0~6,代表星期日~星期六,如果指定兩個,則將值相加,例如,值為65表示在星期天和星期日執行(POWER(2,0)+POWER(2,6))
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS
--*/

--/*--月調度(每X個月的每月幾號)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 16,             --每月
        @freq_recurrence_factor = 2, --每多少月執行一次,這里是每2個月
        @freq_interval = 2,          --在執行月的第幾天執行,這里是第2天
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS
--*/

--/*--月調度(每X個月的相對時間)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 32,             --每月
        @freq_recurrence_factor = 2, --每多少月執行一次,這里是每2個月
        @freq_interval = 9,          --在當月的那個時間執行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末
        @freq_relative_interval = 1, --在第幾個相對時間執行,允許的值為1,2,4,8代表第1~4個相對時間,16表示最后一個相對時間
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS
--*/

--/*--在特定時候執行的作業調度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 64     --64=在SQLServerAgent 服務啟動時運行,128=計算機空閑時運行
--*/

--/*--只執行一次的作業調度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=1,                --僅執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_start_time = 00000   --作業執行的開始時間,格式為HHMMSS
--*/

 

 

自己寫的一個通用存儲過程：

 

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go

 

 

 ALTER   proc   [dbo].[Formula_CreateJob]   
  @jobname   varchar(100),            --作業名稱   
  @sql   varchar(8000),               --要執行的命令, --作業步驟內容,一般定義的是使用TSQL處理的作業,這里定義要執行的Transact-SQL語句   
--  @serverName   sysname='',           --job   server名   
--  @dbname   sysname='',               --默認為當前的數據庫名     
  @freqtype  INT=4,       --頻率 4 天，8周，16 月調度(每X個月的每月幾號 ,32 月調度(每X個月的相對時間)  
  -----------------------------------------------------------------------------
  @freqInterval INT= 1,  
  --指定每多少天發生一次,這里是1天.
  --在星期幾執行,由POWER(2,N)表示,N的值為0~6,代表星期日~星期六,如果指定兩個,則將值相加,例如,值為65表示在星期天和星期日執行(POWER(2,0)+POWER(2,6))
 --在執行月的第幾天執行,這里是第1天
  --在當月的那個時間執行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末
@freq_recurrenceFactor INT =1,  --每多少月(周)執行一次,這里是每1
@freq_relativeInterval INT= 1, --在第幾個相對時間執行,允許的值為1,2,4,8代表第1~4個相對時間,16表示最后一個相對時間
  
--每天頻率
  @freqSubdayType INT =1,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
  @freqSubdayInterval INT =1,     --重復周期數,例freqSubdayType為8,freqSubdayInterval為2，則每2個小時執行一次
 --持續時間
  @active_startDate NVARCHAR(20)= NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
  @active_endDate NVARCHAR(20)='99991231', --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
  @active_startTime NVARCHAR(20)='0', --作業執行的開始時間,格式為HHMMSS
  @active_endTime NVARCHAR(20)='235959'    --作業執行的停止時間,格式為HHMMSS
  
AS  
BEGIN

--定義創建作業
DECLARE @jobid uniqueidentifier
EXEC msdb.dbo.sp_add_job
        @job_name = @jobname,
        @job_id = @jobid OUTPUT

--定義作業步驟
DECLARE @dbname sysname
SELECT @dbname=DB_NAME() --作業步驟在當前數據庫中執行
EXEC msdb.dbo.sp_add_jobstep
        @job_id = @jobid,
        @step_name = N'執行公式作業，生成費用明細',
        @subsystem = 'TSQL', --步驟的類型,一般為TSQL
        @database_name=@dbname,
        @command = @sql
        
 
--創建調度(使用后面專門定義的幾種作業調度模板)
--@freqtype  INT=4,       --頻率 4 天，8周，16 月調度(每X個月的每月幾號 ,32 月調度(每X個月的相對時間)  
 IF @freqtype=4
 BEGIN
 EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'日調度，生成費用明細',
        @freq_type=@freqtype,                --每天
        @freq_interval=@freqInterval,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=@freqSubdayType,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=@freqSubdayInterval,     --重復周期數,這里每小時執行一次
        @active_start_date = @active_startDate,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = @active_endDate, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = @active_startTime, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = @active_endTime    --作業執行的停止時間,格式為HHMMSS

 END
 IF @freqtype=8
 BEGIN
 
 EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'周調度，生成費用明細',
        @freq_type=@freqtype,                --每周
        @freq_recurrence_factor=@freq_recurrenceFactor,--每多少周執行一次,這里是每周
        @freq_interval=@freqInterval,             --在星期幾執行,由POWER(2,N)表示,N的值為0~6,代表星期日~星期六,如果指定兩個,則將值相加,例如,值為65表示在星期天和星期日執行(POWER(2,0)+POWER(2,6))
        @freq_subday_type=@freqSubdayType,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=@freqSubdayInterval,     --重復周期數,這里每小時執行一次
        @active_start_date = @active_startDate,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = @active_endDate, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = @active_startTime, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = @active_endTime    --作業執行的停止時間,格式為HHMMSS
 END
 IF @freqtype=16
 BEGIN
 EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'月調度，生成費用明細',
        @freq_type=@freqtype,                --每月
        @freq_recurrence_factor=@freq_recurrenceFactor,--每多少周執行一次,這里是每周
        @freq_interval=@freqInterval,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=@freqSubdayType,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=@freqSubdayInterval,     --重復周期數,這里每小時執行一次
        @active_start_date = @active_startDate,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = @active_endDate, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = @active_startTime, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = @active_endTime    --作業執行的停止時間,格式為HHMMSS
 END
 IF @freqtype=32
 BEGIN
  EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'月調度，生成費用明細',
        @freq_type=@freqtype,                --每月
        @freq_recurrence_factor=@freq_recurrenceFactor,--每多少周執行一次,這里是每周
        @freq_interval=@freqInterval,            --指定每多少天發生一次,這里是1天.
        @freq_relative_interval = @freq_relativeInterval, --在第幾個相對時間執行,允許的值為1,2,4,8代表第1~4個相對時間,16表示最后一個相對時間
        @freq_subday_type=@freqSubdayType,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=@freqSubdayInterval,     --重復周期數,這里每小時執行一次
        @active_start_date = @active_startDate,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = @active_endDate, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = @active_startTime, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = @active_endTime    --作業執行的停止時間,格式為HHMMSS
 END

 

 

--添加目標服務器
DECLARE @servername sysname
SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))
EXEC msdb.dbo.sp_add_jobserver 
        @job_id = @jobid,
        @server_name = @servername --使用當前SQL實例


END