批處理集錦——(6)【轉】批處理實現全盤搜索指定文件獲取其完整路徑方法大全

【方案一】for /f + dir

@echo off
rem 指定待搜索的文件
set "FileName=string.bat"

echo 正在搜索，請稍候...

for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  
  if exist %%a:\ (
  
        for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (

        if /i "%%~nxb" equ "%FileName%" (
            echo,%%b
        )
      
    )
    
  )
  
)

【方案二】for /r（比 for /f + dir 效率高，但不會遍歷隱藏文件）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 if exist %%a:\ (
  pushd %%a:\
  for /r %%b in (*%FileName%) do (
   if /i "%%~nxb" equ "%FileName%" (
    echo,%%b
   )
  )
  popd
 )
)

【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精簡版可能不支持）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in ("%FileName%") do (
 set "nName=%%~na"
 set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
 echo,%%a
)

【方案四】使用 Windows7 系統自帶的 where 命令

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 if exist %%a:\ (
  for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
   if /i "%%~nxb" equ "%FileName%" (
    echo,%%b
   )
  )
 )
)

出處:http://www.jb51.net/article/54791.htm