sqlserver 作業調度（作業常用的幾個步驟）

--【作業常用的幾個步驟】
EXEC msdb.dbo.sp_delete_job
EXEC msdb.dbo.sp_add_job
EXEC msdb.dbo.sp_add_jobstep
EXEC msdb..sp_add_jobschedule
EXEC msdb.dbo.sp_add_jobserver 
EXEC msdb.dbo.sp_start_job



--刪除作業
IF  EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =N'作業名稱') 
EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=N'作業名稱' 

--定義創建作業
DECLARE @jobid uniqueidentifier
EXEC msdb.dbo.sp_add_job
        @job_name = N'作業名稱',
        @job_id = @jobid OUTPUT

--定義作業步驟
DECLARE @sql nvarchar(400),@dbname sysname
SELECT    @dbname=DB_NAME(), --執行的數據庫（當前）
        @sql=N'作業步驟內容' --一般定義的是使用TSQL處理的作業,這里定義要執行的Transact-SQL語句
EXEC msdb.dbo.sp_add_jobstep
        @job_id = @jobid,
        @step_name = N'作業步驟名稱',
        @subsystem = 'TSQL', --步驟的類型,一般為TSQL
        @database_name=@dbname,
        @command = @sql

--創建調度(使用后面專門定義的幾種作業調度模板)
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=0x8,       --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval=1,     --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--添加目標服務器
DECLARE @servername sysname
SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))--當前SQL實例
EXEC msdb.dbo.sp_add_jobserver 
        @job_id = @jobid,
        @server_name = @servername 

-----------------------------------------------------------------------------------------------
--調度模板定義 sp_add_jobschedule

--只執行一次的作業調度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=1,                --僅執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_start_time = 00000   --作業執行的開始時間,格式為HHMMSS

--日調度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱',
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天發生一次,這里是1天.
        @freq_subday_type=0x8,       --重復方式,(0x1=指定的時間;0x4=多少分鍾;0x8=多少小時)執行一次
        @freq_subday_interval=1,     --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--周調度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 8,              --每周
        @freq_recurrence_factor = 1, --每多少周執行一次,這里是每周
        @freq_interval = 62,         --在星期幾執行,由POWER(2,N)表示,N的值為0~6,代表星期日~星期六,如果指定兩個,則將值相加,例如,值為65表示在星期天和星期日執行(POWER(2,0)+POWER(2,6))
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--月調度(每X個月的每月幾號)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 16,             --每月
        @freq_recurrence_factor = 2, --每多少月執行一次,這里是每2個月
        @freq_interval = 2,          --在執行月的第幾天執行,這里是第2天
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--月調度(每X個月的相對時間)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 32,             --每月
        @freq_recurrence_factor = 2, --每多少月執行一次,這里是每2個月
        @freq_interval = 9,          --在當月的那個時間執行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末
        @freq_relative_interval = 1, --在第幾個相對時間執行,允許的值為1,2,4,8代表第1~4個相對時間,16表示最后一個相對時間
        @freq_subday_type = 0x8,     --重復方式,0x1=在指定的時間,0x4=多少分鍾,0x8=多少小時執行一次
        @freq_subday_interval = 1,   --重復周期數,這里每小時執行一次
        @active_start_date = NULL,   --作業執行的開始日期,為NULL時表示當前日期,格式為YYYYMMDD
        @active_end_date = 99991231, --作業執行的停止日期,默認為99991231,格式為YYYYMMDD
        @active_start_time = 00000, --作業執行的開始時間,格式為HHMMSS
        @active_end_time = 235959    --作業執行的停止時間,格式為HHMMSS

--在特定時候執行的作業調度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N'調度名稱', 
        @freq_type = 64     --64=在SQLServerAgent 服務啟動時運行,128=計算機空閑時運行

-----------------------------------------------------------------------------------------------

IF EXISTS (SELECT * FROM DBO.SYSOBJECTS WHERE ID = OBJECT_ID(N'[DBO].SP_AUTO_CREATEJOB') AND OBJECTPROPERTY(ID, N'ISPROCEDURE') = 1)
DROP PROCEDURE [DBO].SP_AUTO_CREATEJOB
GO

CREATE PROCEDURE DBO.SP_AUTO_CREATEJOB
                        @DBNAME VARCHAR(100),    --執行數據庫   
                        @JOBNAME VARCHAR(100),     
                        @EXECSQL NVARCHAR(4000)    --執行語句      
AS     
PRINT '----作業 :'+@JOBNAME
PRINT '----開始執行:'  +@EXECSQL

BEGIN TRANSACTION   
DECLARE   
    @JOBID UNIQUEIDENTIFIER,       
    @RETURNCODE INT    
    SELECT @RETURNCODE = 0              
BEGIN         
    IF  EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =@JOBNAME) 
    EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=@JOBNAME 
          
    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOB        --返回值:0成功,1失敗
                        @JOB_NAME = @JOBNAME,            
                        @ENABLED = 1,                --狀態。默認值為 1（啟用）,為 0 不啟用
                        @OWNER_LOGIN_NAME = 'SA',    --擁有作業的登錄名。默認值為 NULL,可解釋為當前登錄名
                        @JOB_ID = @JOBID OUTPUT                    
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK  
                   
    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSTEP 
                        @JOB_ID = @JOBID,              
                        @STEP_NAME = N'STEP1',        --步驟名稱   
                        @SUBSYSTEM = 'TSQL',        --步驟的類型,一般為TSQL         
                        @DATABASE_NAME = @DBNAME,    --執行數據庫              
                        @COMMAND = @EXECSQL            --執行語句             
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK     
                 
    EXECUTE @RETURNCODE = MSDB.DBO.SP_UPDATE_JOB 
                        @JOB_ID = @JOBID,               
                        @START_STEP_ID = 1            --作業中要執行的第一個步驟的標識號
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK 
                           
    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSERVER 
                        @JOB_ID = @JOBID,                   
                        @SERVER_NAME = N'(LOCAL)'                         
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK    
        
END 
COMMIT TRANSACTION  
   
GOTO ENDSAVE  
                      
QUITWITHROLLBACK:         
    IF (@@TRANCOUNT > 0)   
    BEGIN        
        ROLLBACK TRANSACTION        
        RETURN 1  
    END   
       
ENDSAVE:       
EXEC @RETURNCODE = MSDB.DBO.SP_START_JOB @JOB_ID = @JOBID  --啟動作業 
RETURN @RETURNCODE