[批處理]自動設置本機系統代理服務器

可以自動修改本機的系統代理(IE代理)服務器地址。

可以是指定計算機名的動態IP，也可以是靜態IP，也可指定端口號，感覺非常有用。

 

下載后先編輯，修改你要設置代理服務器的計算機名和端口號，或直接指定IP

修改后直接運行即可，腳本會先解析主機名對應的IP地址，再設置系統代理。

之后進入IE的Internet設置中的連接即可查看到已經設置成功。

 

自動設置本機代理服務器-批處理代碼：

@echo off
title 自動更改IE代理服務器IP  By:小小滄海  2010.9.15
::color 80&mode con cols=60 lines=20

::請自行將set host=xxx更改為要ping的主機名稱
set host=BJ-CLT-003
::請自行修改目標服務器端口號
set port=8888
for /f "tokens=2 delims=[]" %%i in ('ping %host% /n 1 -4 ^| findstr "Ping"') do echo 主機名稱：%host%   IP地址：%%i:%port%&set ip=%%i
set ip>nul 2>nul
if %errorlevel%==1 echo 主機%host%沒有找到,請檢查主機名稱是否正確!&goto end
::如果需要直接指定IP地址則可刪除上述for命令行和if命令行，直接修改set ip=x.x.x.x即可


echo 正在寫入注冊值...
echo ==============================
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings\Connections" /v "DefaultConnectionSettings" /t  REG_BINARY /d "3C000000AA0100000B0000000F000000" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyEnable" /t  REG_DWORD /d "1" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyServer" /t  REG_SZ /d "%ip%:%port%" /f 
REG ADD "HKLM\System\CurrentControlSet\Hardware Profiles\0001\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyEnable" /t  REG_DWORD /d "1" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings\Connections" /v "SavedLegacySettings" /t  REG_BINARY /d "3C000000AE0100000B0000000F000000" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyOverride" /t  REG_SZ /d "<local>" /f 
echo.
echo ==============================
echo 完成! 重啟IE后生效
:end
ping 127.1 /n 3 >nul&exit

::應阿零制作，IE6 IE8均通過測試

 

刪除本機代理服務器設置-批處理代碼：

@echo off
title 刪除本機代理服務器設置

echo 正在寫入注冊值...
echo ==============================
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings\Connections" /v "DefaultConnectionSettings" /t  REG_BINARY /d "3C000000AA0100000B0000000F000000" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyEnable" /t  REG_DWORD /d "0" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyServer" /t  REG_SZ /d "" /f 
REG ADD "HKLM\System\CurrentControlSet\Hardware Profiles\0001\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyEnable" /t  REG_DWORD /d "1" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings\Connections" /v "SavedLegacySettings" /t  REG_BINARY /d "3C000000AE0100000B0000000F000000" /f 
REG ADD "HKCU\SOFTWARE\MICROSOFT\Windows\CURRENTVERSION\Internet Settings" /v "ProxyOverride" /t  REG_SZ /d "<local>" /f 
echo.
echo ==============================
echo 完成! 重啟IE后生效
:end
exit

::應阿零制作，IE6 IE8均通過測試

 

代碼已托管至GitHub：

自動設置本機系統代理服務器.bat

刪除本機代理服務器設置.bat