批處理-IF詳解

　　在CMD使用IF /?打開IF的系統幫助(自己看我就不全部列出來了),我們會發現IF有3種基本的用法!
　　　　IF [NOT] ERRORLEVEL number command
　　　　IF [NOT] string1==string2 command
　　　　IF [NOT] EXIST filename command

　　NOT 　　　　　　　　　　　把NOT理解為C/C++中的取反操作符，然后就可以理解為C/C++中的條件表達式執行
　　ERRORLEVEL number 　　如果最后運行的程序返回一個等於或大於指定數字的退出編碼，指定條件為 true。
　　string1==string2  　　　　如果指定的文字字符串匹配，指定條件為 true，批處理中只有==沒有!=，可以用NOT 條件表達式替代。
　　EXIST filename    　　　　 如果指定的文件名存在，指定條件為 true。
　　command           　　　　  如果符合條件，指定要執行的命令。如果指定的條件為 FALSE，命令后可跟一個執行 ELSE關鍵字后的命令的 ELSE 命令。

ELSE 子句必須出現在同一行上的 IF 之后。例如:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set file="C:\abc.bat"
if exist %file% (　　　　　　　　::注意這里else后的空格
　　echo file is exists
)else ( 　　　　　　　　　　 　　 ::注意這里else要和if的子句在同一行，並且else后要有空格
　　echo file is not exists
)

pause

第一種用法：IF [NOT] ERRORLEVEL number command
　　這個用法的基本做用是判斷上一條命令執行結果的代碼,以決定下一個步驟.一般上一條命令的執行結果代碼只有兩結果,"成功"用0表示  "失敗"用1表示.
舉例:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

copy C:\abc.bat E:\
if %ERRORLEVEl% == 0 (
    echo operation succ %ERRORLEVEl%
)else (
    echo operation fail %ERRORLEVEl%
)
pause

 @echo off
 Setlocal enabledelayedexpansion
 ::CODER BY dsw POWERD BY iBAT

 set /p var=隨便輸入一個命令
 %var%

 echo errorlevel is %ERRORLEVEL%

 if NOT %ERRORLEVEL% == 0 (
 　　echo !var!執行失敗
 ) else (
　　echo !var!執行成功
 )

 pause

　　%ERRORLEVEL% 這是個系統變量,返回上條命令的執行結果代碼! "成功"用0表示  "失敗"用1表示.一般上一條命令的執行結果代碼只有兩結果,當然有的操作還有其他參數,這只是一般的情況。實際上，errorlevel返回值可以在0~255之間，比如，xcopy默認的errorlevel值就有5個，分別表示5種執行狀態：

如下所示：
　　0 文件復制沒有錯誤。
　　1 if errorlevel 2 echo。
　　2 用戶按 CTRL+C 終止了 xcopy。
　　4 出現了初始化錯誤。沒有足夠的內存或磁盤空間，或命令行上輸入了無效的驅動器名稱或語法。
　　5 出現了磁盤寫入錯誤。

要判斷上面xcopy命令的5種退出情況，應寫如下判斷成才能正確執行：
　　if errorlevel 5 echo出現了磁盤寫入錯誤
　　if errorlevel 4 echo出現了初始化錯誤
　　if errorlevel 2 echo用戶按 CTRL+C 終止了 xcopy
　　if errorlevel 1 echo if errorlevel 2 echo
　　if errorlevel 0 echo文件復制沒有錯誤。

再舉幾個例子

這個是根據你輸入的命令,自動判斷是成功還是失敗了!

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var=隨便輸入一個命令
%var%

::等價於if %ERRORLEVEL% == 0 (echo !var!執行成功了) ELSE (echo !var!執行失敗了!)
if %ERRORLEVEL% == 0 (
    echo !var!執行成功
) else (
    echo !var!執行失敗
)

pause

這里介紹的兩種簡寫對IF的三種語法都可以套用,不單單是在IF [NOT] ERRORLEVEL number command這種法上才能用

第二種用法：IF [NOT] string1==string2 command

這個呢就是用來比較變量或者字符的值是不是相等的.

例子

 @echo off
 Setlocal enabledelayedexpansion
 ::CODER BY dsw POWERD BY iBAT

 set /p var1="請輸入一個字符串："
 set /p var2="請輸入一個字符串："

 if %var1% == %var2% ( echo var1 eque var2) else (echo var1 not eque var2)
 if NOT %var1% == %var2% ( echo var1 not eque var2) else (echo var1 eque var2)

 pause

　　上面這個例子可以判斷你輸入的值是不是相等,但是你如果輸入相同的字符,但是如果其中一個后面打了一個空格,這個例子還是會認為相等,如何讓有空格的輸入不相等呢?我們在比較字符上加個雙引號就可以了.

 

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var1="請輸入一個字符串："
set /p var2="請輸入一個字符串：(加個空格試試)"

if "%var1%" == "%var2%" ( echo var1 eque var2) else (echo var1 not eque var2)
if NOT "%var1%" == "%var2%" ( echo var1 not eque var2) else (echo var1 eque var2)

pause

 

 

第三種用法：IF [NOT] EXIST filename command

這個就是判斷某個文件或者文件夾是否存在的語法

例子

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set file="C:\abc.bat"
if exist %file% (            ::注意這里else后的空格
    echo file is exists
)else (                      ::注意這里else要和if在同一行，並且else后要有空格
    echo file is not exists
)

判斷的文件路徑加引號是為了防止路徑有空格,如果路徑有空格加個雙引號就不會出現判斷出錯了!

 

第四種用法：IF增強的用法

  IF [/I] string1 compare-op string2 command #參數/I表示不區分大小寫
  IF CMDEXTVERSION number command
  IF DEFINED variable command   　　　　　　 #判斷變量是否存在，很有用

　　CMDEXTVERSION 條件的作用跟 ERRORLEVEL 的一樣，除了它是在跟與命令擴展名有關聯的內部版本號比較。第一個版本是 1。每次對命令擴展名有相當大的增強時，版本號會增加一個。命令擴展名被停用時，CMDEXTVERSION 條件不是真的。

如果已定義環境變量，DEFINED 條件的作用跟 EXISTS 的一樣，下面兩條命令效果一樣。
　　IF DEFINED variable command
　　IF NOT "variable"=="" command

用“set variable=”命令使變量variable變成未定義，即空值，一句話，變量值為空，則為未定義；變量值不為空，則為已定義。
用語句IF DEFINED variable command判斷變量是否存在時，請注意variable為不使用引導符號%的變量名，不能用寫為%variable%，否則出錯。

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

  set a=10
  if DEFINED a (echo l hava define) else (echo l don't define)
  set a=
  if DEFINED a (echo l hava define) else (echo l don't define)

pause

輸出：

  l hava define
  l don't define

最后面還有一些用來判斷數字的符號:
    EQU - 等於
    NEQ - 不等於
    LSS - 小於
    LEQ - 小於或等於
    GTR - 大於
    GEQ - 大於或等於

我就舉一個例子,大家都懂數學...不講多了

 

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var=請輸入一個數字:

if %var% LEQ  4 (echo 我小於等於4) ELSE echo 我不小於等於4

pause