使用觸發器實現記錄oracle用戶登錄失敗信息到alert.log日志文件

前面我們說了用oracle自帶的審計功能可以實現記錄用戶登錄失敗日志到數據表中（鏈接：http://www.54ok.cn/6778.html）。今天我們來分享一下如何把用戶登錄失敗信息記錄到alert.log日志文件中。

 

使用sys賬號登錄數據庫，然后創建觸發器。

 

CREATE OR REPLACE TRIGGER logon_denied_to_alert
  AFTER servererror ON DATABASE
DECLARE
  message   VARCHAR2(168);
  ip        VARCHAR2(15);
  v_os_user VARCHAR2(80);
  v_module  VARCHAR2(50);
  v_action  VARCHAR2(50);
  v_pid     VARCHAR2(10);
  v_sid     NUMBER;
  v_program VARCHAR2(48);
BEGIN
  IF (ora_is_servererror(1017)) THEN

    -- get ip FOR remote connections :
    IF upper(sys_context('userenv', 'network_protocol')) = 'TCP' THEN
      ip := sys_context('userenv', 'ip_address');
    END IF;

    SELECT sid INTO v_sid FROM sys.v_$mystat WHERE rownum < 2;
    SELECT p.spid, v.program
      INTO v_pid, v_program
      FROM v$process p, v$session v
     WHERE p.addr = v.paddr
       AND v.sid = v_sid;

    v_os_user := sys_context('userenv', 'os_user');
    dbms_application_info.read_module(v_module, v_action);

    message := to_char(SYSDATE, 'YYYYMMDD HH24MISS') ||
               ' logon denied from ' || nvl(ip, 'localhost') || ' ' ||
               v_pid || ' ' || v_os_user || ' with ' || v_program || ' – ' ||
               v_module || ' ' || v_action;

    sys.dbms_system.ksdwrt(2, message);

  END IF;
END;

 

嘗試使用錯誤的賬號密碼登錄數據庫，然后在alert.log日志中就可以查到信息，但是這個日志信息比較簡單，只記錄了時間，ip和使用的客戶端工具，並沒有記錄登錄的賬號是多少。因此對比起審計功能來說稍微差點。