SqlServer 筆記二 獲取漢字的拼音首字母

一、該函數傳入字符串，返回數據為：如果為漢字字符，返回該字符的首字母，如果為非漢字字符，則返回本身。

二、用到的知識點：漢字對應的UNICODE值，漢字的排序規則。

三、數據庫函數：

CREATE FUNCTION GetInitialLetter(@ChineseString NVARCHAR(4000)) 
RETURNS NVARCHAR(4000) 
AS
BEGIN
 
DECLARE @SingleCharacter NCHAR(1),
@ReturnString NVARCHAR(4000) 
SET @ReturnString = '' 

WHILE LEN(@ChineseString)>0 
BEGIN

--依次取單個字符
SET @SingleCharacter = LEFT(@ChineseString,1) 

----漢字字符，返回字符對應首字母,非漢字字符,返回原字符
IF(UNICODE(@SingleCharacter) BETWEEN 19968 AND 19968+20901)
SET @ReturnString = @ReturnString + 
(SELECT TOP 1 PY FROM
(SELECT 'A' AS PY,N'驁' AS ChineseCharacters 
UNION All SELECT 'B',N'簿' 
UNION All SELECT 'C',N'錯' 
UNION All SELECT 'D',N'鵽' 
UNION All SELECT 'E',N'樲' 
UNION All SELECT 'F',N'鰒' 
UNION All SELECT 'G',N'腂' 
UNION All SELECT 'H',N'夻' 
UNION All SELECT 'J',N'攈' 
UNION All SELECT 'K',N'穒' 
UNION All SELECT 'L',N'鱳' 
UNION All SELECT 'M',N'旀' 
UNION All SELECT 'N',N'桛' 
UNION All SELECT 'O',N'漚' 
UNION All SELECT 'P',N'曝' 
UNION All SELECT 'Q',N'囕' 
UNION All SELECT 'R',N'鶸' 
UNION All SELECT 'S',N'蜶' 
UNION All SELECT 'T',N'籜' 
UNION All SELECT 'W',N'鶩' 
UNION All SELECT 'X',N'鑂' 
UNION All SELECT 'Y',N'韻' 
UNION All SELECT 'Z',N'咗' 
)SpellingTable 
where ChineseCharacters > = @SingleCharacter COLLATE Chinese_PRC_CS_AS_KS_WS 
ORDER by PY ASC)
ELSE
SET @ReturnString = @ReturnString + @SingleCharacter

 
SET @ChineseString = RIGHT(@ChineseString,LEN(@ChineseString)-1) 

END
 
RETURN @ReturnString 

END
GO

 

四、函數調用：

SELECT dbo.GetInitialLetter('中華人民共和國(1949 - 2016)')

返回：

ZHRMGHG(1949 - 2016)

 

后記說明：

1、unicode 字符是國際組織制定的可以容納世界上所有文字和符號的字符編碼方案，世界上的任何字符都有唯一對應的一組十六進制表示（例 ‘漢’：6C49），漢字對應的范圍轉換為十進制之后是：19968 - 40869.

2、臨時表 SpellingTable 字段 ChineseCharacters 中存儲的漢字，以對應的 PY 字段開頭的漢語拼音的最后一個漢字。 可查新華字典：http://xh.5156edu.com/pinyi.html