動態修改PE文件圖標（使用UpdateResource API函數）

PE文件的圖標存儲在資源文件中，而操作資源要用到的API函數就是UpdateResource
首先我們需要先了解一下ICO格式，參考資料：http://www.moon-soft.com/program/FORMAT/windows/icons.htm
ICO格式不復雜，就是由數據頭、數據目錄、數據三個部分組成

一個.ico文件中可能含有若干個圖標，我們需要將數據目錄和數據解析出來。簡單地寫了個單元

 

unit Icons;

interface

uses
  Winapi.Windows, System.SysUtils, System.Classes;

type

  { 用於ICO圖標文件 }

  TIconDirEntry = packed record
    bWidth: Byte;
    bHeight: Byte;
    bColorCount: Byte;
    bReserved: Byte;
    wPlanes: Word;
    wBitCount: Word;
    dwBytesInRes: DWORD;
    dwImageOffset: DWORD;
  end;
  PIconDirEntry = ^TIconDirEntry;

  TIconDir = packed record
    idReserved: Word;
    idType: Word;
    idCount: Word;
    idEntries: array [0..0] of TIconDirEntry;
  end;
  PIconDir = ^TIconDir;

  { 用於PE文件中的圖標 }

  TGroupIconDirEntry = packed record
    bWidth: Byte;
    bHeight: Byte;
    bColorCount: Byte;
    bReserved: Byte;
    wPlanes: Word;
    wBitCount: Word;
    dwBytesInRes: DWORD;
    nID: Word;
  end;

  TGroupIconDir = packed record
    idReserved: Word;
    idType: Word;
    idCount: Word;
    idEntries: array [0 .. 0] of TGroupIconDirEntry;
  end;
  PGroupIconDir = ^TGroupIconDir;

  { ICO圖標文件 }
  TIcoFile = class
  public
    IconStream: TMemoryStream;
    IconDir: PIconDir;
    IconDirSize: DWORD;

    constructor Create; overload;
    constructor Create(const FileName: string); overload;
    destructor Destroy; override;

    // 加載ICO數據
    procedure LoadFromFile(const FileName: string);
    procedure LoadFromStream(Stream: TStream);
  end;

implementation

{ TIcoFile }

constructor TIcoFile.Create;
begin
  IconStream := TMemoryStream.Create;
  IconDir := nil;
  IconDirSize := 0;
end;

constructor TIcoFile.Create(const FileName: string);
begin
  Create;
  LoadFromFile(FileName);
end;

destructor TIcoFile.Destroy;
begin
  FreeMem(IconDir);
  FreeAndNil(IconStream);
  inherited;
end;

procedure TIcoFile.LoadFromFile(const FileName: string);
var
  MS: TMemoryStream;
begin
  MS := TMemoryStream.Create;
  try
    MS.LoadFromFile(FileName);
    LoadFromStream(MS);
  finally
    FreeAndNil(MS);
  end;
end;

procedure TIcoFile.LoadFromStream(Stream: TStream);
var
  Dir: TIconDir;
begin
  Stream.Position := 0;
  IconStream.Clear;
  IconStream.CopyFrom(Stream, Stream.Size);

  IconStream.Position := 0;
  IconStream.ReadBuffer(Dir, SizeOf(Dir));

  FreeMem(IconDir);
  IconDirSize := SizeOf(TIconDirEntry) * (Dir.idCount - 1) + SizeOf(TIconDir);
  IconDir := AllocMem(IconDirSize);
  IconStream.Position := 0;
  IconStream.ReadBuffer(IconDir^, IconDirSize);
end;

end.

這里要注意一個問題，ICO文件中的TIconDirEntry結構和PE文件中的TGroupIconDirEntry結構是不同的
不同處在最后一個參數，ICO文件中表示的是圖像數據偏移地址，是DWORD類型。而PE文件中表示的是圖像數據的索引，是WORD類型，少了2個字節
替換圖標需要寫入2個部分：RT_GROUP_ICON 和 RT_ICON
RT_GROUP_ICON也就是ICO的數據頭部分，RT_ICON就是圖像數據部分了
數據部分直接寫入即可，不用轉換什么的。但是數據頭需要稍微處理一下，因為前面說了，這個替換過程是把ICO文件寫到PE文件中
而他們數據頭部分結構略有不同（PE文件中每個數據頭比起ICO數據頭要少2字節），只用把這里處理下就行了
最后寫個函數就可以替換PE文件圖標了

 

 

function TMainForm.UpdatePeIcon(IcoFile, PeFile: string): Boolean;
var
  Ico: TIcoFile;
  I: Integer;
  hRes: THandle;
  GroupIconDir: PGroupIconDir;
  GroupIconDirSize: DWORD;
  Data: TBytes;
begin
  Result := False;
  hRes := BeginUpdateResource(PChar(PeFile), False);
  if hRes <> 0 then
  begin
    Ico := TIcoFile.Create(IcoFile);
    // TGroupIconDirEntry結構要比TIconDirEntry結構少2字節
    GroupIconDirSize := Ico.IconDirSize - Ico.IconDir^.idCount * 2;
    GroupIconDir := AllocMem(GroupIconDirSize);
    GroupIconDir^.idReserved := 0;
    GroupIconDir^.idType := 1;
    GroupIconDir^.idCount := Ico.IconDir.idCount;

    for I := 0 to Ico.IconDir.idCount - 1 do
    begin
      CopyMemory(@GroupIconDir^.idEntries[I], @Ico.IconDir^.idEntries[I],
        SizeOf(TGroupIconDirEntry));
      // 索引從1開始
      GroupIconDir^.idEntries[I].nID := I + 1;

      // 寫入圖標數據
      SetLength(Data, Ico.IconDir^.idEntries[I].dwBytesInRes);
      Ico.IconStream.Position := Ico.IconDir^.idEntries[I].dwImageOffset;
      Ico.IconStream.ReadBuffer(Data[0], Length(Data));

      UpdateResource(hRes, RT_ICON, MakeIntResource(I + 1), 0, @Data[0], Length(Data));
    end;

    // 寫入 RT_GROUP_ICON
    UpdateResource(hRes, RT_GROUP_ICON, MakeIntResource('MAINICON'), 0, GroupIconDir, GroupIconDirSize);

    FreeMem(GroupIconDir);
    FreeAndNil(Ico);
    EndUpdateResource(hRes, False);
    Result := True;
  end;
end;