前言：
前面放出過一次批處理，本次再放出一些比較有用的批處理(獲得當前包名、查看APP簽名信息等)，好長時沒來寫博客了，簡單化，請看正文，更多腳本盡請期待~~~（不定期）
目錄
1、[手機錄屏(安卓4.4以上)V1.0.bat]
@ECHO OFF
COLOR 0A
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
ECHO. :: ::
ECHO. :: 手機錄屏(安卓4.4及以上)V1.0 ::
ECHO. :: ::
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
:: ::::: 作者：Findyou :::: **************在此修改目錄**************************
:: ::::: 版本:V1.0 時間：2014.12.21 ::
:: ::::::::::::::::::::::::::::::::::::::::::::::::::::
SET pcDir=C:\Users\%username%\Pictures
SET phoneDir=/sdcard
::**************在此修改目錄**************************
:recordstart
ECHO.[ HELP ] 操作步驟：
ECHO. 1、輸入錄制時間[回車]
ECHO. 2、按提示開始錄制
SET /a SCTIME=10
ECHO.
SET /P SCTIME=[ INFO ] 請輸入錄制時間(默認10S):
:MyLoop
SET CONFIRM=Findyou
SET /P CONFIRM=[ INFO ] 確認開始錄制？[Enter]
IF NOT "%CONFIRM%"=="Findyou" GOTO MyLoop
ECHO.
ECHO.[ EXEC ] 開始錄制視頻(Time: %SCTIME%S)
adb shell screenrecord --time-limit %SCTIME% %phoneDir%/screenrecord.mp4
:: 獲取得小時,格式為：24小時制，10點前補0
SET c_time_hour=%time:~0,2%
IF /i %c_time_hour% LSS 10 (
SET c_time_hour=0%time:~1,1%
)
ECHO.[ INFO ] 錄制結束
ECHO.
ECHO.[ EXEC ] 拷貝錄屏至電腦
adb pull %phoneDir%/screenrecord.mp4 "%pcDir%\%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%.mp4"
ECHO.[ EXEC ] 打開視頻保存目錄
start %pcDir%
adb shell rm %phoneDir%/screenrecord.mp4
:BATend
ECHO.
ECHO.[ INFO ] 暫停3秒自動關閉...
ping -n 3 127.0.0.1>nul
說明:手機助手很多時候很厭煩，經常起自已的adb，導制ADB命令時常出錯。此腳本是為了在沒有手機助手的情況下進行屏幕錄制。使用方法:雙擊bat文件即可，默認錄制10S，默認保存路徑在"我的圖片"。
2、[獲得當前運行APP包名.bat]
@ECHO OFF
COLOR 0A
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
ECHO. :: ::
ECHO. :: 當前運行的APP包名 ::
ECHO. :: ::
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
:: ::::: 作者：Findyou ::
:: ::::: 版本:V1.0 時間：2014.05.25 ::
:: ::::::::::::::::::::::::::::::::::::::::::::::::::::
:: **************在此修改目錄**************************
SET pcDir=%~dp0
FOR /F "tokens=3 delims= " %%a in ('adb shell dumpsys window^| find "mCurrentFocus"') do (
FOR /F "tokens=1 delims=}" %%i in ("%%a") do (
ECHO.[ INFO ] 包名/活動名
ECHO.[ INFO ] %%i
)
)
ECHO.
PAUSE
3、[Activity啟動跳轉時間監控V1.0.bat]
@ECHO OFF
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
ECHO. :: ::
ECHO. :: Activity啟動跳轉時間監控 V1.0 ::
ECHO. :: ::
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
:: ::::: 作者：Findyou ::
:: ::::: 版本:V1.0 時間：2014.08.25 ::
:: ::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.[ INFO ] 清空日志
adb logcat -c
ECHO.[ INFO ] 監控開始(Ctrl+C結束)
ECHO.[ INFO ] 保存請拷貝輸出內容
adb logcat -s ActivityManager|Findstr /C:": Displayed"
4、[查看簽名信息(文件拖至此) V1.1.bat]
@ECHO OFF
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
ECHO. :: ::
ECHO. :: 查看APK簽名信息 ::
ECHO. :: ::
ECHO. :: :::::::::::::::::::::::::::::::::::::::::::::::
:: ::::: 作者：Findyou ::
:: ::::: 版本:V1.0 時間：2014.08.25 ::
:: ::::: 版本:V1.1 時間：2014.12.13 ::
:: ::::::::::::::::::::::::::::::::::::::::::::::::::::
Color 0A
ECHO.
ECHO.[ HELP ] 可查看RSA、APK、keystore簽名信息
SET C_PATH=%~dp0
REM 方法：直接將APK或RSA文件到bat文件上
IF NOT "%1"=="" SET apkorFile= %1
IF "%~x1"==".RSA" GOTO RSAFile
IF "%~x1"==".rsa" GOTO RSAFile
IF "%~x1"==".apk" GOTO APKFile
IF "%~x1"==".APK" GOTO APKFile
IF "%~x1"==".keystore" GOTO KEYSTOREFile
IF "%~x1"==".KEYSTORE" GOTO KEYSTOREFile
Color 0D
ECHO.[ INFO ] 你是猴子派來的逗逼吧？
ECHO.[ HELP ] 請將RSA或得APK或者keystore拖至Bat文件上
GOTO BATend
:KEYSTOREFile
DEL "%C_PATH%%~nx1.txt" 2>nul
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~nx1.txt
ECHO.
keytool -list -v -keystore %apkorFile% > "%C_PATH%%~nx1.txt"
type "%C_PATH%%~nx1.txt"
GOTO BATend
:RSAFile
DEL "%C_PATH%%~n1.RSA.txt" 2>nul
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~n1.RSA.txt
ECHO.
keytool -printcert -file %apkorFile% > "%C_PATH%%~n1.RSA.txt"
type "%C_PATH%%~n1.RSA.txt"
GOTO BATend
:APKFile
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~n1.RSA.txt
RD /S /Q %~n1_META-INF 2>nul
:: jar tf %apkorFile%|Findstr "RSA"
:: 解壓簽名目錄
jar -xf %apkorFile% META-INF
:: 重合名文件夾
REN META-INF %~n1_META-INF
:: 查看簽名文件信息
CD %~n1_META-INF
FOR %%I IN (*.RSA) DO (
ECHO.[ INFO ] %%I
ECHO.
keytool -printcert -file %%I > "%C_PATH%%~n1.RSA.txt"
type "%C_PATH%%~n1.RSA.txt"
)
CD %~dp1
RD /S /Q %~n1_META-INF 2>nul
:BATend
ECHO.
ECHO.[ EXIT ] 按任意鍵關閉窗口...
PAUSE>nul
暫進更新到這,Mark 2015-07-23 20：30
朋友反饋目錄名錯誤，已更正 2015-07-23 21:30
附：