sql server 調用webservice


sql server版本2008以上,應該都可以

更改服務器配置

sp_configure 'show advanced options', 1;
GO
RECONFIGURE;
GO
sp_configure 'Ole Automation Procedures', 1;
GO
RECONFIGURE;
GO

sql 代碼:

declare @ServiceUrl as varchar(1000) 
declare @UrlAddress varchar(500)

--WebService地址:以http開頭,結尾帶斜杠,例如'http://www.webxml.com.cn/webservices/qqOnlineWebService.asmx/' 
set @UrlAddress = 'http://www.webxml.com.cn/webservices/qqOnlineWebService.asmx/'

declare @FunName varchar(50)
--WebService中調用的方法名:例如'qqCheckOnline'
set @FunName = 'qqCheckOnline'   

--以下參數對應WebService中參數的[參數名]
declare @P1 varchar(800),@P2 varchar(100)
set @P1 = 'qqCode'
--set @P2 = 'userid'

declare @P1_Value varchar(100),@P2_Value varchar(100)
set @P1_Value = '8698053'
--set @P2_Value = ''

set @ServiceUrl = @UrlAddress + @FunName + '?' + @P1 + '=' + @P1_Value --+'&' + @P2 + '=' + @P2_Value                       
                  
Declare @Object as Int
Declare @ResponseText as Varchar(8000)
                  
--創建 OLE 對象的實例。
--sp_OACreate { progid | clsid } , objecttoken OUTPUT [ , context ] 
--返回的對象令牌,並且必須是數據類型為 int 的局部變量。 該對象令牌用於標識所創建的 OLE 對象,並用於調用其他 OLE 自動化存儲過程。
Exec sp_OACreate 'MSXML2.XMLHTTP', @Object OUT;
--sp_OAMethod   調用一個 OLE 對象的方法。
Exec sp_OAMethod @Object, 'open', NULL, 'get',@ServiceUrl,'false'
Exec sp_OAMethod @Object, 'send'
Exec sp_OAMethod @Object, 'responseText', @ResponseText OUTPUT
     
Select @ResponseText     
Exec sp_OADestroy @Object  --破壞已創建的 OLE 對象。--如果未調用 sp_OADestroy,則在批處理結束時將自動破壞已創建的 OLE 對象。
--當不再需要對象時,調用 sp_OADestroy 釋放使用 sp_OACreate 創建的對象實例。
GO

 


免責聲明!

本站轉載的文章為個人學習借鑒使用,本站對版權不負任何法律責任。如果侵犯了您的隱私權益,請聯系本站郵箱yoyou2525@163.com刪除。



 
粵ICP備18138465號   © 2018-2025 CODEPRJ.COM