模擬實現SQL Server中的datepart(week,date)的功能

本文目錄列表：

1、為什么要模擬實現datepart(week,date)的功能

2、具體實現思路

3、T-SQL代碼實現邏輯

4、總結語

5、參考清單列表

 

1、為什么要模擬實現datepart(week,date)的功能

 

在 SQL Server時間粒度系列----第2節日期、周時間粒度詳解這篇博文中，就有個函數ufn_WeekOfYear----就是用了datepart(week,date)來實現獲取，不過該函數是依賴@@datefirst這個全局變量值的，SQL Server 默認這個值時7（美國的習慣，周日作為一周的第一天），而我們中國則是周一作為一周的第一天的。后來在 SQL Server時間粒度系列----第7節日歷數據表詳解這篇博文中，依然重新實現了ufn_WeekOfYear，當時沒有充分的測試，現在發現也是存在bug的。后來又看到BIWork的這篇博文---- SQL Server - 把星期一(周一)當作每個星期的開始在一年中求取周數 ，這才思考許久才重新實現類似datepart(week,date)的功能函數。

 

SQL Server提供的datepart(week,date)這個函數是依賴@@datefirst這個全局變量值的，由於不同的區域每周的第一天有所不同的，但是@@datefirst不能再函數中重新修改值（其實通過set datefirst num來修改的），這個是很大的不方面的，為了靈活地獲取指定日期所在當前年的星期索引數值(索引數值從1開始計數，依次為1、2、……、51、52、53、54，下同），請繼續往下看。

 

 

2 、具體實現思路

 

由於知道了datepart(week,date)和@@datefirst的依賴關系以及其存在的不方便，將@@datefirst的值以一個參數的形式出現，這樣就可以動態的設定一周的第一天啦。再加上指定的日期以及一周第一天索引數值（索引數值從1開始計數，依次為1、2、……、7，分別對應周一、周二、……、周日，例如：一周第一天索引值為1，即周一是一周的第一天）這兩個參數來實現模擬datepart(week,date)函數的功能，具體思路大致分為如下步驟：

1)、獲取指定日期所在當前年的第一天。

2)、獲取指定日期所在當前周的日索引數值（索引數值從1開始計數，依次為1、2、……、7，分別對應周一、周二、……、周日）。

3)、獲取指定日期和一周第一天索引值來獲得當前年的第一周的第一天。

4）、指定日期、當前年的第一天和當前年的第一周的第一天這三個日期進行邏輯判斷如下：

4.1)、指定日期大於等於當前年的第一天且小於當前年的第一周的第一天時，當前年的星期索引數值為1。

4.2)、4.1的否定為邏輯真時，先通過當前年的星期索引數值默認值為1在加上當前年的第一天與當前的第一周的第一天的日期天差除以7的值，然后通過當前年的第一天小於當前年的第一周的第一天時，將上邊的結果值在加上1，否則上邊的結果值就是當前年的星期索引數值。

 

可能以上文字表述具體的思路有些不太清楚，那就請繼續看下面的T-SQL代碼實現。

 

3、T-SQL代碼實現邏輯以及測試效果

 

根據以上具體的思路，根據T-SQL語言來進行一種實現，T-SQL代碼實現路基如下：

