salesforce 零基礎開發入門學習（八）數據分頁簡單制作

本篇介紹通過使用VF自帶標簽和Apex實現簡單的數據翻頁功能。

代碼上來之前首先簡單介紹一下本篇用到的主要知識：

1.ApexPages命名空間

此命名空間下的類用於VF的控制。

主要的類包括但不限於以下：

• ApexPages.StandardController:當為一個標准Controller定義擴展的時候使用此類。StandardController對象為Salesforce提供的預構建VF的控制器對象引用;
• ApexPages.Action:使用Action類和方法用於VF自定義控制器和擴展中，實現前后台交互;
• ApexPages.Message:可以使用此類將信息傳遞到前台顯示，常用於顯示異常信息（系統異常or自定義異常）;

2.PageReference類

　　PageReference類位於System命名空間下，用於一個實例化頁面的引用。他的作用為可以通過方法將結果導航到其他頁面，可以視圖。

3.基礎知識（當我沒說）

　　如果此部分掌握不好，請移步官方PDF文檔，先好好鑽研一下基礎知識。畢竟基礎還是最重要的。

　　注：上述只是介紹較為常用的內容，如果需要深入了解關於前后台交互的內容，請詳細查閱官方PDF，掌握好ApexPages以及Controller等等之間的關系及交互。

廢話少說，上代碼，以Goods表為例，前幾篇有過介紹，這里只是說一下里面的field主要內容：

GoodsName__c, GoodsType__c, GoodsBrands__c, GoodsPrice__c。

public class CategoryWrapper {
    public Boolean checked{ get; set; }
    public GOODS__c goods { get; set;}

    public CategoryWrapper(){
        goods = new GOODS__c();
        checked = false;
    }

    public CategoryWrapper(GOODS__c goods){
        this.goods = goods;
        checked = false;
    }
}

CategoryWrapper類有兩個變量，一個為Goods對象，用來獲取商品基本信息，一個為布爾類型的checked，用來作為判斷數據行是否被選的屬性。

public with sharing class PagingController {

    List<categoryWrapper> categories {get;set;}

    // instantiate the StandardSetController from a query locator
    public ApexPages.StandardSetController con {
        get {
            if(con == null) {
                con = new ApexPages.StandardSetController(Database.getQueryLocator([SELECT  GOODSBRAND__c,GOODSDESCRIBE__c,GOODSNAME__c, GOODSTYPE__c, GoodsPrice__c, IsStatus__c, Id FROM GOODS__c limit 100]));
                // sets the number of records in each page set
                con.setPageSize(20);
            }
            return con;
        }
        set;
    }

    // returns a list of wrapper objects for the sObjects in the current page set
    public List<categoryWrapper> getCategories() {
        categories = new List<categoryWrapper>();
        for (GOODS__c category1 : (List<GOODS__c>)con.getRecords())
            categories.add(new CategoryWrapper(category1));

        return categories;
    }

    // displays the selected items
     public PageReference process() {
         for (CategoryWrapper cw : categories) {
             if (cw.checked)
                 ApexPages.addMessage(new ApexPages.message(ApexPages.severity.INFO,cw.goods.GOODSNAME__c));
         }
         return null;
     }

    // indicates whether there are more records after the current page set.
    public Boolean hasNext {
        get {
            return con.getHasNext();
        }
        set;
    }

    // indicates whether there are more records before the current page set.
    public Boolean hasPrevious {
        get {
            return con.getHasPrevious();
        }
        set;
    }

    // returns the page number of the current page set
    public Integer pageNumber {
        get {
            return con.getPageNumber();
        }
        set;
    }

    // returns the first page of records
     public void first() {
         con.first();
     }

     // returns the last page of records
     public void last() {
         con.last();
     }

     // returns the previous page of records
     public void previous() {
         con.previous();
     }

     // returns the next page of records
     public void next() {
         con.next();
     }

     // returns the PageReference of the original page, if known, or the home page.
     public void cancel() {
         con.cancel();
     }

}

使用StandardController控制頁面顯示的內容以及每頁顯示多少行數據，是否含有上一頁下一頁等等功能。通過PageReference作為當前頁面的引用，控制頁面數據。

<apex:page controller="PagingController">
    <apex:form >
        <apex:pageBlock title="Goods">

            <apex:pageBlockButtons location="top">
                <apex:commandButton action="{!process}" value="Selected" />
                <apex:commandButton action="{!cancel}" value="Cancel" />
            </apex:pageBlockButtons>
            <apex:pageMessages />

            <apex:pageBlockSection title="Goods -  Page {!pageNumber}" columns="1">
                <apex:pageBlockTable value="{!categories}" var="c">
                    <apex:column width="25px">
                        <apex:inputCheckbox value="{!c.checked}" />
                    </apex:column>
                    <apex:column value="{!c.goods.GoodsName__c}" headerValue="Name" />
                    <apex:column value="{!c.goods.GoodsType__c}" headerValue="type" />
                    <apex:column value="{!c.goods.GoodsBrand__c}" headerValue="brand" />
                    <apex:column value="{!c.goods.GoodsPrice__c}" headerValue="Price" />
                </apex:pageBlockTable>
            </apex:pageBlockSection>
        </apex:pageBlock>

        <apex:panelGrid columns="4">
            <apex:commandLink action="{!first}">First</apex:commandlink>
                <apex:commandLink action="{!previous}" rendered="{!hasPrevious}">Previous</apex:commandlink>
                    <apex:commandLink action="{!next}" rendered="{!hasNext}">Next</apex:commandlink>
                        <apex:commandLink action="{!last}">Last</apex:commandlink>
        </apex:panelGrid>

    </apex:form>
</apex:page>

頁面顯示樣式如下：

總結：本篇只是簡單的實現數據分頁功能，在真正項目中應該很少會有直接使用VF標簽和使用Apex接口配合實現分頁的（吐槽：自動忽略。。。因為VF的布局很丑），通常使用HTML的布局結合着Controller實現精美樣式， 不過可以通過本篇的內容了解ApexPage命名空間里的類和VF頁面的關系以及PageReference的用法和作用，如果內容有寫的錯誤的地方歡迎批評指正，如果有問題，請留言。