IDL中路徑相關函數總結

【轉】

系統變量

系統變量	描述
!DIR	IDL安裝主目錄
!PATH	IDL搜索庫文件及路徑，包含IDL自帶庫文件路徑和用戶工作空間路徑。
!DLM_PATH	IDL搜索DLM路徑
!HELP_PATH	IDL幫助文件路徑

獲取臨時路徑

IDL> print, GETENV('IDL_TMPDIR')

C:\Users\Administrator\AppData\Local\Temp\

 

修改工作空間當前路徑：CD，通過current關鍵字獲取當前路徑

 

IDL> cd, 'D:\temp'

IDL> cd, current = curPath

IDL> print, curPath

D:\temp

 

獲取指定路徑下文件名完整路徑 – FilePath

;默認搜索路徑為!dir路徑下

IDL> print, FILEPATH('people.dat', SUBDIRECTORY=['examples','data'])

C:\Program Files\Exelis\IDL82\examples\data\people.dat

;也可手動指定ROOT_DIR，即根目錄

IDL> print, filepath('ruleset.xml', root_dir = 'D:\', subdirectory = ['temp'])

D:\temp\ruleset.xml

;獲取系統路徑下某文件夾路徑

IDL> print, filepath('data')

C:\Program Files\Exelis\IDL82\data

IDL> print, filepath('bin')

C:\Program Files\Exelis\IDL82\bin

;關鍵字TMP，返回臨時目錄下自定文件名的完整路徑

IDL> print, filepath('a.dat', /tmp)

C:\Users\Administrator\AppData\Local\Temp\a.dat

 

創建新路徑

;如果不指定路徑，則默認在當前路徑下創建新文件夾

IDL> file_mkdir, 'test_mkdir'

;創建指定路徑目錄

IDL> file_mkdir, 'D:\temp\temp\temp'

 

判斷文件/路徑是否存在、文件是否為可執行文件、是否可讀、可寫等。 — File_Test

 

IDL> print, file_test('D:\temp\aaaa.dat')

           0

IDL> print, file_test('D:\temp\temp', /directory)

           1

IDL> print, file_test('D:\temp\temp1', /directory)

       0

IDL> print, file_test('D:\temp\ruleset.xml', /write)

           1

IDL> print, file_test('D:\temp\ruleset.xml', /executable)

           0

 

獲取已編譯某程序文件路徑

IDL> print, routine_filepath('helloworld')

D:\IDLWorkspace82\Default\helloworld.pro

;常用此方法獲取當前程序路徑

IDL> print, file_dirname(routine_filepath('helloworld'))

D:\IDLWorkspace82\Default

IDL 8.2.2可以使用如下方法，即不需要輸入過程名

IDL> print, file_dirname(routine_filepath())

D:\IDLWorkspace82\Default

 

獲取完整文件名，以當前路徑為基礎

IDL> file = 'D:\temp\test_file.dat'

IDL> print, file_dirname(file)

D:\temp

IDL> print, file_basename(file)

test_file.dat

 

獲取系統路徑!Path或指定路徑下的文件完整路徑 – File_Which

 

IDL> print, FILE_WHICH('file_which.pro')

C:\Program Files\Exelis\IDL82\lib\file_which.pro

IDL> print, FILE_WHICH('D:\temp', 'ruleset.xml')

D:\temp\ruleset.xml

;在!Path下沒有搜索到ruleset.xml文件

IDL> print, FILE_WHICH('ruleset.xml')

;include_current_dir關鍵字表示將當前路徑加入到搜索路徑下

IDL> print, FILE_WHICH('ruleset.xml', /include_current_dir)

D:\temp\ruleset.xml

獲取當前系統的路徑分隔符

IDL> print, path_sep()

\

Dialog_Pickfile函數

Result = DIALOG_PICKFILE( [, DEFAULT_EXTENSION=string] [, /DIRECTORY] [, DIALOG_PARENT=widget_id] [, DISPLAY_NAME=string] [, FILE=string] [, FILTER=string/string array] [, /FIX_FILTER] [, GET_PATH=variable] [, GROUP=widget_id] [, /MULTIPLE_FILES] [, /MUST_EXIST] [, /OVERWRITE_PROMPT] [, PATH=string] [, /READ | , /WRITE] [, RESOURCE_NAME=string] [, TITLE=string] )

關鍵字	含義
DEFAULT_EXTENSION	默認返回文件名后綴
DIRECTORY	打開返回路徑的對話框
FILTER	后綴名篩選
GET_PATH	獲取對話框上一次選擇的路徑
MULTIPLE_FILES	是否支持多選文件（按住Ctrl或Shift時）
PATH	默認打開路徑
TITLE	對話框標題