IF OBJECT_ID(N'dbo.ufn_FirstDayOfYear', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_FirstDayOfYear;
END
GO
 
--==================================
-- 功能：獲取指定日期所在當前年的第一天
-- 說明：具體功能說明
-- 兼容：運行SQL Server 2005+
-- 創建：2016-07-06 09:00-09:05 劍走江湖 創建實現
-- 修改：yyyy-MM-dd hh:mm-hh:mm XXX 修改內容描述
--==================================
CREATE FUNCTION dbo.ufn_FirstDayOfYear
(
    @dtmDate AS DATETIME    --指定日期
) RETURNS DATETIME
AS
BEGIN
    RETURN DATEADD(YEAR, DATEDIFF(YEAR, 0, @dtmDate), 0);
END
GO
 
IF OBJECT_ID(N'dbo.ufn_FirstWeekFirstDayOfYear', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_FirstWeekFirstDayOfYear;
END
GO
 
--==================================
-- 功能：獲取指定日期所在當前年的第一周的第一天
-- 說明：可以通過參數@tntDateFirst動態指定一周開始的第一天，類似全局變量@@DATEFIRST的值且保持一致
-- 兼容：運行SQL Server 2005+
-- 創建：2016-07-06 09:05-09:15 劍走江湖 創建實現
-- 修改：yyyy-MM-dd hh:mm-hh:mm XXX 修改內容描述
--==================================
CREATE FUNCTION dbo.ufn_FirstWeekFirstDayOfYear
(
    @dtmDate AS DATETIME                --指定日期
    ,@tntDateFirst AS TINYINT = 1        --第一天日期（從1、2、3、……、7分別對應周一、周二、周三、……、周日)
) RETURNS DATETIME
AS
BEGIN
    IF (@tntDateFirst IS NULL OR @tntDateFirst = 0 OR @tntDateFirst NOT BETWEEN 1 AND 7)
    BEGIN
        SET @tntDateFirst = 1;
    END
 
    DECLARE @dtmFirstWeekFirstDayOfYear AS DATETIME;
    SET @dtmFirstWeekFirstDayOfYear = 0;
 
    DECLARE
         @dtmFirstDayOfYear AS DATETIME
        ,@dtmStartDate AS DATETIME        
        ,@dtmEndDate AS DATETIME;
    SELECT
         @dtmFirstDayOfYear = [dbo].[ufn_FirstDayOfYear](@dtmDate)
        ,@dtmStartDate = @dtmFirstDayOfYear
        ,@dtmEndDate = DATEADD(DAY, 7, @dtmStartDate);
 
    WHILE (@dtmStartDate <= @dtmEndDate)
    BEGIN
        IF ([dbo].[ufn_DayOfWeek](@dtmStartDate) = @tntDateFirst)
        BEGIN
            SET @dtmFirstWeekFirstDayOfYear = @dtmStartDate;
 
            BREAK;
        END
 
        SET @dtmStartDate = DATEADD(DAY, 1, @dtmStartDate);
    END    
 
    RETURN @dtmFirstWeekFirstDayOfYear;
END
GO
 
IF OBJECT_ID(N'dbo.ufn_DayOfWeek', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_DayOfWeek;
END
GO
 
--==================================
-- 功能: 獲取指定日期時間的所在當前周的日索引值（索引值從1開始計數，依次為1、2、……、7）
-- 說明: 運行在SQL Server 2005+。
--       結果值從1到7，分別對應從周一到周日，該值與@@DATEFISRT配置函數值保持一致。
--       使用(@@datefirst + datepart(weekday, @dtmDate))%7的結果值從2、3、4、5、6、0、1
--       分別對應周一、周二、周三、周四、周五、周六、周日。
-- 兼容：運行SQL Server 2005+
-- 創建：2016-01-02 hh:mm-hh:mm 劍走江湖 創建實現
-- 修改：yyyy-MM-dd hh:mm-hh:mm XXX 修改內容描述
-- 調用： SELECT dbo.ufn_DayOfWeek('2017-01-07') -- 4（表示星期四）
--==================================
CREATE FUNCTION dbo.ufn_DayOfWeek
(
    @dtmDate AS DATETIME                -- 指定的日期時間
) RETURNS TINYINT
    --$Encode$--
BEGIN
    DECLARE @tntRemainder AS TINYINT;
    SET @tntRemainder = (@@DATEFIRST + DATEPART(WEEKDAY, @dtmDate)) % 7;   
 
    RETURN (CASE WHEN @tntRemainder <= 1 THEN @tntRemainder + 6 ELSE @tntRemainder - 1 END);
END
GO
 
IF OBJECT_ID(N'dbo.ufn_WeekOfYear', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_WeekOfYear;
END
GO
 
--==================================
-- 功能：獲取指定日期所在當前年的星期索引值(索引值從1開始計數，依次為1、2、……、51、52、53、54）
-- 說明：具體功能說明
-- 兼容：運行SQL Server 2005+
-- 創建：2016-07-06 09:15-09:35 劍走江湖 創建實現
-- 修改：yyyy-MM-dd hh:mm-hh:mm XXX 修改內容描述
--==================================
CREATE FUNCTION dbo.ufn_WeekOfYear
(
    @dtmDate AS DATETIME            --指定日期
    ,@tntDateFirst AS TINYINT = 1    --第一天日期（從1、2、3、……、7分別對應周一、周二、周三、……、周日)        
) RETURNS TINYINT
AS
BEGIN
    DECLARE @tntWeekOfYear AS TINYINT;
    SET @tntWeekOfYear = 1;
 
    DECLARE 
         @dtmFirstDayOfYear AS DATETIME
        ,@dtmFirstWeekFirstDayOfYear AS DATETIME;
    SELECT
         @dtmFirstDayOfYear = dbo.[ufn_FirstDayOfYear](@dtmDate)    
        ,@dtmFirstWeekFirstDayOfYear = dbo.[ufn_FirstWeekFirstDayOfYear](@dtmDate, @tntDateFirst);    
 
    IF NOT(@dtmDate >= @dtmFirstDayOfYear AND @dtmDate < @dtmFirstWeekFirstDayOfYear)
    BEGIN
        SET @tntWeekOfYear =  @tntWeekOfYear +  DATEDIFF(DAY, @dtmFirstWeekFirstDayOfYear, @dtmDate) / 7; 
 
        IF @dtmFirstDayOfYear < @dtmFirstWeekFirstDayOfYear
        BEGIN
            SET @tntWeekOfYear = @tntWeekOfYear + 1;
        END            
    END
 
    RETURN @tntWeekOfYear;
END
GO

 

測試代碼如下：

DECLARE
     @tntDateFirst    AS TINYINT
    ,@tntMaxDateFirst AS TINYINT
    ,@dtmStartDate    AS DATETIME
    ,@dtmEndDate      AS DATETIME;
SELECT
     @tntDateFirst    = 1
    ,@tntMaxDateFirst = 7
    ,@dtmStartDate    = '2000-01-01'
    ,@dtmEndDate      = '2000-01-07';
WHILE (@tntDateFirst <= @tntMaxDateFirst)
BEGIN
    SELECT 
        [T2].[FullDate]
       ,[T2].[DayOfWeek]
       ,[T2].[FirstWeekFirstDayOfYear]
       ,@tntDateFirst AS [FirstDateOfWeek]
       ,[T2].[WeekOfYear]
       ,COUNT(T2.[FullDate]) OVER (PARTITION BY YEAR(T2.[FullDate]), T2.[WeekOfYear]) AS DayCountOfWeek
       ,T2.[DefaultDayOfWeek]
       ,@@DATEFIRST AS [DefaultFirstDateOfWeek]
       ,[T2].[DefaultWeekOfYear]
       ,COUNT(T2.[FullDate]) OVER (PARTITION BY YEAR(T2.[FullDate]), T2.[DefaultWeekOfYear]) AS DefaultDayCountOfWeek
    FROM (
        SELECT 
             T.[FullDate]
            ,[dbo].[ufn_DayOfWeek](T.[FullDate]) AS [DayOfWeek]
            ,[dbo].[ufn_FirstWeekFirstDayOfYear](T.[FullDate], @tntDateFirst) AS [FirstWeekFirstDayOfYear]        
            ,[dbo].[ufn_WeekOfYear](T.[FullDate], @tntDateFirst) AS [WeekOfYear]
            ,DATEPART(WEEKDAY, T.[FullDate]) AS [DefaultDayOfWeek]
            ,DATEPART(WEEK, T.[FullDate]) AS [DefaultWeekOfYear]
        FROM (
            SELECT DATEADD(DAY, [Num], @dtmStartDate) AS FullDate
            FROM [dbo].[ufn_GetNums](0, DATEDIFF(DAY, @dtmStartDate, @dtmEndDate))
        ) AS T
    ) AS T2;
 
    SET @tntDateFirst = @tntDateFirst + 1;
END 
GO

 

以上測試效果如下圖：

 

4、總結語

 

由於我之前寫過幾個版本的ufn_WeekOfYear實現，但是通過博文發出去的有兩個版本的，直到看到BIWork的SQL Server - 把星期一(周一)當作每個星期的開始在一年中求取周數這篇博文才發現自己之前發布的兩個博文中的ufn_WeekOfYear是存在問題的，這才花費了不少時間再次梳理和思考這個功能的實現，都說變成代碼需要測試，T-SQL代碼一樣要嚴格的單元測試才行，不然真是迷惑了自己，也誤導了別人的。

  

5、參考清單列表

5.1、 DATEPART (Transact-SQL)

5.2、 SQL Server時間粒度系列----第2節日期、周時間粒度詳解

5.3、 SQL Server時間粒度系列----第7節日歷數據表詳解

5.4、 SQL Server - 把星期一(周一)當作每個星期的開始在一年中求取周數

5.5、 SQL Server數字輔助表的實現