sqlserver字符串合並(merge)方法匯總

--方法1
--使用游標法進行字符串合並處理的示例。
--處理的數據
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3

--合並處理
--定義結果集表變量
DECLARE @t TABLE(col1 varchar(10),col2 varchar(100))

--定義游標並進行合並處理
DECLARE tb CURSOR LOCAL
FOR
SELECT col1,col2 FROM tb ORDER BY  col1,col2
DECLARE @col1_old varchar(10),@col1 varchar(10),@col2 int,@s varchar(100)
OPEN tb
FETCH tb INTO @col1,@col2
SELECT @col1_old=@col1,@s=''
WHILE @@FETCH_STATUS=0
BEGIN
 IF @col1=@col1_old
  SELECT @s=@s+','+CAST(@col2 as varchar)
 ELSE
 BEGIN
  INSERT @t VALUES(@col1_old,STUFF(@s,1,1,''))
  SELECT @s=','+CAST(@col2 as varchar),@col1_old=@col1
 END
 FETCH tb INTO @col1,@col2
END
INSERT @t VALUES(@col1_old,STUFF(@s,1,1,''))
CLOSE tb
DEALLOCATE tb
--顯示結果並刪除測試數據
SELECT * FROM @t
DROP TABLE tb
/*--結果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
GO

 

--方法2
--使用用戶定義函數，配合SELECT處理完成字符串合並處理的示例
--處理的數據
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3
GO

--合並處理函數
CREATE FUNCTION dbo.f_str(@col1 varchar(10))
RETURNS varchar(100)
AS
BEGIN
 DECLARE @re varchar(100)
 SET @re=''
 SELECT @re=@re+','+CAST(col2 as varchar)
 FROM tb
 WHERE col1=@col1
 RETURN(STUFF(@re,1,1,''))
END
GO

--調用函數
SELECT col1,col2=dbo.f_str(col1) FROM tb GROUP BY col1
--刪除測試
DROP TABLE tb
DROP FUNCTION f_str
/*--結果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
GO

 

--方法3
--使用臨時表實現字符串合並處理的示例
--處理的數據
CREATE TABLE tb(col1 varchar(10),col2 int)
INSERT tb SELECT 'a',1
UNION ALL SELECT 'a',2
UNION ALL SELECT 'b',1
UNION ALL SELECT 'b',2
UNION ALL SELECT 'b',3

--合並處理
SELECT col1,col2=CAST(col2 as varchar(100)) 
INTO #t FROM tb
ORDER BY col1,col2
DECLARE @col1 varchar(10),@col2 varchar(100)
UPDATE #t SET 
 @col2=CASE WHEN @col1=col1 THEN @col2+','+col2 ELSE col2 END,
 @col1=col1,
 col2=@col2
SELECT * FROM #t
/*--更新處理后的臨時表
col1       col2
---------- -------------
a          1
a          1,2
b          1
b          1,2
b          1,2,3
--*/
--得到最終結果
SELECT col1,col2=MAX(col2) FROM #t GROUP BY col1
/*--結果
col1       col2
---------- -----------
a          1,2
b          1,2,3
--*/
--刪除測試
DROP TABLE tb,#t
GO