bat完美關機命令

@echo off
title OLIVER-COMPUTER
mode con cols=46 lines=24
color 0d
shutdown /a >nul 2>nul
ver > %temp%\ver.temp
find /i " 5.2" %temp%\ver.temp > nul && set shutdowntime=600&& goto start
set shutdowntime=526509812
:start
cls 
set choice=
echo    　 　　　   \\\ATA///     %date%
echo 　　   　　   \\　- -　//        %time:~0,8%
echo  　　   　　 　 (　@ @　)
echo     ┏━━━oOOo━━(_)━━oOOo━━━━┓
echo     ╀                                    ╀
echo    A◎ 1.今天你關了嗎？    　　        ◎ 
echo    A◎   2.趕快快快重啟啦！            ◎
echo    A◎     3.來個定時怎么樣？          ◎
rem echo    A◎   4.計划關機!（盡請期待）   ◎
echo     ╁                         Oooo    ╁
echo     ┗━━━━━━━━oooO━━(   )━━┛
echo                       (   )    ) / 
echo                        \ (    (_/ 
echo                         \_)
set /p choice=...說吧，想做什么操作，就在這兒輸入:
If "%choice%" equ "1" goto gj 
If "%choice%" equ "2" goto cq
If "%choice%" equ "3" goto ds
If "%choice%" equ "4" goto jh
If "%choice%" equ "q" goto :eof
goto start
:gj
echo.
echo .....確定立刻關機嗎?？?直接按下Enter
set /p choice=.......想反悔的話，也行，輸入N:
if  /i "%choice%" equ "n" ( goto start ) else (shutdown /s /t 0)
echo.
goto end
:cq
echo.
echo .....確定立刻重啟嗎?？?直接按下Enter
set /p choice=.......想反悔的話，也行，輸入N:
if  /i "%choice%" equ "n" ( goto start ) else (shutdown /r /t 0)
echo.
goto end
:ds
set shijian=
set /p shijian=.....恁就寫上關機時間吧（秒為單位）:
if "%shijian%" equ "" goto start
set tempzhi=%shijian%
:yanzheng
set zhi=%tempzhi:~0,1%
if "%zhi%" equ "0" goto quzhi
if "%zhi%" equ "1" goto quzhi
if "%zhi%" equ "2" goto quzhi
if "%zhi%" equ "3" goto quzhi
if "%zhi%" equ "4" goto quzhi
if "%zhi%" equ "5" goto quzhi
if "%zhi%" equ "6" goto quzhi
if "%zhi%" equ "7" goto quzhi
if "%zhi%" equ "8" goto quzhi
if "%zhi%" equ "9" goto quzhi
echo.
echo ЖЖЖ輸入內容含有非法字符串，請從新輸入ЖЖЖ
pause > nul
goto start
:quzhi
set tempzhi=%tempzhi:~1%
if "%tempzhi%" == "" goto jixu
goto yanzheng
:jixu
if %shijian% leq %shutdowntime% (
        shutdown /s /t %shijian% /c 我屮，得狠了吧，說關就關你!!!
) else (
        echo.
        echo    ЖЖЖ你輸入的關機時間超出電腦范圍ЖЖЖ
        echo         請輸入小於%shutdowntime%的數值
        pause>nul
        goto start
)
echo.
echo ¤¤¤電腦將在%shijian%秒后關機，抓緊了¤¤¤
echo.
echo .....確定關機時間了嗎???直接按下Enter
set /p choice=.......想反悔的話，也行，輸入N:
if /i "%choice%" equ "n" ( goto qx ) else ( goto end )
:jh
echo.
echo.
echo         計划關機暫未推出，請敬請關注！
echo                 ... ...
pause > nul
goto start
:qx
cls
shutdown /a > nul 2>nul
set choice=
echo     　 　　　                    %time%
echo.
echo    1.額知到錯了，再也不敢關機了，繞了我吧？
echo.
echo  2.哥只是失誤，最近眼睛不太好使了，時間瞧錯了
echo.
echo    3.我原來是想重啟來，冤這電腦不按套路出牌
echo.
echo      4.太慢了，我要立馬關機里，不玩了...
echo.
echo.
echo    又反悔了吧？就你這臭脾氣，深度鄙視你！！！
set /p choice=瞧見了沒？上面有的后悔葯讓你選，自己看着辦：
echo.
if "%choice%" equ "" goto qx
if "%choice%" equ "1" goto start 
if "%choice%" equ "2" goto ds
if "%choice%" equ "3" goto cq
if "%choice%" equ "4" goto gj
if "%choice%" equ "q" goto :eof
:end
echo.
echo                  Good Bye!!!
echo                                    %date%
pause>nul

這是一個比較個性化的關機腳本。

把上述的代碼粘貼復制到新建的“關機.bat”腳本中，然后雙擊執行即可。